B4J Library InlineEditing - extends B4XTable with inline editing features

Private Sub MainForm_Resize (Width As Double, Height As Double)
    ie.TableResized
End Sub

Sub B4XTable1_CellClicked (ColumnId As String, RowId As Long)
    'avoid calling ie.CellClicked if the column is not editable.
    ie.CellClicked(ColumnId, RowId)
End Sub

Sub B4XTable1_DataUpdated
    ie.DataUpdated
End Sub

Private Sub IE_EnterEditMode (FC As FocusedCell)
    'FC.PrevValue holds the current value. It can also be used later to revert changes
    Select FC.ColumnId
        Case "Number"
            B4XPlusMinus1.SetNumericRange(0, 100, 1)
            B4XPlusMinus1.SelectedValue = FC.PrevValue
            FC.View = B4XPlusMinus1.mBase
        Case "String"
            SetTextField
            TextField1.Text = FC.PrevValue
            FC.View = TextField1
        Case "Color"
            B4XPlusMinus1.SetStringItems(ColorsList)
            B4XPlusMinus1.SelectedValue = FC.PrevValue
            FC.View = B4XPlusMinus1.mBase
        Case "Date"
            SetTextField
            TextField1.Text = DateTime.Date(FC.PrevValue)
            FC.View = TextField1
    End Select
End Sub

Private Sub IE_GetUpdatedValue (FC As FocusedCell) As Object
    Select FC.ColumnId
        Case "Number"
            Return B4XPlusMinus1.SelectedValue
        Case "String"
            Return TextField1.Text
        Case "Color"
            Return B4XPlusMinus1.SelectedValue
        Case "Date"
            Try
                Return DateTime.DateParse(TextField1.Text)
            Catch
                Return FC.PrevValue
            End Try
    End Select
    Return Null
End Sub