B4J Code Snippet [PyBridge] Create barcodes

Based on: https://python-barcode.readthedocs.io/en/stable/getting-started.html

Usage:

Wait For (CreateBarcode("code128", "abcdef")) Complete (Result As B4XBitmap)
ImageView1.SetBitmap(Result)

'dependencies: pip install python-barcode "python-barcode[images]"
'Types: ['codabar', 'code128', 'code39', 'ean', 'ean13', 'ean13-guard', 'ean14', 'ean8', 'ean8-guard', 'gs1', 'gs1_128', 'gtin', 'isbn', 'isbn10', 'isbn13', 'issn', 'itf', 'jan', 'nw-7', 'pzn', 'upc', 'upca']
Private Sub CreateBarcode (CodeType As String, Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim Barcode As PyWrapper = Py.ImportModule("barcode")
    Dim ImageWriter As PyWrapper = Py.ImportModuleFrom("barcode.writer", "ImageWriter")
    Barcode.GetField("PROVIDED_BARCODES").Print2("Types:", "", False)
    Dim EAN As PyWrapper = Barcode.Run("get_barcode_class").Arg(CodeType)
    Dim rv As PyWrapper = BytesIO.Call
    EAN.Call.Arg(Code).ArgNamed("writer", ImageWriter.Call).Run("write").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

Ctrl + click on the Python shell link at the top of B4XMainPage and run:
pip install python-barcode "python-barcode[images]"

 

[Johan Schoeman]

My first shot at Pybridge.. .

It is based on this web posting (could not with a quick browse find a PyBridge QR code generator on the forum):

Generate QR Code using qrcode in Python - GeeksforGeeks

Your All-in-One Learning Portal: GeeksforGeeks is a comprehensive educational platform that empowers learners across domains-spanning computer science and programming, school education, upskilling, commerce, software tools, competitive exams, and more.

www.geeksforgeeks.org

Have added it to @Erel 's sample code above



pip install qrcode

    ...
    ...
  
  
    Wait For (CreateBarcode("code128", "abcdef")) Complete (Result As B4XBitmap)
    ImageView1.SetBitmap(Result)
  

    Wait For (CreateQRCode("Hello Johan")) Complete (Result As B4XBitmap)
    ImageView2.SetBitmap(Result)
  
    ...
    ...
  
    Private Sub CreateBarcode (CodeType As String, Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim Barcode As PyWrapper = Py.ImportModule("barcode")
    Dim ImageWriter As PyWrapper = Py.ImportModuleFrom("barcode.writer", "ImageWriter")
    Barcode.GetField("PROVIDED_BARCODES").Print2("Types:", "", False)
    Dim EAN As PyWrapper = Barcode.Run("get_barcode_class").Arg(CodeType)
    Dim rv As PyWrapper = BytesIO.Call
    EAN.Call.Arg(Code).ArgNamed("writer", ImageWriter.Call).Run("write").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

Private Sub CreateQRCode(Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim QRCode As PyWrapper = Py.ImportModule("qrcode")
    Dim Img As PyWrapper = QRCode.Run("make").Arg(Code)
    Dim rv As PyWrapper = BytesIO.Call
    Img.Run("save").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

 

[Johan Schoeman]

....and this will allow you to set Version, Box Size, and Border. You can also change the hard coded colors for the fill_color and back_color:

Private Sub CreateQRCode(Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim qrcode As PyWrapper = Py.ImportModule("qrcode")
    Dim qr As PyWrapper = qrcode.Run("QRCode").ArgNamed("version", 5).ArgNamed("box_size", 10).ArgNamed("border", 5)
    qr.Run("add_data").Arg(Code)
    Dim Img As PyWrapper = qr.Run("make_image").ArgNamed("fill_color", "white").ArgNamed("back_color" , "black")
    Dim rv As PyWrapper = BytesIO.Call
    Img.Run("save").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

 

[Johan Schoeman]

This will allow you to also set the error correction level to L, M, Q, H

Private Sub CreateQRCode(Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim qrcode As PyWrapper = Py.ImportModule("qrcode")
    Dim qr As PyWrapper = qrcode.Run("QRCode").ArgNamed("version", 9).ArgNamed("box_size", 10).ArgNamed("border", 5).ArgNamed("error_correction", qrcode.GetField("ERROR_CORRECT_Q"))
    qr.Run("add_data").Arg(Code)
    Dim Img As PyWrapper = qr.Run("make_image").ArgNamed("fill_color", "white").ArgNamed("back_color" , "black")
    Dim rv As PyWrapper = BytesIO.Call
    Img.Run("save").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

 

[William Lancee]

I really, really like the way PyBridge has extended the capabilities of B4X. Thank you, @Johan Schoeman for turning your considerable skill to this portal.

 

[Johan Schoeman]

This will make a QR code that has rounded module corners and a gradient applied to it.

 

[Johan Schoeman]

Choose any of the following in the code to change the module shape:

'RoundedModuleDrawer, VerticalBarsDrawer, HorizontalBarsDrawer, CircleModuleDrawer, GappedSquareModuleDrawer, SquareModuleDrawer

Private Sub CreateQRCode(Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim qrcode As PyWrapper = Py.ImportModule("qrcode")
    Dim styledPilIMage As PyWrapper = Py.ImportModuleFrom("qrcode.image.styledpil", "StyledPilImage")
    'RoundedModuleDrawer, VerticalBarsDrawer, HorizontalBarsDrawer, CircleModuleDrawer, GappedSquareModuleDrawer, SquareModuleDrawer
    Dim RoundedModuleDrawerType As PyWrapper = Py.ImportModuleFrom("qrcode.image.styles.moduledrawers.pil", "GappedSquareModuleDrawer")
    Dim radialGradientColorMask As PyWrapper = Py.ImportModuleFrom("qrcode.image.styles.colormasks", "RadialGradiantColorMask")

    Dim qr As PyWrapper = qrcode.Run("QRCode").ArgNamed("box_size", 10).ArgNamed("border", 4).ArgNamed("error_correction", qrcode.GetField("ERROR_CORRECT_L"))
    qr.Run("add_data").Arg(Code)
    qr.Run("make").ArgNamed("fit", True)
    Dim Img As PyWrapper = qr.Run("make_image").ArgNamed("fill_color", "black").ArgNamed("back_color" , "white").ArgNamed("image_factory", styledPilIMage).ArgNamed("module_drawer", RoundedModuleDrawerType.Call).ArgNamed("color_mask", radialGradientColorMask.Call)
    Dim rv As PyWrapper = BytesIO.Call
    Img.Run("save").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

 

[William Lancee]

F.Y.I. For those who are not familiar with Python - AI tools are extremely familiar with Python and its libraries, including numpy, pandas, scikit-learn, keras, tensorflow, and other machine learning modules. I have not found it hallucinating in these areas. So you can do quick and informative searches. Be specific in your questions. If you don't specify, it won't volunteer to give you details not asked for. If AI generates Python code, it is syntactically correct, but needs to be adapted to your needs - so don't copy blindly.

I fondly think back on the days of going to the book store, finding an up-to-date manual, and searching for code examples.

 

[Johan Schoeman]

F.Y.I. For those who are not familiar with Python - AI tools are extremely familiar with Python and its libraries, including numpy, pandas, scikit-learn, keras, tensorflow, and other machine learning modules. I have not found it hallucinating in these areas. So you can do quick and informative searches. Be specific in your questions. If you don't specify, it won't volunteer to give you details not asked for. If AI generates Python code, it is syntactically correct, but needs to be adapted to your needs - so don't copy blindly.

I fondly think back on the days of going to the book store, finding an up-to-date manual, and searching for code examples.

Although it seems to be somewhat related to using JavaObject in B4J, it will take a bit of time to get used to the "constructors" when using PyBridge. AI at present probably does not have sufficient samples to draw from to come up with sensible PyBridge code to use an underlying library. Just my HO.

Rgds

Johan

 

[Johan Schoeman]

If you want to make a QR code with RadialGradiantColorMask:

The QR code above also uses the RoundedModuleDrawer.

Others:

Private Sub CreateQRCode(Code As String) As ResumableSub
    Dim BytesIO As PyWrapper = Py.ImportModuleFrom("io", "BytesIO")
    Dim qrcode As PyWrapper = Py.ImportModule("qrcode")
    Dim styledPilIMage As PyWrapper = Py.ImportModuleFrom("qrcode.image.styledpil", "StyledPilImage")
    'RoundedModuleDrawer, VerticalBarsDrawer, HorizontalBarsDrawer, CircleModuleDrawer, GappedSquareModuleDrawer, SquareModuleDrawer
    Dim RoundedModuleDrawerType As PyWrapper = Py.ImportModuleFrom("qrcode.image.styles.moduledrawers.pil", "VerticalBarsDrawer")
    Dim radialGradientColorMask As PyWrapper = Py.ImportModuleFrom("qrcode.image.styles.colormasks", "RadialGradiantColorMask")

    Dim qr As PyWrapper = qrcode.Run("QRCode").ArgNamed("box_size", 10).ArgNamed("border", 4).ArgNamed("error_correction", qrcode.GetField("ERROR_CORRECT_L"))
    qr.Run("add_data").Arg(Code)
    qr.Run("make").ArgNamed("fit", True)            'automatically determine the size of the QR Code to fit the supplied data
    Dim Img As PyWrapper = qr.Run("make_image").ArgNamed("fill_color", "black") _
                                               .ArgNamed("back_color" , "white") _
                                               .ArgNamed("image_factory", styledPilIMage) _
                                               .ArgNamed("module_drawer", RoundedModuleDrawerType.Call) _  '
                                               .ArgNamed("color_mask", radialGradientColorMask.Call _     'apply a radialgradientcolor to the QR code...
                                               .ArgNamed("back_color", Array As Object (255,255,255)) _   'adjust color here
                                               .ArgNamed("edge_color", Array As Object(100, 100, 0)) _    'adjust color here
                                               .ArgNamed("center_color", Array As Object(255,0, 0)))      'adjust color here
    Dim rv As PyWrapper = BytesIO.Call
    Img.Run("save").Arg(rv)
    Wait For (rv.Fetch) Complete (rv As PyWrapper)
    Return Py.ImageFromBytes(rv.Value)
End Sub

The end of my explorations of the PyBridge QR Code....