Android Question Localization in B4XPages

[Sergey_New]

In the B4XPages localization example, ListView is used to select the language.
Please help me replace ListView with B4XComboBox to select the language. Filling the ComboBox works, but then I got confused.
A simplified example is attached.

 

[DonManfred]

untested but maybe

Private Sub cmbLanguages_SelectedIndexChanged (Index As Int)
    Dim langval As String = cmbLanguages.cmbBox.GetItem(Index)
    loc.ForceLocale(langval)
    ResetLayout
End Sub

 

[Sergey_New]

untested but maybe

Thank you!
Removed everything related to ListView.
Doesn't work correctly. Please fix the attached example.

 

[DonManfred]

Please fix the attached example.

i´m at work. No time.

Try to fix it by yourself

 

[Sergey_New]

Try to fix it by yourself

I tried, it doesn't work...

 

[John Naylor]

I tried, it doesn't work...

It works second time you select a language.

First time selecting French, your

    Dim langval As String = cmbLanguages.GetItem(Index)

returns "French" but it then runs ResetLayout and next time you select French it returns "fr" which is what you want

 

[aeric]

I tried this in B4J. I think it should work in B4A too.

Sub Class_Globals
    Private Root As B4XView
    Private xui As XUI
    Public loc As Localizator
    Private cmbLanguages As B4XComboBox
    Dim availableLangs() As String = Array As String ("en", "fr", "de", "ru")
    Dim availableLanguages As List
    Dim Selected As Int
End Sub

Public Sub Initialize

End Sub

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    loc.Initialize(File.DirAssets, "strings.db")
    ResetLayout
End Sub

Private Sub ResetLayout
    Root.RemoveAllViews
    Root.LoadLayout("1")
    loc.LocalizeLayout(Root)
    availableLanguages = loc.LocalizeList(availableLangs)
    cmbLanguages.SetItems(availableLanguages)
    cmbLanguages.SelectedIndex = Selected
End Sub

Private Sub cmbLanguages_SelectedIndexChanged (Index As Int)
    Selected = Index
    loc.ForceLocale(availableLangs(Selected))
    ResetLayout
End Sub

Edit: Rearrange code in ResetLayout sub

 

[John Naylor]

Fix - Add

I tried this in B4J. I think it should work in B4A too.

Sub Class_Globals
    Private Root As B4XView
    Private xui As XUI
    Public loc As Localizator
    Private cmbLanguages As B4XComboBox
    Dim availableLangs() As String = Array As String ("en", "fr", "de", "ru")
    Dim availableLanguages As List
    Dim Selected As Int
End Sub

Public Sub Initialize

End Sub

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    loc.Initialize(File.DirAssets, "strings.db")
    ResetLayout
End Sub

Private Sub ResetLayout
    Root.RemoveAllViews
    Root.LoadLayout("1")
    availableLanguages = loc.LocalizeList(availableLangs)
    cmbLanguages.SetItems(availableLanguages)
    loc.LocalizeLayout(Root)
    cmbLanguages.SelectedIndex = Selected
End Sub

Private Sub cmbLanguages_SelectedIndexChanged (Index As Int)
    Selected = Index
    loc.ForceLocale(availableLangs(Selected))
    ResetLayout
End Sub

Cleaner than mine

I added

Public Sub GetCode(lang As String) As String
    If lang = Null Then Return "Error"
    lang = lang.Trim
    For Each k As String In strings.Keys
        Dim v As String = strings.Get(k)
        If v <> Null And v.EqualsIgnoreCase(lang) Then Return k
    Next
    Return "Error"
End Sub

into the Localizator code then

loc.ForceLocale(loc.GetCode(langval))

into SelectedIndexChanged

 

[Sergey_New]

I think it should work in B4A too

Thanks, it works!

I added

Thanks for adding!

 

[Sergey_New]

aeric, in cmbLanguages when creating a page, the language set by default on the device is not selected. I have "ru", and in cmbLanguages "Английский(English)" is displayed. Has something changed?

 

[aeric]

aeric, in cmbLanguages when creating a page, the language set by default on the device is not selected. I have "ru", and in cmbLanguages "Английский(English)" is displayed. Has something changed?

Add line #4 to set the cmbLanguages to select the device locale:

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    loc.Initialize(File.DirAssets, "strings.db")
    Selected = availableLangs.As(List).IndexOf(loc.Language)
    ResetLayout
End Sub

I have tested with French and Russian.

 

[Sergey_New]

Add line #4 to set the cmbLanguages to select the device locale

Thank you very much!

 

[aeric]

Project uploaded here:

[B4X] Localizator B4XPages

A B4X project example to use Localizator in B4XPages The device locale is selected for B4XCombobox by default. This is answer to this question: https://www.b4x.com/android/forum/threads/localization-in-b4xpages.167998/#post-1029898 GitHub: https://github.com/pyhoon/Localizator-B4XPages-B4X

www.b4x.com