Button stuck in 'pressed down' look?

[Jim Brown]

Is there a way to avoid the following little issue ..

In my app I use a button to delete local items. As a precaution I employ the use of the LongClick() event (to avoid accidental clicks)
Once all items are deleted I disable the button

The problem is, the button remains in its "pressed-down" look

Try this simple example:

' Button stuck in "Pressed Down" look from LongClick/Disable combo
Sub Process_Globals
End Sub

Sub Globals
   Dim bt As Button
End Sub

Sub Activity_Create(FirstTime As Boolean)
   bt.Initialize("ButtonPress") : bt.Text="Long-Press me"
   Activity.AddView(bt,10%x,20dip,60%x,40dip)
End Sub

Sub ButtonPress_LongClick()
   bt.Enabled=False
End Sub

Sub Activity_Resume
End Sub

Sub Activity_Pause (UserClosed As Boolean)
End Sub

Is there a method to avoid this situation? I tried various combinations of the following inside the LongClick() sub:

bt.Invalidate​

bt.Visible=True .... False​

DoEvents​

 

[Erel]

This looks like a bug in the Android SDK. Here is a workaround:

Sub Process_Globals
   Dim tmrDisable As Timer
   Dim shouldDisable As Boolean
End Sub

Sub Globals
   Dim bt As Button
End Sub

Sub Activity_Create(FirstTime As Boolean)
   If FirstTime Then
      tmrDisable.Initialize("tmrDisable", 5)
   End If
   bt.Initialize("ButtonPress") : bt.Text="Long-Press me"
   Activity.AddView(bt,10%x,20dip,60%x,40dip)
End Sub
Sub ButtonPress_Up
   If shouldDisable Then
      tmrDisable.Enabled = True
      shouldDisable = False
   End If
End Sub
Sub ButtonPress_LongClick()
   shouldDisable = True
End Sub
Sub tmrDisable_Tick
   tmrDisable.Enabled = False
   bt.Enabled = False
End Sub

Sub Activity_Resume
End Sub

Sub Activity_Pause (UserClosed As Boolean)
End Sub

 

[Jim Brown]

Thanks for confirming Erel

I just found another work-around. Remove the view entirely then re-create it:

' Button stuck in "Pressed Down" look from LongClick/Disable combo
' One solution to get around the issue
Sub Process_Globals
End Sub

Sub Globals
   Dim bt As Button
End Sub

Sub Activity_Create(FirstTime As Boolean)
   bt.Initialize("ButtonPress") : bt.Text="Long-Press me"
   Activity.AddView(bt,10%x,20dip,60%x,40dip)
End Sub

Sub ButtonPress_LongClick()
   bt.RemoveView
   bt.Initialize("ButtonPress") : bt.Text="Long-Press me"
   Activity.AddView(bt,10%x,20dip,60%x,40dip)
   bt.Enabled=False
End Sub

Sub Activity_Resume
End Sub

Sub Activity_Pause (UserClosed As Boolean)
End Sub