Android Question Is there a way to invert a clip path?

[NeoTechni]

Let's say I've used the advanced graphics library to make a circle clip path, is there a way to select only the outside of the clip path? (Without generating the opposite clip path manually from the outside in)

 

[Erel]

You can create a path that covers the whole screen and then subtract the circle path.

 

[NeoTechni]

What sub/method subtracts a clip path? I can only find the ones to add them.

 

[Erel]

I don't know what is "advanced graphics library" so I cannot help you with this.

The native API does allow you to subtract one path from another.

 

[NeoTechni]

The ABExtDrawing library lets you make circle paths for example

but what is the native API call?
I only know of Canvas.ClipPath and Canvas.RemoveClip

 

[Erel]

Sub Activity_Create(FirstTime As Boolean)
   Dim cvs As Canvas
   cvs.Initialize(Activity)
   Dim circle As Path
   circle.Initialize(50%x, 50%y)
   Dim radius As Float = 100dip
   PathAddCircle(circle, 50%x, 50%y, radius)
   Dim fullScreen As Path
   fullScreen.Initialize(0, 0)
   fullScreen.LineTo(100%x, 0)
   fullScreen.LineTo(100%x, 100%y)
   fullScreen.LineTo(0, 100%y)
   Dim p As Path = OpPath(fullScreen, circle, "DIFFERENCE")
   cvs.ClipPath(p)
   
   Dim dest As Rect
   dest.Initialize(0, 0, 100%x, 100%y)
   cvs.DrawBitmap(LoadBitmap(File.DirAssets, "b4a.png"), Null, dest)
End Sub

Sub OpPath(p1 As Path, p2 As Path, Op As String) As Path
   Dim jo As JavaObject = p1
   Dim success As Boolean = jo.RunMethod("op", Array(p2, Op))
   Log($"Success: ${success}"$)
   Return p1   
End Sub

Sub PathAddCircle(path As Path, x As Float, y As Float, radius As Float)
  Dim jo As JavaObject = path
  jo.RunMethod("addCircle", Array(x, y, radius, "CW"))
End Sub

 

[NeoTechni]

That's awesome! Thank you.

For anyone else who finds this, I found the other operations OpPath would accept

Path.Op
DIFFERENCE
Subtract the second path from the first path.

Path.Op INTERSECT
Intersect the two paths.

Path.Op REVERSE_DIFFERENCE
Subtract the first path from the second path.

Path.Op UNION
Union (inclusive-or) the two paths.

Path.Op XOR
Exclusive-or the two paths.

 

[NeoTechni]

Also, with that PathAddCircle sub, I finally understand how to call native methods.