Android Question Notifications stopped working (targetSdkVersion=26)

[martin24]

If I use the following in my manifest:

...
<uses-sdk android:minSdkVersion="17" android:targetSdkVersion="25"/>
...
AddPermission(android.permission.VIBRATE)

Then the following notification works without problems:

Dim n As Notification
n.Initialize
n.Icon = "icon"
n.SetInfo("This is the title", "and this is the body.", "") 'Change Main to "" if this code is in the main module.
n.Notify(1)

When I change to android:targetSdkVersion="26", then the notification is no longer displayed. I have also tried the NotificationBuilder with the same effect.

What do I miss here?

 

[NJDude]

Yes, notifications changed starting on SDK 26+, that's not a B4A problem.

 

[Star-Dust]

How can you solve?

 

[NJDude]

How can you solve?

Just target SDK < 26.

 

[Star-Dust]

How do you solve keeping SDK_Target at 26?
Because we have to adapt to the requirements for future prosism.
What is the solution

 

[NJDude]

How do you solve keeping SDK_Target at 26?
Because we have to adapt to the requirements for future prosism.
What is the solution

There's no problem still targeting SDK 22, and to get the notification libraries to work on SDK 26+ they will have to be updated to handle "Notification channels".

 

[Erel]

Relevant tutorial: https://www.b4x.com/android/forum/t...etsdkversion-minsdkversion.87610/#post-554210

You can use this code together with NotificationBuilder library to create a notification and set its channel:

Sub Button1_Click
   Dim nb As NotificationBuilder
   nb.Initialize
   nb.SmallIcon = "icon"
   nb.ContentTitle = "title"
   nb.ContentText = "content"
   Dim p As Phone
   If p.SdkVersion >= 26 Then
       Dim ctxt As JavaObject
       ctxt.InitializeContext
       Dim manager As JavaObject
       manager.InitializeStatic("android.app.NotificationManager")
       Dim Channel As JavaObject
       Dim ChannelVisibleName As String = Application.LabelName
       Channel.InitializeNewInstance("android.app.NotificationChannel", _
           Array("MyChannelId1", ChannelVisibleName, manager.GetField("IMPORTANCE_DEFAULT"))) 'change to IMPORTANCE_LOW to remove sounds
       manager = ctxt.RunMethod("getSystemService", Array("notification"))
       manager.RunMethod("createNotificationChannel", Array(Channel))
       Dim jo As JavaObject = nb
       jo.RunMethod("setChannelId", Array("MyChannelId1"))
   End If
   nb.Notify(1)
End Sub

 

[Star-Dust]

Thanks, I will use the code you posted.

Maybe I'm worried too much about the changes. But since I stayed a while back in the last have, I have the anxiety to recover the knowledge that I miss to get to SDK 26

 

[Peter Simpson]

Relevant tutorial: https://www.b4x.com/android/forum/t...etsdkversion-minsdkversion.87610/#post-554210

You can use this code together with NotificationBuilder library to create a notification and set its channel:

Sub Button1_Click
   Dim nb As NotificationBuilder
   nb.Initialize
   nb.SmallIcon = "icon"
   nb.ContentTitle = "title"
   nb.ContentText = "content"
   Dim p As Phone
   If p.SdkVersion >= 26 Then
       Dim ctxt As JavaObject
       ctxt.InitializeContext
       Dim manager As JavaObject
       manager.InitializeStatic("android.app.NotificationManager")
       Dim Channel As JavaObject
       Dim ChannelVisibleName As String = "My Channel"
       Channel.InitializeNewInstance("android.app.NotificationChannel", _
           Array("MyChannelId1", ChannelVisibleName, manager.GetField("IMPORTANCE_DEFAULT")))
       manager = ctxt.RunMethod("getSystemService", Array("notification"))
       manager.RunMethod("createNotificationChannel", Array(Channel))
       Dim jo As JavaObject = nb
       jo.RunMethod("setChannelId", Array("MyChannelId1"))
   End If
   nb.Notify(1)
End Sub

This code should also be added to the original notifications tutorial/post, or at least a link from the post above to the original tutorial/post.

 

[Erel]

I've added a link to this post here: https://www.b4x.com/android/forum/t...etsdkversion-minsdkversion.87610/#post-554210

 

[martin24]

tested successfully. Thanks for that solution.