Android Question [Solved]How to get Date and Time difference between two dateTimes

[AndroidMadhu]

Hello,
I want to calculate or how can I get a date difference[in Hours and Minutes] between two dates with times.
Any example will be very helpful.

Thanks

 

[udg]

DateUtils

 

[Erel]

DateUtils.PeriodBetween is probably the correct answer as you said "date difference".

If you are interested in the hours and minutes only (no days or months) then you should simply subtract the two values and use this: https://www.b4x.com/android/forum/threads/b4x-convert-milliseconds-to-string.89851/#content

 

[Num3]

Use DateUtils like udg mentioned.

Hope this helps:

    Dim timeleft As Period = DateUtils.PeriodBetween( DateTime.Now,DateTime.Now + DateTime.TicksPerHour * 2.3)
    Log($"$2{timeleft.hours}:$2{timeleft.Minutes}:$2{timeleft.Seconds}"$ )

 

[Mahares]

get a date difference[in Hours and Minutes] between two dates with times.

Here is how I would have done it to comply with your question details:

Sub TimeDiffHoursMinutes(ds As String, de As String) As String
    Dim p As Period
    DateTime.DateFormat="yyyy-MM-dd HH:mm:ss"
    p=DateUtils.PeriodBetweenindays(DateTime.DateParse(ds), DateTime.DateParse(de))
    Return $"${(p.Days)*24 +p.hours}:$2.0{p.Minutes}:$2.0{p.Seconds}"$    
End Sub

To test ( if no need for seconds, remove them from code):

Log(TimeDiffHoursMinutes("2021-02-18 17:30:00", "2021-02-18 19:48:00"))

 

[Erel]

Sorry to say but only my answer is 100% correct.

Post #4 is wrong as it ignores the days and months.
Post #5 is mostly correct but it assumes that there are 24 hours per day. There are also days with 23 hours or 25 hours.
(it is also better to accept ticks instead of string)

If you are interested in difference measured in hours and minutes then you shouldn't use DateUtils.PeriodBetween. This one solves a more complicated problem.

 

[udg]

only my answer

C'mon, post #2 is as much correct as yours..
Ok, it was a bit too succinct and it's based on the same assumption of dates+times as in your first sentence, but it earned some merit too.
And , for once, I was quicker than you

ps: obviously joking..and almost ready for some jogging..hehehe

 

[Erel]

C'mon, post #2 is as much correct as yours..

No. DateUtils isn't needed here.

Sub AppStart (Args() As String)
    Log(HoursMinutesAndSecondsBetweenToTicks(DateTime.Now, DateTime.DateParse("02/23/2021")))
End Sub

Sub HoursMinutesAndSecondsBetweenToTicks (StartTime As Long, EndTime As Long) As String
    Return ConvertMillisecondsToString(EndTime - StartTime)
End Sub

Sub ConvertMillisecondsToString (t As Long) As String
    Dim Hours, minutes, seconds As Int
    Hours = t / DateTime.TicksPerHour
    minutes = (t Mod DateTime.TicksPerHour) / DateTime.TicksPerMinute
    seconds = (t Mod DateTime.TicksPerMinute) / DateTime.TicksPerSecond
    Return $"$1.0{Hours}:$2.0{minutes}:$2.0{seconds}"$
End Sub

 

[udg]

How many coffees did you sip at this time today? I had to re-read the first post a few times before absorbing this: date difference[in Hours and Minutes] !
Anyway, maybe a short note to your example code could be useful: DateUtils.DateParse will set the time to 00:00:00 so the code "as is" computes the difference between Now (date and current time) to "new date" at midnight.

Eventually a similar note could be added to the help window when hovering on that function.

 

[Num3]

There are also days with 23 hours or 25 hours.

I guess I need more coffee ? ?

 

[Erel]

It wasn't a joke. These are the days where the time zone offset changes because of the daylight saving (DST).

 

[udg]

Once you had your cup of coffee (better two cups), you may want to read this article. It's just one out of several ones you may find on the Internet.
This one let you compute day duration for any date.

 

[Num3]

It wasn't a joke. These are the days where the time zone offset changes because of the daylight saving (DST).

I know, my example was based on my own needs (countdown timer with max 1 hour period).
But indeed your code is more reliable, it takes into consideration DST and the user changing time zone!

 

[Num3]

Once you had your cup of coffee (better two cups), you may want to read this article. It's just one out of several ones you may find on the Internet.
This one let you compute day duration for any date.

I miss the Swatch Beat time
No time zones and no DST to hassle you

 

[Didier9]

It wasn't a joke. These are the days where the time zone offset changes because of the daylight saving (DST).

And if you are interested in minutes and seconds over a long period, you need to factor in leap seconds...

Be careful, precision timing is a rabbit hole! (speaking for a friend...)

 

[AndroidMadhu]

f you are interested in the hours and minutes only (no days or months) then you should simply subtract the two values and use this: https://www.b4x.com/android/forum/threads/b4x-convert-milliseconds-to-string.89851/#content

@Erel.. resolved the issue using above link...

Thanks for your advice..

Thanks