B4A Library FusedLocationProvider

Sub Process_Globals
    'These global variables will be declared once when the application starts.
    'These variables can be accessed from all modules.
  

    Private FusedLocationProvider1 As FusedLocationProvider
    Private LastLocation As Location  
  
End Sub

Sub Globals
    'These global variables will be redeclared each time the activity is created.
    'These variables can only be accessed from this module.

    Private LblLastLocation As Label  
End Sub


Sub Activity_Create(FirstTime As Boolean)

    If FirstTime Then
        FusedLocationProvider1.Initialize("FusedLocationProvider1")
    End If  
  
    'Do not forget to load the layout file created with the visual designer. For example:
    Activity.LoadLayout("StartEndTravel")

    If LastLocation.IsInitialized Then
        UpdateUI
    End If  
End Sub

Sub Activity_Resume
    '    attempt to connect to the location services
    '    after calling Connect we are waiting for either ConnectionFailed or ConnectionSuccess events
    FusedLocationProvider1.Connect
End Sub

Sub Activity_Pause (UserClosed As Boolean)
    FusedLocationProvider1.Disconnect
End Sub

Sub FusedLocationProvider1_ConnectionFailed(ConnectionResult1 As Int)
    Log("FusedLocationProvider1_ConnectionFailed")
  
    '    the FusedLocationProvider ConnectionResult object contains the various CoonectionResult constants
  
    Select ConnectionResult1
        Case FusedLocationProvider1.ConnectionResult.NETWORK_ERROR
            '    a network error has occurred, this is likely to be a recoverable error
            '    so try to connect again
            FusedLocationProvider1.Connect
        Case Else
            '    TODO handle other errors
    End Select
End Sub

Sub FusedLocationProvider1_ConnectionSuccess
    Log("FusedLocationProvider1_ConnectionSuccess")
    Dim LocationRequest1 As LocationRequest
    LocationRequest1.Initialize
    LocationRequest1.SetInterval(1000)    '    1000 milliseconds
    LocationRequest1.SetPriority(LocationRequest1.Priority.PRIORITY_HIGH_ACCURACY)
    LocationRequest1.SetSmallestDisplacement(1)    '    1 meter
  
    Dim LocationSettingsRequestBuilder1 As LocationSettingsRequestBuilder
    LocationSettingsRequestBuilder1.Initialize
    LocationSettingsRequestBuilder1.AddLocationRequest(LocationRequest1)
    FusedLocationProvider1.CheckLocationSettings(LocationSettingsRequestBuilder1.Build)
  
    FusedLocationProvider1.RequestLocationUpdates(LocationRequest1)
End Sub

Sub FusedLocationProvider1_ConnectionSuspended(SuspendedCause1 As Int)
    Log("FusedLocationProvider1_ConnectionSuspended")
  
    '    the FusedLocationProvider SuspendedCause object contains the various SuspendedCause constants
  
    Select SuspendedCause1
        Case FusedLocationProvider1.SuspendedCause.CAUSE_NETWORK_LOST
            '    TODO take action
        Case FusedLocationProvider1.SuspendedCause.CAUSE_SERVICE_DISCONNECTED
            '    TODO take action
    End Select
End Sub

Sub FusedLocationProvider1_LocationChanged(Location1 As Location)
    Log("FusedLocationProvider1_LocationChanged")
    LastLocation=Location1
    UpdateUI
End Sub

Sub FusedLocationProvider1_LocationSettingsChecked(LocationSettingsResult1 As LocationSettingsResult)
    Log("FusedLocationProvider1_LocationSettingsChecked")
    Dim LocationSettingsStatus1 As LocationSettingsStatus=LocationSettingsResult1.GetLocationSettingsStatus
    Select LocationSettingsStatus1.GetStatusCode
        Case LocationSettingsStatus1.StatusCodes.RESOLUTION_REQUIRED
            Log("RESOLUTION_REQUIRED")
            '    device settings do not meet the location request requirements
            '    a resolution dialog is available to enable the user to change the settings
            Msgbox("It looks like that you have disabled GPS. On the next screen, it will ask you to enable GPS. Please choose 'Yes', Do not use the option 'Never'","GPS is disabled")
            LocationSettingsStatus1.StartResolutionDialog("LocationSettingsResult1")
        Case LocationSettingsStatus1.StatusCodes.SETTINGS_CHANGE_UNAVAILABLE
            Log("SETTINGS_CHANGE_UNAVAILABLE")
            '    device settings do not meet the location request requirements
            '    a resolution dialog is not available to enable the user to change the settings
            Msgbox("Unable to listen for location updates, device does not meet the requirements.", "Problem")
            Activity.Finish
        Case LocationSettingsStatus1.StatusCodes.SUCCESS
            Log("SUCCESS")
            '    device settings meet the location request requirements
            '    no further action required
    End Select
End Sub

Sub LocationSettingsResult1_ResolutionDialogDismissed(LocationSettingsUpdated As Boolean)
    Log("LocationSettingsResult1_ResolutionDialogDismissed")
    If Not(LocationSettingsUpdated) Then
        '    the user failed to update the device settings to meet the location request requirements
            Msgbox("Unable to listen for location updates, you failed to enable the required device settings.", "Problem")
        Activity.Finish
    End If
End Sub

Sub UpdateUI
    'Label LblLastLocation is used to display the lat an long
    LblLastLocation.Text="Date : "&DateTime.Date(LastLocation.Time)& "  Time : "&DateTime.Time(LastLocation.Time)

End Sub

#Region  Project Attributes 
	#ApplicationLabel: FusedLocationProvider example
	#VersionCode: 1
	#VersionName: 
	'SupportedOrientations possible values: unspecified, landscape or portrait.
	#SupportedOrientations: unspecified
	#CanInstallToExternalStorage: False
	#AdditionalRes: C:\Users\martin\AppData\Local\Android\sdk\extras\google\google_play_services\libproject\google-play-services_lib\res, com.google.android.gms
	#AdditionalJar: android-support-v4.jar
#End Region

#AdditionalJar: android-support-v4.jar

#AdditionalJar: android-support-v4.jar

 If Location1.Latitude = 0 Or Location1.Longitude = 0 Then
    Dim result As Int
    result = Msgbox2("try another mode ?","Error GPS ! ","OK","","NO",Null)
    If result = DialogResponse.POSITIVE Then
    Gps1.Initialize("Gps")
    Gps1.Start(0,0)
    FusedLocationProvider1.Disconnect
    ProgressDialogShow2(ResourceStrings.Get("Apps_Wait"),True)
    If result = DialogResponse.NEGATIVE Then
    FusedLocationProvider1.Connect
    Gps1.Stop
    End If