Other [new feature] b4xlib - a new type of library

#Region Project Attributes 
    #MainFormWidth: 600
    #MainFormHeight: 600 
    #AdditionalJar: zip4j-1.3.2
#End Region

Sub Process_Globals
    
End Sub

Sub AppStart (Form1 As Form, Args() As String)
    
    #If Release
        MakeB4XLIB(File.GetFileParent(File.DirApp), "K:\B4J\AddLibraries", "AnotherDatePicker.b4xlib")    
        Log("done!")
    #end if    
    
    ExitApplication
End Sub

#Region MakeB4XLib
Sub MakeB4XLIB(inDir As String,outDir As String,zipFilename As String)
    If File.Exists(outDir,zipFilename) Then
        File.Delete(outDir,zipFilename)
    End If
    Dim zipFile As JavaObject
    zipFile.InitializeNewInstance("net.lingala.zip4j.core.ZipFile",Array(File.Combine(outDir,zipFilename)))
    Dim constants As JavaObject
    constants.InitializeStatic("net.lingala.zip4j.util.Zip4jConstants")
    Dim params As JavaObject
    params.InitializeNewInstance("net.lingala.zip4j.model.ZipParameters",Null)
    params.RunMethod("setCompressionMethod",Array(constants.GetField("COMP_DEFLATE")))
    params.RunMethod("setCompressionLevel",Array(constants.GetField("DEFLATE_LEVEL_NORMAL")))
    For Each filename As String In File.ListFiles(inDir)
        Dim tmpFileName As String = filename.tolowercase
        Dim path As String
        path=File.Combine(inDir,filename)
        If File.IsDirectory(inDir,filename) And tmpFileName = "files" Then
            zipFile.RunMethod("addFolder",Array(path,params))
        Else
            If tmpFileName.EndsWith(".bas") Or tmpFileName = "manifest.txt" Then
                zipFile.RunMethod("addFile",Array(getFile(path),params))
            End If
        End If
    Next
End Sub

Sub getFile(path As String) As JavaObject
    Dim fileJO As JavaObject
    fileJO.InitializeNewInstance("java.io.File",Array(path))
    Return fileJO
End Sub
#End Region