Android Code Snippet [B4X] Get absolute top value of a View

Private Sub GetAbsViewTop(xView As B4XView) As Int
    Dim Top As Int = xView.top
    Dim Parent As B4XView = xView.Parent
    Do While Parent.IsInitialized = True
        Top = Top + Parent.Top
        Parent = Parent.Parent
    Loop
    Return Top
End Sub

Tested very little. Also, maybe someone has already published a snippet like this.

 

[LucaMs]

Weird thing: that function, in a B4A project with an IME object, returns as Parent type:

anywheresoftware.b4a.objects.IME$ExtendedBALayout

and this creates problems that I will try to solve.

 

[Alexander Stolte]

Also, maybe someone has already published a snippet like this.

Code from my ASPopupMenu:

Sub ViewScreenPosition (view As B4XView) As Int()
    
    Dim leftTop(2) As Int
    #IF B4A
    Dim JO As JavaObject = view
    JO.RunMethod("getLocationOnScreen", Array As Object(leftTop))
    leftTop(1) = leftTop(1) - view.Height
    #Else If B4I
    'https://www.b4x.com/android/forum/threads/absolute-position-of-view.56821/#content
    Dim parent As B4XView = view
    Do While GetType(parent) <> "B4IMainView"
        Dim no As NativeObject = parent
        leftTop(0) = leftTop(0) + parent.Left
        leftTop(1) = leftTop(1) + parent.Top
        parent = no.GetField("superview")
   Loop
    #Else
    Dim parent As B4XView = view
   Do While parent.IsInitialized
       leftTop(0) = leftTop(0) + parent.Left
       leftTop(1) = leftTop(1) + parent.Top
       parent = parent.Parent
   Loop
    #End If

    Return Array As Int(leftTop(0), leftTop(1))
End Sub

 

[LucaMs]

Code from my ASPopupMenu:

It seems that the B4A version does not work well.

I attach a project; I slightly modified your function to get only the Top value (I could have done otherwise) and changed its name, but I did not touch the code.

In the project, the click on the button should align two labels at the same top of two B4XFloatTextFields but the values are very different.

 

[Alexander Stolte]

It seems that the B4A version does not work well.

But it works. Only instead of the top value, the function returns the bottom value. You have to do the following:

Private Sub Button1_Click
    Label1.Top = GetAbsTop(B4XFloatTextField2.mBase) - B4XFloatTextField2.mBase.Height
    Label2.Top = GetAbsTop(B4XFloatTextField3.mBase) - B4XFloatTextField3.mBase.Height
End Sub

 

[LucaMs]

But it works. Only instead of the top value, the function returns the bottom value

Excellent. It's all your fault for getting the name wrong (LeftBottom)

 

[LucaMs]

Excellent. It's all your fault for getting the name wrong (LeftBottom)

No, wait, then there is a major problem. The function returns the Bottom if the language is B4A but returns the Top if it is B4J or B4i.

 

[LucaMs]

Asked ChatGPT:

 

[LucaMs]

However, despite the official documentation and ChatGPT's answer, it seems to be exactly as you wrote, Alexander, that in the case of B4A the function returns the Bottom, not the Top.

In order for the function not to be "inconsistent", you should add a line:

    #IF B4A
        Dim JO As JavaObject = view
        JO.RunMethod("getLocationOnScreen", Array As Object(LeftTop))
        LeftTop(1) = LeftTop(1) - view.Height ' <------
    #Else If B4I

 

[Alexander Stolte]

In order for the function not to be "inconsistent", you should add a line:

I have revised the code snippet, thanks luca.