B4R Question Deep sleep with AsyncStreams + B4XSerializator

Sub AppStart (Form1 As Form, Args() As String)

    socket.Initialize("socket")
    socket.Connect(IP, port, 0)
    ser.Initialize
    
    MainForm = Form1
    MainForm.RootPane.LoadLayout("Layout1")
    MainForm.Show
    
End Sub

Sub Socket_Connected (Successful As Boolean)
    If Successful Then
        Log("Connected")
        If astream.IsInitialized Then astream.Close
        astream.InitializePrefix(socket.InputStream, False, socket.OutputStream, "astream")
    Else
        Log("Could not connect")
    End If
End Sub

Sub AStream_NewData (Buffer() As Byte)
    Log("New data")
    Dim data() As Object = ser.ConvertBytesToArray(Buffer)
    lblHumidity.Text = "Humidity " & data(0) & "%"
    lblTemperature.Text = "Temperature " & data(1) & " ºC"
End Sub

Sub AStream_Error
    Log("Error")
End Sub

Sub AStream_Terminated
    Log("Terminated")
End Sub

' Connect to ESP
Private Sub Button2_Click
    socket.Initialize("socket")
    socket.Connect(IP, port, 0)
End Sub

Sub Process_Globals
    Public Serial1 As Serial
    Private wifi As ESP8266WiFi
    Private server As WiFiServerSocket
    Private astream As AsyncStreams
    Private ser As B4RSerializator
    Public DHT11pin As Pin
    Private dht11 As dht
    Dim humidity,temperature As Double ' Humidity/Temperature DHT11 readings
    Public timer As Timer
    Public Const interval As ULong = 5000
End Sub

Private Sub AppStart
    Serial1.Initialize(115200)
    Log("AppStart")
    If wifi.Connect2("xxx", "yyy") Then
        Log("Connected to wireless network.")
        Log("My ip: ", wifi.LocalIp)
    Else
        Log("Failed to connect to network")
    End If
    
    timer.Initialize("timer_tick", interval)
    DHT11pin.Initialize(2,    DHT11pin.MODE_INPUT)
    server.Initialize(51042, "server_NewConnection")
    server.Listen
    timer.Enabled = True
    timer_tick
End Sub

Sub timer_tick
    dht11.Read11(DHT11pin.PinNumber) ' Reading the DHT11 measure
    temperature = dht11.GetTemperature ' Get temperature from readed measure
    humidity = dht11.GetHumidity       ' Get humidity from readed measure
    Log("DHT11 ","Humidity = ", humidity, " %", "  Temperature =", temperature, " ºC")
    If server.Socket.Connected Then
        astream.Write(ser.ConvertArrayToBytes(Array(humidity, temperature)))
    End If
End Sub

Sub Server_NewConnection (NewSocket As WiFiSocket)
    Log("Client connected")
    astream.InitializePrefix(NewSocket.Stream, False, "astream_NewData", "astream_Error")
End Sub

Sub AStream_Error
    Log("Error")
    server.Listen
End Sub

Sub AStream_NewData (Buffer() As Byte)
    Dim be(10) As Object
    Dim data() As Object = ser.ConvertBytesToArray(Buffer, be)
    Log("Received:")
    For Each o As Object In data
        Log(o)
        Select o
            Case "sleep"
                wifi.Disconnect
                DeepSleep(60000)
        End Select
    Next
End Sub

Private Sub DeepSleep(ms As ULong)
    RunNative("deepSleep", ms * 1000)
End Sub

#if C
void deepSleep(B4R::Object* o) {
   ESP.deepSleep(o->toULong());
}
#end if