B4R Question ESP32 to mimic B4APeripheral

[Yanik Freeman]

Hi,

Not a B4R question per see but I'm wondering if anyone out there has some insight as to why the Arduino ESP32 code below does not seem to connect to the centrals. This is an attempt to modify for native Arduino iOS compatibility from code in this thread:

BLE Chat with ESP32

I wrote an application as a chat using BLE between Android and ESP32. ( using same sample code ) The Android apk find the ESP32 than connect and receive a "Wellcome" text. Then everthing that you write and send to ESP 32 comes back. I´d like to write the ESP32 application in B4R. Someone...

www.b4x.com

Note: The author later adapted for iOS in the B4X environment but one of the requirements of a larger project I would like to scale this up for is that the firmware component needs to remain in Arduino. All the mobile components of my project are developed in B4X.

If I run a BLE scanner I get identical advertised services and components from an Android phone running as peripheral from this thread:

BLE Peripheral

A BLE connection is made between a central device and a peripheral device. In most cases the Android device will be the central device. Beacons, heart rate sensors and other BLE devices are implemented as peripheral device. However the Android device can also implement the peripheral role. This...

www.b4x.com

/*
    Video: https://www.youtube.com/watch?v=oCMOYS71NIU
    Based on Neil Kolban example for IDF: https://github.com/nkolban/esp32-snippets/blob/master/cpp_utils/tests/BLE%20Tests/SampleNotify.cpp
    Ported to Arduino ESP32 by Evandro Copercini

   Create a BLE server that, once we receive a connection, will send periodic notifications.
   The service advertises itself as: 6E400001-B5A3-F393-E0A9-E50E24DCCA9E
   Has a characteristic of: 6E400002-B5A3-F393-E0A9-E50E24DCCA9E - used for receiving data with "WRITE"
   Has a characteristic of: 6E400003-B5A3-F393-E0A9-E50E24DCCA9E - used to send data with  "NOTIFY"

   The design of creating the BLE server is:
   1. Create a BLE Server
   2. Create a BLE Service
   3. Create a BLE Characteristic on the Service
   4. Create a BLE Descriptor on the characteristic
   5. Start the service.
   6. Start advertising.

   In this example rxValue is the data received (only accessible inside that function).
   And txValue is the data to be sent, in this example just a byte incremented every second.
*/
#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>

BLEServer *pServer = NULL;
BLECharacteristic * pTxCharacteristic;
bool deviceConnected = false;
bool oldDeviceConnected = false;
uint8_t txValue = 0;
bool flag_wait_resp = true;


// See the following for generating UUIDs:
// https://www.uuidgenerator.net/

//#define SERVICE_UUID           "00000001-B5A3-F393-E0A9-E50E24DCCA9E" // UART service UUID
//#define CHARACTERISTIC_UUID_RX "00001002-B5A3-F393-E0A9-E50E24DCCA9E"
//#define CHARACTERISTIC_UUID_TX "00001003-B5A3-F393-E0A9-E50E24DCCA9E"

//modified to mimic B4APeripheral for iOS compatibility and echo back, refer to:
//https://www.b4x.com/android/forum/threads/ble-chat-with-esp32.111996/
//https://www.b4x.com/android/forum/threads/ble-peripheral.84051/

#define SERVICE_UUID             "00000001-0000-1000-8000-00805F9B34FB"
#define CHARACTERISTIC_UUID_RX   "00001002-0000-1000-8000-00805F9B34FB" //B4X Writable characteristic
#define CHARACTERISTIC_UUID_TX   "00001001-0000-1000-8000-00805F9B34FB" //B4X Readable / notifiable characteristic


class MyServerCallbacks: public BLEServerCallbacks {
    void onConnect(BLEServer* pServer) {
      deviceConnected = true;
    };

    void onDisconnect(BLEServer* pServer) {
      deviceConnected = false;
    }
};

class MyCallbacks: public BLECharacteristicCallbacks {
    void onWrite(BLECharacteristic *pCharacteristic) {
      std::string rxValue = pCharacteristic->getValue();

      if ( rxValue == "OK:" ){
        flag_wait_resp = false;
        // acknowledge receiving information
      }
      if ( rxValue != "OK:" ){
        // echo the text received
        pTxCharacteristic->setValue(rxValue);
        pTxCharacteristic->notify();
      }
      if (rxValue.length() > 0) {
        Serial.println("*********");
        Serial.print("Received Value: ");
        for (int i = 0; i < rxValue.length(); i++){
          Serial.print(rxValue[i]);
          
        }

        Serial.println();
        Serial.println("*********");
      }
    }
};

void setup() {
  //Serial.begin(115200);
  Serial.begin(9600);

  // Create the BLE Device
  BLEDevice::init("B4APeripheral");

  // Create the BLE Server
  pServer = BLEDevice::createServer();
  pServer->setCallbacks(new MyServerCallbacks());

  // Create the BLE Service
  BLEService *pService = pServer->createService(SERVICE_UUID);

  // Create a BLE Characteristic
  //pTxCharacteristic = pService->createCharacteristic(
  //                                      CHARACTERISTIC_UUID_TX,
  //                                      BLECharacteristic::PROPERTY_NOTIFY
  //                                  );

  pTxCharacteristic = pService->createCharacteristic(
                                        CHARACTERISTIC_UUID_TX,
                                        BLECharacteristic::PROPERTY_READ |
                                        BLECharacteristic::PROPERTY_NOTIFY
                                    );
                      
  pTxCharacteristic->addDescriptor(new BLE2902());
 
  BLECharacteristic * pRxCharacteristic = pService->createCharacteristic(
                                             CHARACTERISTIC_UUID_RX,
                                            BLECharacteristic::PROPERTY_WRITE
                                        );

  pRxCharacteristic->setCallbacks(new MyCallbacks());

  // Start the service
  pService->start();

  // Start advertising
  pServer->getAdvertising()->start();
  Serial.println("Waiting for a client connection to notify...");
}

void loop() {

    if (deviceConnected && flag_wait_resp ) {
//        pTxCharacteristic->setValue(&txValue, 1);
        pTxCharacteristic->setValue("device connected");
        pTxCharacteristic->notify();
//        txValue++;
            delay(1000); // send until acknowledge from cellphone
    }

    // disconnecting
    if (!deviceConnected && oldDeviceConnected) {
        delay(500); // give the bluetooth stack the chance to get things ready
        pServer->startAdvertising(); // restart advertising
        Serial.println("start advertising");
        oldDeviceConnected = deviceConnected;
    }
    // connecting
    if (deviceConnected && !oldDeviceConnected) {
        // do stuff here on connecting
        oldDeviceConnected = deviceConnected;
    }
}

Thanks!

 

[Yanik Freeman]

I am still unable to connect using BleCentral as coded but here is a hack that works in both B4A and B4i!

...and...

Pay close attention to the case of UUID in all cases (no pun intended).

Note: ESP32 as a peripheral only seems to allow one connection at a time