Android Question Hiding html element from webview before page load

sorex said:

I see that you can set the useragent string with the webviewsetting library.

then you can set it to "androidapp" or something and with a small mod in the php code you can add an extra class or style to those 4 objects to hide them when the useragent is "androidapp".

All other options client options won't help as they occur when the content is already shown (unless you force the (pre)loading overlay on every page)

Click to expand...

sorex said:

this works fine and shows test on my desktop and nothing on my android phone

B4X:

Sub Globals
    Dim wv As WebView
    Dim wvs As WebViewSettings
End Sub

Sub Activity_Create(FirstTime As Boolean)
    wv.Initialize("wv")
    wvs.setUserAgentString(wv,"androidapp")
    wv.LoadUrl("http://mytesturl/test.php")      
    Activity.AddView(wv,0,0,100%x,100%y)
End Sub

PHP:

<?php
$hideStyle="";
if($_SERVER['HTTP_USER_AGENT']=="androidapp"){$hideStyle="style='display:none'";}
?>

<div <?php echo $hideStyle?>>test</div>

Click to expand...

stevel05 said:

Have you tried Overriding the Url, downloading the page text and updating it before displaying as HTML?

Click to expand...

stevel05 said:

Something like this:

B4X:

#Region  Project Attributes
    #ApplicationLabel: B4A Example
    #VersionCode: 1
    #VersionName:
    'SupportedOrientations possible values: unspecified, landscape or portrait.
    #SupportedOrientations: unspecified
    #CanInstallToExternalStorage: False
#End Region

#Region  Activity Attributes
    #FullScreen: False
    #IncludeTitle: True
#End Region

Sub Process_Globals
    'These global variables will be declared once when the application starts.
    'These variables can be accessed from all modules.

End Sub

Sub Globals
    'These global variables will be redeclared each time the activity is created.
    'These variables can only be accessed from this module.

    Private WebView1 As WebView
End Sub

Sub Activity_Create(FirstTime As Boolean)
    'Do not forget to load the layout file created with the visual designer. For example:
    Activity.LoadLayout("1")
    WebView1.LoadUrl("http://beisat.com/en/")

End Sub

Sub Activity_Resume

End Sub

Sub Activity_Pause (UserClosed As Boolean)

End Sub


Sub WebView1_OverrideUrl (Url As String) As Boolean
    Log(Url)
   
    Dim Job As HttpJob
    Job.Initialize("Job",Me)
    Job.Download(Url)

   
    Return True
End Sub

Private Sub JobDone(j As HttpJob)
    If j.Success Then
        Log(j.GetString)
        Log("Loading")
        '
        'Add your script block before displaying
        '
        WebView1.LoadHtml(j.GetString)
    End If
End Sub

Click to expand...

sorex said:

Won't that create multiple sessions?

also postings inbetween will get lost.

Click to expand...

sorex said:

Can you enable a preloading animation in the webshop?

Than you can abuse that to remove those elements before you hide the preloading overlay.

Click to expand...

Sub Globals
    Private xui As XUI
    Private WebView1 As WebView
    Private we As WebViewExtras
    Private p As B4XView
    Private inProgress As Boolean
End Sub

Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("a")
    ShowProgress
    WebView1.LoadUrl("https://beisat.com/en/")
End Sub

Sub WebView1_PageFinished (Url As String)
    we.executeJavascript(WebView1,"document.getElementsByClassName('customer-signin-module')[0].style.display = 'none';")
    we.executeJavascript(WebView1,"document.getElementsByClassName('left-nav-trigger')[0].style.display = 'none';")
    we.executeJavascript(WebView1,"document.getElementsByClassName('shopping-cart-module')[0].style.display = 'none';")
    we.executeJavascript(WebView1,"document.getElementsByClassName('language-selector-wrapper')[0].style.display = 'none';")
    p.SetVisibleAnimated(0,False)
    p.RemoveViewFromParent
    inProgress =False
End Sub

Sub WebView1_OverrideUrl (Url As String) As Boolean
    ShowProgress
End Sub

Sub ShowProgress
    If inProgress = True Then Return
    inProgress = True
    p = xui.CreatePanel("pnl")
    p.Color = xui.Color_ARGB(150,255,255,255)
    Activity.AddView(p,WebView1.Left, WebView1.Top, WebView1.Width, WebView1.Height)
    p.SetVisibleAnimated(0,True)
End Sub

Sub pnl_Click
  
End Sub