Android Question Modbus CRC16 calculation

FreeWolF · Apr 10, 2014

Hello, I have to calculate the CRC16 of a MODBUS string. Unfortunately I have no idea how can I do that. I have found a code for Visual Basic, how I can convert it for Basic4Android?

B4X:

Public Function CRC(buf() As Byte, lbuf As Integer) As Integer
'-------------------------------------------------

' returns the MODBUS CRC of the lbuf first bytes of "buf" buffer (buf is a global array of bytes)
Dim CRC1 As Integer

CRC1 = &HFFFF ' init CRC
For i = 0 To lbuf - 1 Step 1 ' for each byte
CRC1 = CRC1 Xor buf(i)
For j = 0 To 7 Step 1 ' for each bit
k = CRC1 And 1 ' memo bit 0 state
CRC1 = ((CRC1 And &HFFFE) / 2) And H7FFF ' Shift right with 0 at left
If k > 0 Then CRC1 = CRC1 Xor &HA001 ' Bocuse
Next j
Next i
CRC = CRC1
End Function

And, there is an another solution for the calculation of the CRC16 modbus?

Thanks a lot!!!

FreeWolF · Apr 10, 2014

And here is the algorithm in C, I think that is better....but I need to covert it to basic4android

B4X:

WORD CRC16 (const BYTE *nData, WORD wLength)
{
static const WORD wCRCTable[] = {
0X0000, 0XC0C1, 0XC181, 0X0140, 0XC301, 0X03C0, 0X0280, 0XC241,
0XC601, 0X06C0, 0X0780, 0XC741, 0X0500, 0XC5C1, 0XC481, 0X0440,
0XCC01, 0X0CC0, 0X0D80, 0XCD41, 0X0F00, 0XCFC1, 0XCE81, 0X0E40,
0X0A00, 0XCAC1, 0XCB81, 0X0B40, 0XC901, 0X09C0, 0X0880, 0XC841,
0XD801, 0X18C0, 0X1980, 0XD941, 0X1B00, 0XDBC1, 0XDA81, 0X1A40,
0X1E00, 0XDEC1, 0XDF81, 0X1F40, 0XDD01, 0X1DC0, 0X1C80, 0XDC41,
0X1400, 0XD4C1, 0XD581, 0X1540, 0XD701, 0X17C0, 0X1680, 0XD641,
0XD201, 0X12C0, 0X1380, 0XD341, 0X1100, 0XD1C1, 0XD081, 0X1040,
0XF001, 0X30C0, 0X3180, 0XF141, 0X3300, 0XF3C1, 0XF281, 0X3240,
0X3600, 0XF6C1, 0XF781, 0X3740, 0XF501, 0X35C0, 0X3480, 0XF441,
0X3C00, 0XFCC1, 0XFD81, 0X3D40, 0XFF01, 0X3FC0, 0X3E80, 0XFE41,
0XFA01, 0X3AC0, 0X3B80, 0XFB41, 0X3900, 0XF9C1, 0XF881, 0X3840,
0X2800, 0XE8C1, 0XE981, 0X2940, 0XEB01, 0X2BC0, 0X2A80, 0XEA41,
0XEE01, 0X2EC0, 0X2F80, 0XEF41, 0X2D00, 0XEDC1, 0XEC81, 0X2C40,
0XE401, 0X24C0, 0X2580, 0XE541, 0X2700, 0XE7C1, 0XE681, 0X2640,
0X2200, 0XE2C1, 0XE381, 0X2340, 0XE101, 0X21C0, 0X2080, 0XE041,
0XA001, 0X60C0, 0X6180, 0XA141, 0X6300, 0XA3C1, 0XA281, 0X6240,
0X6600, 0XA6C1, 0XA781, 0X6740, 0XA501, 0X65C0, 0X6480, 0XA441,
0X6C00, 0XACC1, 0XAD81, 0X6D40, 0XAF01, 0X6FC0, 0X6E80, 0XAE41,
0XAA01, 0X6AC0, 0X6B80, 0XAB41, 0X6900, 0XA9C1, 0XA881, 0X6840,
0X7800, 0XB8C1, 0XB981, 0X7940, 0XBB01, 0X7BC0, 0X7A80, 0XBA41,
0XBE01, 0X7EC0, 0X7F80, 0XBF41, 0X7D00, 0XBDC1, 0XBC81, 0X7C40,
0XB401, 0X74C0, 0X7580, 0XB541, 0X7700, 0XB7C1, 0XB681, 0X7640,
0X7200, 0XB2C1, 0XB381, 0X7340, 0XB101, 0X71C0, 0X7080, 0XB041,
0X5000, 0X90C1, 0X9181, 0X5140, 0X9301, 0X53C0, 0X5280, 0X9241,
0X9601, 0X56C0, 0X5780, 0X9741, 0X5500, 0X95C1, 0X9481, 0X5440,
0X9C01, 0X5CC0, 0X5D80, 0X9D41, 0X5F00, 0X9FC1, 0X9E81, 0X5E40,
0X5A00, 0X9AC1, 0X9B81, 0X5B40, 0X9901, 0X59C0, 0X5880, 0X9841,
0X8801, 0X48C0, 0X4980, 0X8941, 0X4B00, 0X8BC1, 0X8A81, 0X4A40,
0X4E00, 0X8EC1, 0X8F81, 0X4F40, 0X8D01, 0X4DC0, 0X4C80, 0X8C41,
0X4400, 0X84C1, 0X8581, 0X4540, 0X8701, 0X47C0, 0X4680, 0X8641,
0X8201, 0X42C0, 0X4380, 0X8341, 0X4100, 0X81C1, 0X8081, 0X4040 };

BYTE nTemp;
WORD wCRCWord = 0xFFFF;

  while (wLength--)
  {
  nTemp = *nData++ ^ wCRCWord;
  wCRCWord >>= 8;
  wCRCWord ^= wCRCTable[nTemp];
  }
  return wCRCWord;

}

