Wish FaceDetectionListener callback for the camera

gmh said:

Thanks, this has been really helpful.

Question 1: I’m looking to display the rectangle around the face and I’m not quite sure how to superimpose it on the preview. Using the above code, I am able to identify the co-ordinates. Any pointers on overlaying a rectangle greatly appreciated.

Question 2: I’ve tried to identify the co-ordinates for eyes and mouth. However there doesn’t seem to be a type for ‘Point’. I’ve try using the code below without success. Again any pointers (no pun intended) also greatly appreciated.

B4X:

Private Sub FaceDetection_Event (MethodName As String, Args() As Object) As Object
   Dim faces() As Object = Args(0)
   For Each f As Object In faces
     Dim jo As JavaObject
     jo = f
   
     Dim faceRect As Rect
     faceRect = jo.GetField("rect")
     Log("faceRect "&faceRect.Top&" "&faceRect.Left)  'works as expected
   
     Dim Score As Int
     Score = jo.GetField("score")
     Log("left "&Score) ' works as expected
   
     Dim p As JavaObject
     p.InitializeNewInstance("android.graphics.PointF", Null)
     p = jo.GetField("leftEye")
     Log("Point "&p.GetField("x") & " , "&p.GetField("y") ) 'Gets  java.lang.RuntimeException: Object should first be initialized (JavaObject).
 
   Next
   Return Null
End Sub

Many thanks

Geoff

Click to expand...

Erel said:

Here:
1. Add this code to CameraEx:

B4X:

Public Sub SetFaceDetectionListener
   Dim jo As JavaObject = nativeCam
   Dim e As Object = jo.CreateEvent("android.hardware.Camera.FaceDetectionListener", "FaceDetection", Null)
   jo.RunMethod("setFaceDetectionListener", Array(e))
End Sub

Private Sub FaceDetection_Event (MethodName As String, Args() As Object) As Object
   Dim faces() As Object = Args(0)
   For Each f As Object In faces
     Dim jo As JavaObject = f
     Dim faceRect As Rect = jo.GetField("rect")
     Log(faceRect)
   Next
   Return Null
End Sub

Public Sub StartFaceDetection
   Dim jo As JavaObject = nativeCam
   jo.RunMethod("startFaceDetection", Null)
End Sub

Public Sub StopFaceDetection
   Dim jo As JavaObject = nativeCam
   jo.RunMethod("stopFaceDetection", Null)
End Sub

2. You need to call SetFaceDetectionListener when your app starts and StartFaceDetection after the preview is started:

B4X:

Sub Camera1_Ready (Success As Boolean)
   If Success Then
     camEx.SetJpegQuality(90)
     camEx.ExposureCompensation = camEx.MaxExposureCompensation
     camEx.SetFaceDetectionListener
     camEx.CommitParameters
     camEx.StartPreview
     camEx.StartFaceDetection
   Else
     ToastMessageShow("Cannot open camera.", True)
   End If
End Sub

See the documentation of Face.rect: http://developer.android.com/reference/android/hardware/Camera.Face.html

Click to expand...

Erel said:

The coordinates are explained here: http://developer.android.com/reference/android/hardware/Camera.Face.html

Start in landscape orientation with the rear camera.

Remove this line: p.InitializeNewInstance("android.graphics.PointF", Null)
You are creating a new point and you never use its value.

You should check the value of p.IsInitialized before you use it. As you can see in the documentation it may be null.

Click to expand...

Dim Score As Int
     Score = jo.GetField("score")
     Log("left "&Score) ' works as expected

Dim mouth As JavaObject = jo.GetField("mouth")
Log(mouth.GetField("x"))
Log(mouth.GetField("y"))

java.lang.RuntimeException: Object should first be initialized (JavaObject).
at anywheresoftware.b4a.AbsObjectWrapper.getObject(AbsObjectWrapper.java:50)
at anywheresoftware.b4j.object.JavaObject.getCurrentClass(JavaObject.java:258)
at anywheresoftware.b4j.object.JavaObject.GetField(JavaObject.java:180)
at com.omnicorp.scifiui.cameraexclass._facedetection_event(cameraexclass.java:372)
at java.lang.reflect.Method.invoke(Native Method)
at anywheresoftware.b4a.BA.raiseEvent2(BA.java:186)
at anywheresoftware.b4a.BA.raiseEvent(BA.java:166)
at anywheresoftware.b4j.object.JavaObject$1.invoke(JavaObject.java:237)
at java.lang.reflect.Proxy.invoke(Proxy.java:393)
at $Proxy0.onFaceDetection(Unknown Source)
at android.hardware.Camera$EventHandler.handleMessage(Camera.java:1139)
at android.os.Handler.dispatchMessage(Handler.java:102)
at anywheresoftware.b4a.Msgbox.waitForMessage(Msgbox.java:227)
at anywheresoftware.b4a.Msgbox.msgbox(Msgbox.java:166)
at anywheresoftware.b4a.BA.ShowErrorMsgbox(BA.java:260)
at anywheresoftware.b4a.BA.raiseEvent2(BA.java:224)
at anywheresoftware.b4a.BA.raiseEvent(BA.java:166)
at anywheresoftware.b4j.object.JavaObject$1.invoke(JavaObject.java:237)
at java.lang.reflect.Proxy.invoke(Proxy.java:393)
at $Proxy0.onFaceDetection(Unknown Source)
at android.hardware.Camera$EventHandler.handleMessage(Camera.java:1139)
at android.os.Handler.dispatchMessage(Handler.java:102)
at android.os.Looper.loop(Looper.java:148)
at android.app.ActivityThread.main(ActivityThread.java:5417)
at java.lang.reflect.Method.invoke(Native Method)
at com.android.internal.os.ZygoteInit$MethodAndArgsCaller.run(ZygoteInit.java:726)
at com.android.internal.os.ZygoteInit.main(ZygoteInit.java:616)

Click to expand...