Android Question Select a line on a multiline EditText when user tap on it

[Mattiaf]

Hi, I'm looking for a way to select a line into a multiline EditText when the user tap on it..
Online i can only find ways to select the text between two indexes...
Thanks

 

[LucaMs]

Replace that EditText with a CustomListView.

 

[Erel]

B4XView.SetSelection

 

[LucaMs]

B4XView.SetSelection

when user tap on it​

 

[Mattiaf]

Replace that EditText with a CustomListView.

I ll try, so when I ll tap on the string, it will automatically select it?

 

[LucaMs]

I ll try, so when I ll tap on the string, it will automatically select it?

If I'm not mistaken, I think you don't need to allow the user to edit the text in that multiline EditText, i.e. you just fill it by code; right?
Let me know, because if that were the case, I would have already something that could be useful for you.

 

[Mattiaf]

exactly, the edittext is not modifiable by the user

 

[LucaMs]

exactly, the edittext is not modifiable by the user

Then try the project I am attaching.
It's nothing special, just a CLV that looks like a multiline EditText.
B4XPages version, therefore also for B4J (theoretically also for B4I, but I don't have this).

 

[klaus]

I suppose that this is what you are looking for.

The code:

Sub Globals
    Private edtTest As EditText
End Sub

Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("Layout")
    
    'adds a Click listener
    'as long as the EditText has the focus, the FocusChanged event is not raised, therefore the Click event
    Private refEditText As Reflector
    refEditText.Target = edtTest
    refEditText.SetOnClickListener("edtTest_Click")

    edtTest.Text = "This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text. This is a long text."
End Sub

'used for the first click, sets the focus and selects the cursor position
Private Sub edtTest_FocusChanged (HasFocus As Boolean)
    SelectLine
End Sub

'used for subsequent clicks when the EditText has the focus
Private Sub edtTest_Click(View As Object)
    SelectLine
End Sub

Private Sub SelectLine
    'SelectionStart = text cursor position
    'LineIndex = index of the line where the cursor is positioned
    'LineStart = text cursor position of the first character in the line
    'LineVisibleEnd = text cursor position of the last visible character in the line
    Private SelectionStart, LineIndex, LineStart, LineVisibleEnd As Int
    Private joEditText, joEditTextLayout As JavaObject
    
    joEditText = edtTest
    joEditTextLayout = joEditText.RunMethod("getLayout", Null)
    
    SelectionStart = joEditText.RunMethod("getSelectionStart", Null)
    LineIndex = joEditTextLayout.RunMethod("getLineForOffset", Array As Object(SelectionStart))
    LineStart = joEditTextLayout.RunMethod("getLineStart", Array As Object(LineIndex))
    LineVisibleEnd = joEditTextLayout.RunMethod("getLineVisibleEnd", Array As Object(LineIndex))
    joEditText.RunMethod("setSelection", Array As Object(LineStart, LineVisibleEnd))
End Sub

 

[LucaMs]

I suppose that this is what you are looking for.

Great code, Klaus.

I haven't tried it, but there might be a problem: would the user be able to edit the text in the EditText?

I say this in general, since @Mattiaf doesn't want to allow it; he has just to show a list of data from which the user has to choose one value (so I modified his project, using a more suitable CustomListView).

Yours it's anyway good code, to which I would add the copy directly to the clipboard (and I would post it in the Snippets forum ?)

 

[klaus]

would the user be able to edit the text in the EditText?

The user can still edit the text.

and I would post it in the Snippets forum

I am about to add it to the EditTextUtils.