FreeWolF · Apr 10, 2014

For example, with that string:

11 01 00 03 00 0C

The CRC must be

CE9F (CE High, 9F Low)

And for that string:

11 01 02 CD 0B

The CRC must be:

6D 68

This is the table (Click on it to view the full example):

Erel · Apr 11, 2014

Try this code:

B4X:

Sub CRC(buf() As Byte, lbuf As Int) As Int
   Dim CRC1 As Int
   CRC1 = 0xffff
   For i = 0 To lbuf - 1
     CRC1 = Bit.Xor(CRC1, buf(i))
     For j = 0 To 7
       Dim k As Int = Bit.AND(crc1, 1)
       CRC1 = Bit.AND(Bit.AND(CRC1, 0xfffe) / 2, 0xf777)
       If k > 0 Then CRC1 = Bit.Xor(CRC1, 0xa001)
     Next
   Next
   Return CRC1
End Sub

FreeWolF · Apr 11, 2014

Thanks for the reply! But how I can implement that sub function in a program?

I have an edittext1 for write the string, a edittext2 for the CRC result and a button.

Erel · Apr 11, 2014

You can convert a string to an array of bytes with:

B4X:

EditText1.Text.GetBytes("UTF8")

Handling events is explained in the beginner's guide: http://www.b4x.com/android/documentation.html

FreeWolF · Apr 11, 2014

Unfortunately doesn't work, the calculated CRC is not correct...

FreeWolF · Apr 11, 2014

B4X:

Function CRC(DialString As String)
Dim G As Long, A As Long, AUX As Long
Dim ALow As Long, AHigh As Long, AL As Long, Carry As Integer
Dim i As Integer, j As Integer, cA As Long, cHex As String
'
A = 65535
G = 40961
i = 0
Do While i < Len(DialString$)
j = 0
ALow = Int(A / 256)
ALow = ALow * 256
ALow = A - ALow
AHigh = Int(A / 256) * 256
cA = Asc(Mid$(DialString, i + 1, 1))
AL = Int(cA Xor ALow)
AUX = Int(AHigh + AL)
A = AUX
Do While j < 8
j = j + 1
AUX = A
A = Int(A / 2)
Carry = AUX Mod 2
If Carry = 1 Then
A = Int(G Xor A)
End If
Loop
i = i + 1
Loop
ALow = A - Int(A / 256) * 256
AHigh = Int(A / 256)
CRC = Chr(ALow) + Chr(AHigh)
End Function

How can I convert that code from VB to B4A ?

LucaMs · Apr 11, 2014

you can simply replace the functions that do not match between VBnet and B4A, such as mid$ with SubString2

LucaMs · Apr 11, 2014

