Android Question Long operations in BackGround

[GiovanniPolese]

Hi. I have a long operation to carry out (some minutes). I would like to put it in the background, being notified when it ends. Which is the state of art for this task?
Thanks in advance for any suggestion.

 

[Alexander Stolte]

Hi. I have a long operation to carry out (some minutes). I would like to put it in the background, being notified when it ends. Which is the state of art for this task?

You can try to integrate a background media player that plays a silent sound and thus keeps the app active. I use this principle under ios in my AS_Alarm library. This currently only works under ios. But to understand the principle it is great.

here is another thread for B4A for a background task, maybe it helps:

Background task

I'm struggling to create a background task using Tracker as a guide. I have a simple music player that we like but of course it stops when the screen goes off. Where should my Process Globals/Globals and all subs go? Particularly what happens to what was Activity_Create ?

www.b4x.com

 

[Erel]

You must start a service while your app is in the foreground and you need to call Service.StartForeground.

And read this: https://www.b4x.com/android/forum/t...getsdkversion-34-and-services.162140/#content

 

[GiovanniPolese]

You must start a service while your app is in the foreground and you need to call Service.StartForeground.

And read this: https://www.b4x.com/android/forum/t...getsdkversion-34-and-services.162140/#content

Ok. Thanks a lot.

 

[GiovanniPolese]

I have read it before posting the question. I have some doubts. First of all the example requests permissions that probably I don't need (i guess). Then there is the description of processes with maximum 3 minutes duration. Finally, if I need to run a service with no duration limits ( i mean maybe 6 minutes) and be notified when the process ended, I fear that the the answer is that I can't. Specifically, my idea was to run in background a complex file reading (i.e. not simply load, but also do some calculations) while the main App was allowing the user to navigate some images of aerial photos. When the loading ended, the image produced should be superimposed to the images. At the moment, I do it, but I have some strange crashes, (i.e. App vanishes, not crashes), while the App waits the loading process. Therefore I was thinking to completely isolate the process of loading. Moreover it should have been a much more elegant situation (at the moment the User must wait minutes, and often the App vanishes after waiting .. but not always...). Anyway useless to give further details, if I am thinking to the impossible. Thanks again.

 

[emexes]

Just an idea:

If you can somehow make sure that the activity process message loop doesn't get killed and recreated, then you can have a Resumable Sub running "separate" to your main program, by using Sleep(1) to occasionally yield from your "background" task to the main program.

I've done it in B4J, but and just tested it in B4A, and it works fine as a demo, as long as the activity remains intact.

The background task sends information back to the rest of the program via a global Result() As Object.

The first element of the array is the task status. In B4J I used a Boolean that is set True when the task is finished, but in the demo below, I used an Int to signify percentage complete, set to 100 when the task is finished.

Result() has to be Dim'ensioned (allocated) before calling the background task. It doubles as an indication that the background task is running: if it is only 1 element long, then the task is not running; if it is more than 1 element long, then the task is (or should be) running.

Good luck. Like I said, it's just an idea. If you work out how to make sure that the activity doesn't get killed - which I assume would take down the background task with it - I'd be interested in how you did that.

Sub Process_Globals
    'These global variables will be declared once when the application starts.
    'These variables can be accessed from all modules.
    Private xui As XUI

    Dim Result1(1) As Object
    'Dim Result2(1) As Object    'multiple background tasks, no problem!
    'Dim Result3(1) As Object
    'Dim Result4(1) As Object

    Dim CheckTasksTimer As Timer
End Sub

Sub Globals
    'These global variables will be redeclared each time the activity is created.
End Sub

Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("Layout")
    
    CheckTasksTimer.Initialize("CheckTasksTimer", 1000)
    CheckTasksTimer.Enabled = True
End Sub

Sub CheckTasksTimer_Tick
    Log("Tick")
    
    If Result1.Length <> 1 Then
        If Result1(0) = 100 Then
            Log("Task1 finished!")
            For I = 0 To 3
                Log("Result(" & I & ") = " & Result1(I))
            Next
            Dim Result1(1) As Object
        Else
            Log("Task1 in progress... " & Result1(0) & "%")
        End If
    End If
    
    'repeat similar for other background tasks eg
    'If Result2.Length <> 1 Then
