B4J Question get pdf filename from B4j Print JavaFX8 library

stevel05 said:

You can't retrieve the job name after you've printed it, but you can set it before you print it see https://www.b4x.com/android/forum/threads/b4j-print-javafx8.49836/post-652102 (May work slightly differently for different printers).

Yes you can skip the dialogs, you will need to get the printer you want to print to using Printer_Static.GetAllPrinters, and find the printer object

Something like:

B4X:

Dim mPrinterName As String = "the target printer name"
Dim Ptr As Printer
Dim TPJ As PrinterJob
Dim JS As JobSettings
Dim PL As PageLayout

For Each P As Printer In AllPrinters
    If P.GetName.ToLowerCase = mPrinterName.ToLowerCase Then
        Ptr = P
        Exit
    End If
Next

Or get the default printer Ptr = Printer_Static.GetDefaultPrinter

Create a printer Job from the printer: TPJ = PrinterJob_Static.CreatePrinterJob2(Ptr)

Get the Jobsettings JS = TPJ.GetJobSettings, Unless you are happy with the defaults which you would have to try as they are not likely to be the same for all printers.

Then set the paper and other settings you require:

B4X:

PL = Ptr.CreatePageLayout(mPaper,mOrientation,LeftPageMargin,RightPageMargin,TopPageMargin,BottomPageMargin)
JS.SetPageLayout(PL)

Click to expand...

stevel05 said:

The link shows how to name the saved document. And the code is what you need to do to replace the dialogs.

Click to expand...

PA.Initialize()
        PA = Paper_static.A4
        Dim PRPDF As Printer= GetPrinter("Microsoft Print to PDF")
        Dim PL As PageLayout
        PL.Initialize()
        PL = PRPDF.CreatePageLayout2(PA, PageOrientation_Static.PORTRAIT, "HARDWARE_MINIMUM")
        Dim PJR As PrinterJob = PrinterJob_Static.CreatePrinterJob2(PRPDF)
        Dim fn As String = File.GetUri(File.Dirdata("appdatafolder") & "\"& "PDFs\", "FileName")
        PJR.GetJobSettings.SetJobName(fn)
        PJR.PrintPage2(PL,Panetoprint)
        PJR.EndJob

stevel05 said:

As I mentioned, the SetJobName sub works differently on different printers, it seems it doesn't work for MicrosoftPDF. And it would only set the JobName, not the full path.

This code works with Microsoft PDF printer (can't guarantee others) to set the full path (which must exist) and requires the reflection library.

B4X:

Dim PA As Paper
    PA.Initialize()
    PA = Paper_static.A4
    Dim PRPDF As Printer = GetPrinter("Microsoft Print to PDF")
    Dim PL As PageLayout
    PL.Initialize()
    PL = PRPDF.CreatePageLayout2(PA, PageOrientation_Static.PORTRAIT, "HARDWARE_MINIMUM")
    Dim PJR As PrinterJob = PrinterJob_Static.CreatePrinterJob2(PRPDF)
'    Dim fn As String = "FileName.pdf"'File.GetUri(File.Dirdata("appdatafolder") & "\"& "PDFs\", "FileName")
'    Dim PS As JobSettings = PJR.GetJobSettings
'    PS.SetJobName(fn)

    'Set the full filepath.  Works for Microsoft PDF printer
    Dim Refl As Reflector
    Refl.Target = PJR.GetObject
    Refl.Target = Refl.GetField("jobImpl")
    Dim AttSet As JavaObject = Refl.GetField("printReqAttrSet")
 
    'Directory has to exist
    File.MakeDir("D:\","PDfs")
 
    Dim URI As JavaObject
    URI.InitializeNewInstance("java.net.URI",Array(File.GetUri(File.Combine("D:\","PDfs"),"FileName.pdf")))
 
    Dim Dest As JavaObject
    Dest.InitializeNewInstance("javax.print.attribute.standard.Destination",Array(URI))
    AttSet.RunMethod("add",Array(Dest))


    PJR.PrintPage2(PL,Panetoprint)
    PJR.EndJob

Note: It creates and saved the document to a folder Pdfs on the D:\ drive, you will need to change that.
And doesn't display a dialog.

Click to expand...