Android Question [SOLVED] GPS not working after HttpJob

[epneeh]

Hi

Sub Activity_Resume
    '//try experiment ------------------
    If alreadyversioncheck = False Then
       
        Dim j As HttpJob
        j.Initialize("",Me)
        j.Download("https://somesite.com/pvt/maps/ver.php")
        Wait For (j) jobdone(j As HttpJob)
        If j.Success Then
            Dim cloudver As Int = j.GetString
            If versi <> cloudver Then
               
                ToastMessageShow("Update your apps",True)
            End If
        Else
            ToastMessageShow("Koneksi error",True)
        End If
        j.Release
        alreadyversioncheck = True
    End If
    '//try experiment ------------------
   
    If Label1.Text = "" Then
        ProgressDialogShow2("Loading location...",False)
    End If
   
    If Starter.gps1.GPSEnabled =False  Then
        StartActivity(Starter.gps1.LocationSettingsIntent)
        Return
    Else
        Wait For MapFragment1_Ready
        log("Map is ready")
        gmap = MapFragment1.GetMap
        rp.CheckAndRequest(rp.PERMISSION_ACCESS_FINE_LOCATION)
        
        Wait For Activity_PermissionResult (Permission As String, Result As Boolean)
        If Result Then

       Else 

       End If
    End If
End Sub

If i add httpjob before checking gps is on or off, code execution stop at line 26, but when i remove httpjob (line 2 until 21) gps work fine, any help appreciate. Thanks in advance.

 

[Erel]

What does it mean that code execution stop? Put a breakpoint on line 27 and see whether it is reached.

 

[epneeh]

What does it mean that code execution stop? Put a breakpoint on line 27 and see whether it is reached.

I've already put log() on line 26, 28, 30 and 34 it never reach

 

[Erel]

There is no such thing that code just stops. I don't see the log statements and I don't see the log outputs so it is difficult to help you.

It can take a long time for the http request to be completed. As you have a call to Wait For it will wait until the requests completes or fails.

 

[epneeh]

Sori erel i've updated the code, see line 32, i think mapFragment1 is never ready, this is my log

*** Service (starter) Create ***
** Service (starter) Start **
** Activity (main) Create, isFirst = true **
** Activity (main) Resume **
*** Service (httputils2service) Create ***
** Service (httputils2service) Start **

 

[Erel]

I don't see how we can help you with the information you provided.

 

[epneeh]

ok, i upload my test project, i hope it helps you to analyze

 

[Erel]

The problem is that this line: Wait For MapFragment1_Ready is called long after the event was raised.

Change your code to:

Sub Activity_Create(FirstTime As Boolean)
    'Do not forget to load the layout file created with the visual designer. For example:
    'Activity.LoadLayout("Layout1")
    Activity.LoadLayout("main")
    Wait For MapFragment1_Ready
    Log("====Map is ready====")
    gmap = MapFragment1.GetMap
    rp.CheckAndRequest(rp.PERMISSION_ACCESS_FINE_LOCATION)
        
    Wait For Activity_PermissionResult (Permission As String, Result As Boolean)
    If Result Then
        gmap.MyLocationEnabled = True
        If gmap.IsInitialized Then
            Do While gmap.MyLocation.IsInitialized = False
                Sleep(100)
            Loop
            Dim cp As CameraPosition
            cp.Initialize(gmap.MyLocation.Latitude,gmap.MyLocation.Longitude,15)
            gmap.AnimateCamera(cp)
        End If
    End If
End Sub

Sub Activity_Resume
    
    '//try experiment -----------------
    Dim j As HttpJob
    j.Initialize("",Me)
    j.Download("https://epneeh.com/pvt/maps/ver.php")
    Wait For (j) jobdone(j As HttpJob)
    If j.Success Then
        Dim cloudver As Int = j.GetString
        If versi <> cloudver Then
               
            ToastMessageShow("Update your apps",True)
        End If
    Else
        ToastMessageShow("Koneksi error",True)
    End If
    j.Release
    If Starter.gps1.GPSEnabled =False  Then
        StartActivity(Starter.gps1.LocationSettingsIntent)
        Return
    End If

End Sub

 

[epneeh]

The problem is that this line: Wait For MapFragment1_Ready is called long after the event was raised.

Change your code to:

Sub Activity_Create(FirstTime As Boolean)
    'Do not forget to load the layout file created with the visual designer. For example:
    'Activity.LoadLayout("Layout1")
    Activity.LoadLayout("main")
    Wait For MapFragment1_Ready
    Log("====Map is ready====")
    gmap = MapFragment1.GetMap
    rp.CheckAndRequest(rp.PERMISSION_ACCESS_FINE_LOCATION)
       
    Wait For Activity_PermissionResult (Permission As String, Result As Boolean)
    If Result Then
        gmap.MyLocationEnabled = True
        If gmap.IsInitialized Then
            Do While gmap.MyLocation.IsInitialized = False
                Sleep(100)
            Loop
            Dim cp As CameraPosition
            cp.Initialize(gmap.MyLocation.Latitude,gmap.MyLocation.Longitude,15)
            gmap.AnimateCamera(cp)
        End If
    End If
End Sub

Sub Activity_Resume
   
    '//try experiment -----------------
    Dim j As HttpJob
    j.Initialize("",Me)
    j.Download("https://epneeh.com/pvt/maps/ver.php")
    Wait For (j) jobdone(j As HttpJob)
    If j.Success Then
        Dim cloudver As Int = j.GetString
        If versi <> cloudver Then
              
            ToastMessageShow("Update your apps",True)
        End If
    Else
        ToastMessageShow("Koneksi error",True)
    End If
    j.Release
    If Starter.gps1.GPSEnabled =False  Then
        StartActivity(Starter.gps1.LocationSettingsIntent)
        Return
    End If

End Sub

thanks erel it solved now, i put Wait For MapFragment1_Ready right after load its layout, you're the man