Try so (i'm not sure!!!)

B4X:

Sub CRC(DialString As String) As String
    Dim Res As String

    Dim G As Long, A As Long, AUX As Long
    Dim ALow As Long, AHigh As Long, AL As Long
    Dim Carry As Int
    Dim i, J As Int
    Dim cA As Long

    A = 65535
    G = 40961
    i = 0
    Do While i < DialString.Length
        J = 0
        ALow = A / 256
        ALow = ALow * 256
        ALow = A - ALow
        AHigh = (A / 256) * 256
        'cA =  Asc(Mid$(DialString, i + 1, 1))
        cA = DialString.SubString2(i, i + 1)
        AL = Bit.Xor(cA, ALow)
        AUX = AHigh + AL
        A = AUX
        Do While J < 8
            J = J + 1
            AUX = A
            A = A / 2
            Carry = AUX Mod 2
            If Carry = 1 Then
                A = Bit.Xor(G, A)
            End If
        Loop
        i = i + 1
    Loop
    ALow = A - (A / 256) * 256
    AHigh = A / 256
    Res = Chr(ALow) & Chr(AHigh)
   
    Return Res
End Sub

taktrashe · Oct 18, 2015

i have new sun function for CRC16 in B4A , i test it and it work great .
hope you try it and send me feedback .

B4X:

Sub CRC(buf() As Byte, lbuf As Short) As Short
   Dim CRC1 As Short
   CRC1 = 0xffff
   For i = 0 To lbuf - 1
    CRC1 = Bit.Xor(CRC1,Bit.And( buf(i),0xff))
     For j = 0 To 7
     If Bit.And(CRC1, 1) > 0 Then
         CRC1 =Bit.And( Bit.ShiftRight(CRC1,1),0x7fff)
        CRC1=Bit.Xor(CRC1, 0xa001)
        Else
         CRC1 =Bit.And( Bit.ShiftRight(CRC1,1),0x7fff)
    End If
    Next    'j
Next        'i
Return CRC1
End Sub

ta1dr · Oct 19, 2015

I tried BAJ and it is work..
010107DE000A----> CRC 17373 43DD hex

thanks for share

ahmadalibeck · Oct 19, 2015

Mr. taktrashe,

I really thank you, your code was very helpful.

When I used COM Port Monitor, I wondered why extra bytes are sent !! But soon later, I discovered that it was the PLC responding

It was a very nice moment.

ta1dr · Oct 20, 2015

also I tried this code it is is work too..you can send hex number in string and return value hex sting

my modbus data : 010107DE000A ----> crc DD43 ( expand modbus why different I dont know) but I want to this resuld..)

http://www.simplymodbus.ca/ try demo version..for check

B4X:

Sub Modbus_CRC(strInput As String) As String
    Dim RetCRC As String
    Dim RetStr As String

    Dim CRCREG As Int
    Dim MVAL As Int

    Dim R As Short
    Dim I As Short
    Dim A As Int
    Dim B As Int

    CRCREG = 0xFFFF

    For R = 0 To strInput.Length - 1 Step 2
        RetStr = strInput.SubString2(R, R + 2)
        MVAL = Bit.ParseInt(RetStr, 16)
    
        CRCREG = Bit.Xor(CRCREG, MVAL)
        CRCREG = Bit.And(CRCREG, 0xFFFF)

        For I = 1 To 8 Step 1
            If Bit.And(CRCREG, 0x01) = 1 Then
                CRCREG = Bit.Xor(Bit.UnsignedShiftRight(CRCREG, 1), 0xA001)
                CRCREG = Bit.And(CRCREG, 0xFFFF)
            Else
                CRCREG = Bit.UnsignedShiftRight(CRCREG, 1)
                CRCREG = Bit.And(CRCREG, 0xFFFF)
            End If
        Next
    Next

    A = Bit.And(CRCREG, 0xFF)
    B = Bit.And(CRCREG, 0xFF00)
    A = A * 256
    B = B / 256

    If (A + B) < 16 Then
        RetCRC = "000" & (A + B)
    Else If (A + B) < 256 Then
        RetCRC = "00" & Bit.ToHexString(A + B)
    Else If (A + B) < 4096 Then
        RetCRC = "0" & Bit.ToHexString(A + B)
    Else
        RetCRC = Bit.ToHexString(A + B)
    End If

    Return RetCRC.ToUpperCase
End Sub

Android Question Modbus CRC16 calculation

FreeWolF

Active Member

FreeWolF

Active Member

FreeWolF

Active Member

Erel

B4X founder

FreeWolF

Active Member

Erel

B4X founder

FreeWolF

Active Member

FreeWolF

Active Member

LucaMs

Expert

LucaMs

Expert

taktrashe

New Member

ta1dr

Member

ahmadalibeck

Member

ta1dr

Member

Similar Threads