Android Question [Solved] DJI - Read GimbalPitch

[schimanski]

Is it possible to read out the current gimbal pitch of the dji drone?
Thanks for help!

 

[Erel]

Were you able to run the DJI example:?

It should be possible with JavaObject.
Start with:
Het the gimbal object with:

Dim aircraftjo As JavaObject = aircraft
Dim gimbal As JavaObject = aircraftjo.RunMethod("getGimbal", Null)
If gimbal.IsInitialized Then
 
End If

You then need to call "setStateCallback with an event created with JavaObject.CreateEventFromUI with this class: "dji.common.gimbal.GimbalState$Callback".

The event raised will include a GimbalState parameter - args(0).

 

[schimanski]

Thank you! The following code seems to run:

    Dim aircraftjo As JavaObject = aircraft
    Dim gimbal As JavaObject = aircraftjo.RunMethod("getGimbal", Null)
    If gimbal.IsInitialized Then
        Dim cc As Object = gimbal.CreateEventFromUI("dji.common.gimbal.GimbalState$Callback", "callback", Null)
        gimbal.RunMethod("setStateCallback", Array As Object(cc))
        Wait For (gimbal) callback_Event (MethodName As String, Args() As Object)
        Log(Args(0))
    Else
        Log("Gimbal not available.")
    End If

The result is:

dji.common.gimbal.GimbalState@88a75585

But how is it possibel to read out the field in Args(0)?

 

[DonManfred]

But how is it possibel to read out the field in Args(0)?

this is a Class

DJI Mobile SDK Documentation

developer.dji.com

Dim gimbalstate As JavaObject = Args(0)
' Work with gimbalstate

 

[schimanski]

I tried to use the SDK Documentation, but

Dim gimbalstate As JavaObject = Args(0)

does not get me any further. I see, that the log of Args(0) changes with changing the gimbal-position. I'm too stupid to read out the information of the pitch in plaintext?

 

[schimanski]

Ok, I have it. Thank you for your efforts!
Short info: The gimbalPitch ist the pitch in relation to the horizon. So it is not necessary to offset it with the pitch of the drone.

    Dim aircraftjo As JavaObject = aircraft
    Dim gimbal As JavaObject = aircraftjo.RunMethod("getGimbal", Null)
    If gimbal.IsInitialized Then
        Dim cc As Object = gimbal.CreateEventFromUI("dji.common.gimbal.GimbalState$Callback", "callback", Null)
        gimbal.RunMethod("setStateCallback", Array As Object(cc))
        Wait For (gimbal) callback_Event (MethodName As String, Args() As Object)
        Dim gimbalstate As JavaObject= Args(0)
        Dim attitude As JavaObject = gimbalstate.RunMethod("getAttitudeInDegrees", Null)
        Dim Pitch As Float = attitude.RunMethod("getPitch", Null)
        Log("GimbalPitch:" & Pitch)
    Else
        Log("Gimbal not available.")
    End If