Android Question Convert Date Format

[RishiKumar2210]

I need to convert date(22-04-2023) into Apr'2023. Is it possible?

 

[Erel]

Sub ConvertDate(date As String) As String
    DateTime.DateFormat = "dd-MM-yyyy"
    Dim t As Long = DateTime.DateParse(date)
    DateTime.DateFormat = "MMM''yyyy" 'two quotes as the quote needs to be escaped
    Return DateTime.Date(t)
End Sub

Note that it changes the date format so make sure to explicitly set it before parsing dates in other places.

 

[emexes]

Note that it changes the date format so make sure to explicitly set it before parsing dates in other places.

or, in the absence of DateParse and DateFormat functions that have a non-global format parameter, perhaps save and restore?

Sub ConvertDate(date As String) As String
    Dim SaveDateFormat As String = DateTime.DateFormat
    DateTime.DateFormat = "dd-MM-yyyy"
    Dim t As Long = DateTime.DateParse(date)
    DateTime.DateFormat = "MMM''yyyy" 'two quotes as the quote needs to be escaped
    Dim Result As String = DateTime.Date(t)
    DateTime.DateFormat = SaveDateFormat
    Return Result
End Sub

 

[emexes]

I need to convert date(22-04-2023) into Apr'2023. Is it possible?

Not only is it possible, but it is possible in many ways, eg if you are confident of the date being in that exact 10-character format then you could add this Sub:

Sub RishiFormat(D As String) As String
  
    Dim Mmm() As String = Array As String( _
        "Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec" _
    )
  
    Dim M As Int = D.SubString2(3, 5)    '2 digit month
    Dim Y As Int = D.SubString2(6, 10)    '4 digit year
  
    Return Mmm(M - 1) & "'" & Y

End Sub

and call it eg:

Dim TestDate As String = "22-04-2023"
Log( TestDate & " becomes " & RishiFormat(TestDate) )

 

[emexes]

I need to convert date(22-04-2023) into Apr'2023. Is it possible?

The nice thing about the hand-crafted array approach is that it makes oddball arbitrary formats easier eg you could freak your users out with:

Sub NotRishiFormat(D As String) As String
 
    Dim Mmm() As String = Array As String( _
        "First", "Second", "Third", "Fourth", "Fifth", "Sixth", "Seventh", "Eighth", "Ninth", "Tenth", "Penultimate", "Last" _
    )
 
    Dim M As Int = D.SubString2(3, 5)    '2 digit month
    Dim Y As Int = D.SubString2(6, 10)    '4 digit year
 
    Return Mmm(M - 1) & " month of " & Y

End Sub

 

[Mahares]

DateTime.DateFormat = "MMM''yyyy"

I tried to use String Literals, the only one I could make it work is this one:

DateTime.DateFormat = $"MMM${Chr(39)}${Chr(39)}yyyy"$

Are there better ones.

 

[RishiKumar2210]

Not only is it possible, but it is possible in many ways, eg if you are confident of the date being in that exact 10-character format then you could add this Sub:

Sub RishiFormat(D As String) As String
 
    Dim Mmm() As String = Array As String( _
        "Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec" _
    )
 
    Dim M As Int = D.SubString2(3, 5)    '2 digit month
    Dim Y As Int = D.SubString2(6, 10)    '4 digit year
 
    Return Mmm(M - 1) & "'" & Y

End Sub

and call it eg:

Dim TestDate As String = "22-04-2023"
Log( TestDate & " becomes " & RishiFormat(TestDate) )

Thanks for the answer and Function Name(rishiformat) @emexes. I will try this.

 

[RishiKumar2210]

Not only is it possible, but it is possible in many ways, eg if you are confident of the date being in that exact 10-character format then you could add this Sub:

Sub RishiFormat(D As String) As String
 
    Dim Mmm() As String = Array As String( _
        "Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec" _
    )
 
    Dim M As Int = D.SubString2(3, 5)    '2 digit month
    Dim Y As Int = D.SubString2(6, 10)    '4 digit year
 
    Return Mmm(M - 1) & "'" & Y

End Sub

and call it eg:

Dim TestDate As String = "22-04-2023"
Log( TestDate & " becomes " & RishiFormat(TestDate) )

Thanks. Mr. @emexes It Worked.