B4J Tutorial [BANanoWebix] Creating Multi-Page Apps - Part 4

Mashiane · Jul 24, 2019

Detecting Double Click / KeyPress on the Data-Table

As we want to detect a double click on the data-table and also a keypress e.g. the delete / insert keys, we attach events to the data-table before we conclude its creation.

B4X:

'add events to the dtpositions
    Dim arguements As Object
    dtpositions.DataTable.OnItemDblClick(BANano.CallBack(Me,"dtpositions_dblclick",Array(arguements)))
    dtpositions.DataTable.OnKeyPress(BANano.CallBack(Me,"dtpositions_keypress",Array(arguements)))

So when an entry in the data-table is double-clicked (we have set row selection), the edit mode is activated and the form is updated with the contents of the selected grid item.

B4X:

Sub dtpositions_dblclick(arguements As Object)
    ' turn edit on
    Dim item As Map = Page.GetSelectedItem("dtpositions",False)
    If item <> Null Then
        Page.SetValues("formpositions", item)
        Mode = "E"
        Page.HideMulti(Array("btnnewposition"))
        Page.ShowMulti(Array("btncancelposition","btnsaveposition","btndeleteposition"))
        Page.Focus("positions.id")
    End If
End Sub

The form is linked to the grid using the 'name' property of the input elements. On edit we hide the new icon and show cancel, save and delete.

When a key is pressed, for example, the insert key, the 'addition' mode is activated, this prepares the form for entry. On the other hand when the delete keyboard key is pressed, a confirmation is provided to ask the user if they want to delete the record.

B4X:

Sub dtpositions_keypress(arguements As Object)
    Dim kCode As Int = BANano.parseInt(arguements)
    Select Case kCode
        Case 45
            'insert
            btnnewposition_click
        Case 46
            'delete
            Dim confirmresult As Boolean = False
            Dim cb As BANanoObject = BANano.CallBack(Me,"dtpositions_delete",Array(confirmresult))
            Page.Confirm(cb, "Confirm Delete", "Are you Sure Want to delete the selected position? You will not be able to undo your changes. Continue?")
    End Select
End Sub

Sub dtpositions_delete(confirmresult As Boolean)
    If confirmresult = False Then Return
    Dim item As Map = Page.GetSelectedItem("dtpositions",False)
    If item = Null Then Return
    Dim did As String = item.Get("id")
    '
    Dim alasql As BANanoAlaSQL
    alasql.Initialize
    Dim rs As AlaSQLResultSet = alasql.DeleteWhere("positions", CreateMap("id":did))
    rs.Result = ourclients.ExecuteWait(rs.query, rs.args)
    Page.clear("formpositions")
    Page.ClearValidation("formpositions")
    Page.Show("btnnewposition")
    Page.HideMulti(Array("btncancelposition", "btnsaveposition", "btndeleteposition"))
    LoadPositions
End Sub

On confirmation, the selected record is read from the data-table, the 'id' value is read, the record is deleted from the underlying database table and the grid listing refreshed.

If on the other hand the 'insert' key is pressed, the 'addition' of a new record is activated. The 'max' of the 'id' column is read, this is incremented by 1 and the form is updated for data entry.

B4X:

Sub btnnewposition_click
    Page.Hide("btnnewposition")
    Page.Show("btncancelposition")
    Page.Show("btnsaveposition")
    Page.Hide("btndeleteposition")
    
    'set the mode
    Mode = "A"
    'clear the form
    Page.Clear("formpositions")
    Page.ClearValidation("formpositions")
    'set the focus to element
    Page.Focus("positions.id")
    'get next available id
    'initialize the helper class
    Dim alaSQL As BANanoAlaSQL
    alaSQL.Initialize
    'generate the create table sql
    Dim rs As AlaSQLResultSet = alaSQL.GetMax("positions", "id")
    'execute the create table command
    rs.Result = ourclients.ExecuteWait(rs.query, rs.args)
    Dim lastID As Int
    If rs.result.Size = 0 Then
        lastID = 0
    Else
        'get the record
        Dim rec As Map = rs.result.get(0)
        Dim lID As String = rec.GetDefault("id","0")
        lastID = BANano.parseint(lID)
    End If
    lastID = lastID + 1
    Page.SetValue("positions.id", lastID)
End Sub

Whilst the 'id' input element is shown here for brevity, in real world situations, to avoid manual editing, this can be hidden / rather disabled.

Mashiane · Jul 24, 2019

Saving Records

Depending on the mode being active, whether 'A' for addition or 'E' for editing, saving the record will perform an insert on 'A' and an update when 'E'

B4X:

Sub btnsaveposition_click
    'validate the form
    Dim bValidate As Boolean = Page.Validate("formpositions")
    If bValidate = False Then
        Page.Message_Error("There are some missing contents for this record, please rectify!")
        Return
    End If
    
    Select Case Mode
        Case "A"
            'adding a new position
            Dim rec As Map = Page.GetValues("formpositions")
            Dim alaSQL As BANanoAlaSQL
            alaSQL.Initialize
            Dim rs As AlaSQLResultSet = alaSQL.Insert("positions", rec)
            rs.Result = ourclients.ExecuteWait(rs.query, rs.args)
        Case "E"
            'updating an existing position
            Dim rec As Map = Page.GetValues("formpositions")
            Dim eid As String = rec.Get("id")
            Dim alaSQL As BANanoAlaSQL
            alaSQL.Initialize
            Dim rs As AlaSQLResultSet = alaSQL.UpdateWhere("positions", rec, CreateMap("id":eid))
            rs.Result = ourclients.ExecuteWait(rs.query, rs.args)
    End Select
    Mode = ""
    Page.clear("formpositions")
    Page.ClearValidation("formpositions")
    Page.Show("btnnewposition")
    Page.Hide("btncancelposition")
    Page.Hide("btnsaveposition")
    Page.Hide("btndeleteposition")
    LoadPositions
End Sub

The form contents are validated. If they are valid, depending on the mode, an insert takes place or an update takes place.

Where duplicates should be avoided, a next step after the validation can be undertaken to check if duplicates will not be created on inserts of new records.

Part 5 of this will delve on the clients screen and how the positions and the cities data can be used to load selects/combo boxes.

Ta!

B4J Tutorial [BANanoWebix] Creating Multi-Page Apps - Part 4

Mashiane

Expert

Mashiane

Expert

Similar Threads