B4J Question B4J and Python

[Tyrion]

Hi. I can run simple Python scripts when I don't use any import external modules (like import requests, import numpy, ...)
Is it possible to run a "main" script using import "external python's libraries"

Is it possible using shell (sh.initialize)... or does I need to add a Jython or JPython library.
I do love and appreciate a small sample !

Thank a lot.

 

[Erel]

Your best option is to use jShell and run it with the python command.

Something like:

Dim shl As Shell
shl.Initialize("shl", "python", Array("path to script"))
shl.Run(30000)
Wait For shl_ProcessCompleted (Success As Boolean, ExitCode As Int, StdOut As String, StdErr As String)
If Success Then
    Log(ExitCode)
    Log(StdErr)
    Log(StdOut)
End If

If it is a non-ui app then you need to make sure that there is a message loop running.

 

[LucaMs]

Please, use the Code menu icon:

?

 

[Tyrion]

Thanks for the thoughts Erel... always appreciate help.
As this is a Non-UI app, I try this code with StartMessageLoop inside :

'Non-UI application (console / server application)
#Region Project Attributes
    #CommandLineArgs:
    #MergeLibraries: True
#End Region

Sub Process_Globals
    
End Sub

Sub AppStart (Args() As String)
    Log("Hello")
    Dim shl As Shell
    shl.Initialize("shl", "C:\Users\Tyrion\AppData\Local\Continuum\anaconda3\python", Array("C:\Users\Tyrion\Desktop\Maths\truc.py"))
    shl.Run(30000)
    Wait For shl_ProcessCompleted (Success As Boolean, ExitCode As Int, StdOut As String, StdErr As String)
    If Success=True Then 
        Log("Success")
    Else
        Log("Failure")
    End If
    If Success Then
        Log(StdOut)
        Log(ExitCode)
        Log(StdErr)
    End If
    StartMessageLoop
End Sub

Where truc.py is :

# -*- coding: utf-8 -*-
"""
Created on Mon Apr 12 21:34:10 2021

@author: Tyrion
"""
print('truc')

And I get no error but no return from StdOut (just log("Hello") at the begining on the console and nothing else !
The message from the console is "StartMessageLoop was not called" and all the lines after "Wait For shl_ProcessCompleted(..." seems to be ignored.

Tyrion... (humble) !

 

[agraham]

Your StartMessageLoop is in the wrong place

Resumable Subs (wait for / sleep) in server handlers | B4X Programming Forum

 

[Erel]

The answer above is correct.

In this case it should look like this:

Sub AppStart (Args() As String)
 DoSomething
 StartMessageLoop
End Sub

Sub DoSomething
   Dim shl As Shell
    shl.Initialize("shl", "C:\Users\Tyrion\AppData\Local\Continuum\anaconda3\python", Array("C:\Users\Tyrion\Desktop\Maths\truc.py"))
    shl.Run(30000)
    Wait For shl_ProcessCompleted (Success As Boolean, ExitCode As Int, StdOut As String, StdErr As String)
    If Success=True Then 
        Log("Success")
    Else
        Log("Failure")
    End If
    If Success Then
        Log(StdOut)
        Log(ExitCode)
        Log(StdErr)
    End If
End Sub

 

[Tyrion]

Yop. It's work perfectly. Thank's. I can dive inside apps
? Thank's a lot all of you.