iOS Question How do I download a PDF file from Webview?

[tiagovsilva]

I followed this thread
https://www.b4x.com/android/forum/t...n-webview-and-how-to-download-pdf-file.66546/

And my code is:

Sub WebView1_OverrideUrl (Url As String) As Boolean
    If Url.EndsWith(".pdf") Then
        Dim j As HttpJob
        j.Initialize("pdf", Me)
        j.Download(Url)
        Return True
    Else
        Return False
    End If
End Sub

but does nothing when trying to download.
Is this no longer supported or am I doing something wrong?

Thank you!

 

[Erel]

Call a different sub and download the PDF from that sub. Make sure to read this tutorial: [B4X] OkHttpUtils2 with Wait For

 

[tiagovsilva]

I have this now

Sub JobDone (Job As HttpJob)
End Sub

Sub WebView1_OverrideUrl (Url As String) As Boolean
    If Url.EndsWith(".docx") Then
        App.OpenURLAsync(Url)
        'Msgbox("Download Completo", "Educa4YOU")
        Return True
    Else If Url.EndsWith(".pdf") Then
        Download(Url)
        Return True
    Else
        Return False
    End If
End Sub

Sub Download (link As String)
    Dim j As HttpJob
    j.Initialize("pdf", Me)
    j.Download(link)
    Wait For (j) JobDone(j As HttpJob)
    If j.Success Then
        Msgbox("ok", "Sucesso!")
    Else
        Msgbox("ok", "Erro")
    End If
    j.Release
End Sub

and when I open the PDF link, it does not download.

I dont know if this is important but I'm using HttpUtils2Service Module.

 

[Erel]

I dont know if this is important but I'm using HttpUtils2Service Module.

You should use iHttpUtils2 library.

Put a breakpoint in Download sub. Is it reached?

 

[tiagovsilva]

Put a breakpoint in Download sub. Is it reached?

It reaches the Download Sub and the success MsgBox shows up but the PDF file is not stored on the ipad.

 

[Erel]

That's expected. You aren't doing anything with the downloaded resource.

See the download and save file example: https://www.b4x.com/android/forum/threads/b4x-okhttputils2-with-wait-for.79345/

 

[tiagovsilva]

I'm sorry for bothering again but the file is not being saved on the ipad.

My code is now like this

Sub JobDone (Job As HttpJob)
End Sub

Sub WebView1_OverrideUrl (Url As String) As Boolean
    If Url.EndsWith(".docx") Then
        App.OpenURLAsync(Url)
        Return True
    Else If Url.EndsWith(".pdf") Then
        DownloadFile(Url)
        Return True
    Else
        Return False
    End If
End Sub

Sub DownloadFile (link As String)
    Dim j As HttpJob
    j.Initialize("", Me)
    j.Download(link)
    Wait For (j) JobDone(j As HttpJob)
    If j.Success Then
        Dim out As OutputStream = File.OpenOutput(File.DirDocuments,"ficheiro.pdf", False)
        File.Copy2(j.GetInputStream, out)
        out.Close
        Msgbox("Download efetuado com sucesso!", "Sucesso")
    Else
        Msgbox(j.ErrorMessage, "Erro")
    End If
    j.Release
End Sub

And I even added to the Project Attributes

#PlistExtra: <key>UIFileSharingEnabled</key><true/>

I know that it reaches the success MsgBox but nothing more happens.

Again, sorry for bothering you

 

[Erel]

What is the output of:

Log("Size: " & File.Size(File.DirDocuments,"ficheiro.pdf"))

 

[tiagovsilva]

The output is: 56074

But I can not find the file on the Ipad. Should it be in the iBook or in the Adobe Acrobat?

 

[aeric]

When you use Resumable Sub, you don't need this sub:

Sub JobDone (Job As HttpJob)
End Sub

 

[Erel]

Should it be in the iBook or in the Adobe Acrobat?

No. It is stored in an app specific folder.

 

[tiagovsilva]

Is it possible to save to another folder? To be able to view in one of the mentioned apps.

 

[DonManfred]

Is it possible to save to another folder?

Sure, adapt the path

Sub DownloadFile (link As String)
    Dim j As HttpJob
    j.Initialize("", Me)
    j.Download(link)
    Wait For (j) JobDone(j As HttpJob)
    If j.Success Then
        Dim out As OutputStream = File.OpenOutput(File.DirDocuments,"ficheiro.pdf", False)
        File.Copy2(j.GetInputStream, out)
        out.Close
        Msgbox("Download efetuado com sucesso!", "Sucesso")
    Else
        Msgbox(j.ErrorMessage, "Erro")
    End If
    j.Release
End Sub

 

[tiagovsilva]

I read in the stackoverflow that it is not possible to access the folder of another app.
What I want is to do the same thing the browser does when you want to save a file. It gives the different options to save and read the file.

I know that didn't mention it before but I thought it was a system default.

 

[Erel]

What do you want to do with the file?
See this:

Open local files with external apps

And:
https://www.b4x.com/android/forum/t...pp-with-activityviewcontroller.73159/#content

 

[tiagovsilva]

Open local files with external apps

It works perfectly!

Sub WebView1_OverrideUrl (Url As String) As Boolean
    If Url.EndsWith(".docx") Then
        DownloadFile(Url,"ficheiro.docx")
        Return True
    Else If Url.EndsWith(".pdf") Then
        DownloadFile(Url,"ficheiro.pdf")
        Return True
    Else
        Return False
    End If
End Sub

Sub DownloadFile (link As String, FileName As String)
    Dim j As HttpJob
    j.Initialize("", Me)
    j.Download(link)
    Wait For (j) JobDone(j As HttpJob)
    If j.Success Then
        Dim out As OutputStream = File.OpenOutput(File.DirDocuments,FileName, False)
        File.Copy2(j.GetInputStream, out)
        out.Close
        di.Initialize("di", File.DirDocuments, FileName)
        di.PreviewFile(Page1)
    Else
        Msgbox(j.ErrorMessage, "Erro")
    End If
    j.Release
End Sub

Thanks Erel!

 

[tufanv]

It works perfectly!

Sub WebView1_OverrideUrl (Url As String) As Boolean
    If Url.EndsWith(".docx") Then
        DownloadFile(Url,"ficheiro.docx")
        Return True
    Else If Url.EndsWith(".pdf") Then
        DownloadFile(Url,"ficheiro.pdf")
        Return True
    Else
        Return False
    End If
End Sub

Sub DownloadFile (link As String, FileName As String)
    Dim j As HttpJob
    j.Initialize("", Me)
    j.Download(link)
    Wait For (j) JobDone(j As HttpJob)
    If j.Success Then
        Dim out As OutputStream = File.OpenOutput(File.DirDocuments,FileName, False)
        File.Copy2(j.GetInputStream, out)
        out.Close
        di.Initialize("di", File.DirDocuments, FileName)
        di.PreviewFile(Page1)
    Else
        Msgbox(j.ErrorMessage, "Erro")
    End If
    j.Release
End Sub

Thanks Erel!

what is di here ?

 

[Pendrush]

what is di here ?

Private di As DocumentInteraction

https://www.b4x.com/android/forum/threads/open-local-files-with-external-apps.51941/#content