Android Code Snippet Start receiver at exact time

The standard StartReceiverAt is inexact, in order to allow the OS to make optimizations.

Worth reading: https://developer.android.com/training/scheduling/alarms

Exact scheduling:
1. AddPermission(android.permission.SCHEDULE_EXACT_ALARM)
2. Private ion As Object - class global
3.

Private Sub Button1_Click
    Wait For (GetScheduleExactAlarmPermission) Complete (HasPermission As Boolean)
    If HasPermission Then
        StartServiceAtExact(ScheduledReceiver, DateTime.Now + 10 * DateTime.TicksPerSecond, True) 'yes it is StartServiceAtExact and we pass a receiver
    Else
        Log("no permission")
    End If
End Sub

Private Sub GetScheduleExactAlarmPermission As ResumableSub
    Dim p As Phone
    If p.SdkVersion >= 31 Then
        Dim am As JavaObject = GetAlarmManager
        If am.RunMethod("canScheduleExactAlarms", Null).As(Boolean) = False Then
            Dim in As Intent
            in.Initialize("android.settings.REQUEST_SCHEDULE_EXACT_ALARM", "package:" & Application.PackageName)
            StartActivityForResult(in)
            Wait For ion_Event (MethodName As String, Args() As Object)
            Return -1 = Args(0)
        End If
    End If
    Return True
End Sub

Private Sub GetAlarmManager As JavaObject
    Dim ctxt As JavaObject
    ctxt.InitializeContext
    Return ctxt.RunMethod("getSystemService", Array("alarm"))
End Sub

Sub StartActivityForResult(i As Intent)
    Dim jo As JavaObject = GetBA
    ion = jo.CreateEvent("anywheresoftware.b4a.IOnActivityResult", "ion", Null)
    jo.RunMethod("startActivityForResult", Array As Object(ion, i))
End Sub

Sub GetBA As Object
    Dim jo As JavaObject = Me
    Return jo.RunMethod("getBA", Null)
End Sub

 

[asales]

Thanks!
How can I use with this?:

[B4X] Calculating the next scheduled time

Name: Find the next scheduled time. Description by example: You need to start a service each day at 5 am, 6:30 am and 8 pm. You need to find the ticks values of the next scheduled time, either today or tomorrow if it is after 8pm. Dim t As Long = FindNextTime(Array As Double(5, 6.5, 20))...

www.b4x.com

 

[Erel]

That code gives you the next time that you need to pass to StartServiceAtExact.