End Sub

Sub Button1_Click
    '''xui.MsgboxAsync("Hello world!", "B4X")
    
    Log("Starting background task (from Button1_Click)")
    Dim Result1(4) As Object
    BackgroundTask(Result1)
    Log("Background task started")
End Sub

Sub BackgroundTask(Result() As Object)
    Result(0) = 0
    
    Dim BigCount As Long = 0
    Dim BigSum As Double = 0
    Dim BigTime As Int = 0
    
    Dim T1 As Long
    Dim T2 As Long
    
    For I = 1 To 10000
        Result(0) = (99 * I / 10000).As(Int)
        
        T1 = DateTime.Now
        Sleep(0)    'this is where background task temporarily yields to main program message loop
        T2 = DateTime.Now
        BigTime = BigTime + (T2 - T1)
        
        For J = 1 To 10000
            BigCount = BigCount + I * J
            BigSum = BigSum + Sqrt(I * I + J * J)
        Next
    Next
    
    Result(1) = BigCount
    Result(2) = BigSum
    Result(3) = BigTime
    Result(0) = 100    'order shouldn't matter but why risk it?
End Sub

Logger connected to:  HMD Global Nokia C01 Plus
** Activity (main) Create (first time) **
** Activity (main) Resume **
Tick
Tick
Tick
Tick
Starting background task (from Button1_Click)
Background task started
Tick
Task1 in progress... 0%
Tick
Task1 in progress... 12%
Tick
Task1 in progress... 38%
Tick
Task1 in progress... 64%
Tick
Task1 in progress... 90%
Tick
Task1 finished!
Result(0) = 100
Result(1) = 2500500025000000
Result(2) = 7.652604958254282E11
Result(3) = 111
Tick
Tick
Tick
Tick

 

[GiovanniPolese]

I will give it a try, unluckily not immediately, due to other urgent tasks. Anyway this is more o less what I was thinking. Nevertheless, to be sincere, my long task, which is the dxf reading, is in a resumable sub. Inside it I have a ProgressDialogShow/hide, both followed by Sleep(100) (without Sleep, the progress dialogs don't remain active. This said, using a WaitFor to call the DxfRead function, I obtain a behaviour exactly like a normal call to a non-resumable sub. The App waits until the DxfRead ends, I would like that it doesn't wait while the DxfRead is executing. I am forced to have a resumable sub for the DxfRead ONLY because of the presence of the Sleep, which seem to be mandatory to use the ProgressDialogShow. I mean that ProgressDialogShow doesn't work without a following Sleep. Perhaps I didn't understand these facts well, but this is how I did. Now, if you speak about the use of Resumable Sub, much probably I can easily adapt the actual code to your suggestion. Thanks

 

[emexes]

You can actually have more than one background task going on at the same time. Well, nearly the same time - they interleave (or task swap) using the Sleeps.

Eg, you can download multiple web pages simultaneously.

But the problem is that when the Sub finishes, the return value isn't saved in the ResumableSub handle that you've got to the background task. The Completed flag is set, so you know that it's finished, but the Return value is apparently lost unless you were sitting in a WaitFor ready to catch it. Hence why I use an Object Array to communicate between the main program and the background task.

I have belatedly attached the project file for the previous post, in case it's of use.

 

[emexes]

WaitFor only seems to let you get a Return value from one Resumable Sub at a time. Eg, if you have 5 Resumable Subs active, and you Wait For one of them, then if any of the other 4 Subs finish then their Return value is lost. And once they've Completed, then you can't do a Wait For on them to get their Return value.

I've found that my homemade kludgy way works great, at least in B4J. But it's looking good for B4A too. Main thing is to make sure you don't run the same task more than once (although that might work, if they don't step on each other's shared global variables... and you make sure each instance of the task has its own separate copy of the Result() array).

One of Erel's example videos was a grid of buttons, that would do a ten second countdown when you pressed them, and quite clearly it was possible to have multiple instances active at the same time.

https://www.b4x.com/android/forum/threads/b4x-resumable-subs-sleep-wait-for.78601/