B4J Code Snippet Sharing the goodness: Useful methods

Hi

Mashy's B4J Overview

I'm new to b4j and have just finished my project in it which is a helper for me in relation to php generation. I shared my creation here. As I am working on an updated version, I needed some functionality on the listview,e.g. returning all items as a map, search for a text or searching for a tag property. Whilst this will start with code on a listview, I intend to collect my snippets here.

'Description: add two lines to a listview
'Tag: listview, add two lines
Sub ListViewAddTwoLines(lv As ListView, Line1 As String, Line2 As String, Value As Object)
   Dim ap As AnchorPane
   ap.Initialize("")
   Dim lbl1, lbl2 As Label
   lbl1.Initialize("")
   lbl1.Text = Line1                
   lbl1.Font = fx.DefaultFont(14)
   lbl2.Initialize("")
   lbl2.Text = Line2
   lbl2.Font = fx.DefaultFont(12)
   ap.AddNode(lbl1, 0, 0, lv.Width, 20dip)
   ap.AddNode(lbl2, 0, 25dip, lv.Width, 20dip)
   lv.Items.Add(ap)
   lbl1.Tag = Value
End Sub

'Description: add a single line to a listview
'Tag: listview, add single line
Sub ListViewAddOneLine(lv As ListView, Line1 As String, Value As Object)
  Dim ap As AnchorPane
  ap.Initialize("")
  Dim lbl1 As Label
  lbl1.Initialize("")
  lbl1.Text = Line1                
  lbl1.Font = fx.DefaultFont(14)
  lbl1.Tag = Value
  ap.AddNode(lbl1, 0, 0, lv.Width, 20dip)
  lv.Items.Add(ap)
End Sub

'Description: search for tag from a listview and return boolean
'Tag: b4j, listview, text, search
Sub ListViewTagExist(lstView As ListView, searchTag As String) As Boolean
    Dim l As List
    Dim i As Int
    Dim t As Int
    Dim m As Map
    Dim txt As String
    searchTag = searchTag.ToLowerCase
    ' get all items as a list
    l = ListViewGetItems(lstView)
    t = l.Size - 1
    For i = 0 To t
        m = l.Get(i)
        txt = m.Get("tag")
        txt = txt.ToLowerCase
        If txt = searchTag Then
            Return True
        End If
    Next
    Return False
End Sub

'Description: search for text from a listview and return boolean
'Tag: b4j, listview, text, search
Sub ListViewTextExist(lstView As ListView, searchText As String) As Boolean
    Dim l As List
    Dim i As Int
    Dim t As Int
    Dim m As Map
    Dim txt As String
    searchText = searchText.ToLowerCase
    ' get all items as a list
    l = ListViewGetItems(lstView)
    t = l.Size - 1
    For i = 0 To t
        m = l.Get(i)
        txt = m.Get("text")
        txt = txt.ToLowerCase
        If txt = searchText Then
            Return True
        End If
    Next
    Return False
End Sub

'Description: return all items in the listview as a list of maps
'Tag: listview, b4j, map, anchorpane
Sub ListViewGetItems(lstView As ListView) As List
    Dim lstTarget As List
    Dim ap As AnchorPane
    Dim title As Label
    Dim m As Map
    Dim l As List
    l.Initialize
    ' get all the items from the list
    lstTarget = lstView.items
    ' loop through each item
    For I = 0 To lstTarget.Size - 1
        ap = lstTarget.Get(I)
        title = ap.GetNode(0)
        m.Initialize
        m.Put("tag", title.tag)
        m.Put("text", title.Text)
        l.Add(m)
    Next
    Return l
End Sub

'Description: return a tag and text of selected listview item as a map
'Tag: listview, map, tag, text
Sub ListViewGetSelected(lstView As ListView) As Map
    Dim m As Map
    m.Initialize
    Dim fsel As Int = lstView.SelectedIndex
    If fsel = -1 Then
        m.Put("tag", "")
        m.Put("text", "")
        m.Put("index","-1")
    Else
        ' get the selected item
        Dim ap As AnchorPane = lstView.SelectedItem
        Dim title As Label = ap.GetNode(0)
        m.Put("tag", title.tag)
        m.Put("text", title.Text)
        m.Put("index", fsel)
    End If
    Return m
End Sub

 

[Mashiane]

'Description: return all text in the listview as a delimited string
'Tag: listview, b4j, map, anchorpane
Sub ListViewGetTexts(lstView As ListView, Delimiter As String) As String
    Dim lstTarget As List
    Dim sb As StringBuilder
    Dim ap As AnchorPane
    Dim title As Label
    Dim lTot As Int
    Dim lCnt As Int
    sb.Initialize
    ' get all the items from the list
    lstTarget = lstView.items
    ' loop through each item
    lTot = lstTarget.Size - 1
    For lCnt = 0 To lTot
        ap = lstTarget.Get(lCnt)
        title = ap.GetNode(0)
        sb.Append(title.text)
        If lCnt <> lTot Then sb.Append(Delimiter)
    Next
    Return sb.tostring
End Sub

 

[Mashiane]

'Description: Add listview items from a delimited string
'Tag: listview, b4j, add items
Sub ListViewFromMV(lstView As ListView, MvString As String, Delimiter As String, bClear As Boolean)
    ' do we clear the list first
    If bClear = True Then lstView.Items.clear
    Dim lst() As String: lst = Split(MvString,Delimiter)
    Dim lstTot As Int: lstTot = lst.length - 1
    Dim lstCnt As Int
    Dim lstStr As String
    For lstCnt = 0 To lstTot
        lstStr = lst(lstCnt)
        ListViewAddOneLine(lstView, lstStr,lstStr)
    Next
End Sub

 

[Mashiane]

Helper function used by above script...

'Description: Split a multi delimited string to an array
'Tag: split, delimited string
Sub Split(Text As String, Delimiter As String) As String()
   Return Regex.Split(Delimiter,Text)
End Sub

 

[Mashiane]

'Description: Format string to display in webview with a specified font.
'Tag: webView, font, format text
Sub ToHTML(svalue As String, sFont As String) As String
    Dim sb As StringBuilder
    sb.Initialize
    sb.Append("<html>").Append(CRLF)
    sb.append("<head>").Append(CRLF)
    sb.Append("<style>.f{font-family:").Append(QUOTE).Append(sFont).Append(QUOTE).Append(";}</style>").Append(CRLF)
    sb.Append("</head>").Append(CRLF)
    sb.Append("<body>").Append(CRLF)
    sb.Append("<p class=f>").Append(svalue).Append("</p>").Append(CRLF)
    sb.Append("</body></html>")
    Return sb.ToString
End Sub

 

[Mashiane]

'Description: Load File.DirAssets file to webview, file can be a txt file
'Tag: webview, assets, text file
Sub AssetFileToWebView(webV As WebView, fn As String)
    Dim fc As String
    fc = File.ReadString(File.DirAssets,fn)
    fc = fc.Replace(Chr(13), "<br /><br />")
    webV.LoadHtml(ToHTML(fc,"Arial"))
End Sub

 

[Mashiane]

'Description: Load image to webview and fill area
'Tag: webview, load image
Sub ImageFileToWebView(webView As WebView, dir As String, fn As String)
    webView.LoadHtml("<html><body><img src='file:///" & dir & "/" & fn & "' width=100% height=100%/></body></html>")
End Sub

 

[Mashiane]

'Description: Save panel as image to a file
'Tag: panel, save, image
Sub SavePaneToImage(pnl As Pane, imgFile As String)
    Dim Out As OutputStream
    Dim TempImage As Image
    If File.Exists(File.DirApp, imgFile) Then File.Delete(File.dirapp, imgFile)
    Out = File.OpenOutput(File.dirapp, imgFile, False)
    TempImage = pnl.Snapshot
    TempImage.WriteToStream(Out)
    Out.Close
End Sub

 

[Mashiane]

'Description: Remove an item from the treeview using its text property
'Tag: treeview, remove, item
Sub TreeViewRemoveItem(tv As TreeView, itmName As String)
    Dim res As TreeItem
    res = TreeViewSearch(tv.Root, itmName)
    TreeItemDelete(res)
End Sub

 

[Mashiane]

' Description: Remove an item from treeview using treeitem
' Tag: treeview, remove, delete
Sub TreeItemDelete(res As TreeItem)
    If res.IsInitialized Then
        Dim i As Int = res.Parent.Children.IndexOf(res)
         res.Parent.Children.RemoveAt(i)
       End If
End Sub

 

[Mashiane]

'Description: Select an item in treeview using its name
'Tag: treeview, select item
Sub TreeViewSetItem(tv As TreeView, s As String)
    Dim ti As TreeItem
    ti = TreeViewSearch(tv.Root, s)
    If ti.IsInitialized = True Then
        Dim jo As JavaObject = tv
        jo.RunMethodJO("getSelectionModel", Null).RunMethod("select", Array(ti))
    End If   
End Sub

 

[Mashiane]

'Description: return a treeview item using its text property
'Tag: treeview, search, text
Sub TreeViewSearch(Parent As TreeItem, s As String) As TreeItem
   For Each ti As TreeItem In Parent.Children
     If ti.Text = s Then
       Return ti
     End If
     If ti.Children.Size > 0 Then
       Dim res As TreeItem = TreeViewSearch(ti, s)
       If res.IsInitialized Then Return res
     End If
   Next
   Dim res As TreeItem
   Return res
End Sub

 

[Mashiane]

'Description: return 0 / 1 based on checkbox checked value
'Tag: checkbox, return numeric
Sub ChkBox2YN(chkBox As CheckBox) As String
    If chkBox.Checked = True Then
        Return "1"
    Else
        Return "0"
    End If
End Sub

 

[Mashiane]

'Description: Set checkbox value based on numeric 0/1
'Tag: checkbox, numeric
Sub YN2ChkBox(YN As String, chkBox As CheckBox)
    Select Case YN
    Case "1"
        chkBox.Checked = True
    Case Else
        chkBox.Checked = False
    End Select
End Sub

 

[Mashiane]

'Description: Bring panel to front
'Tag: panel, node, Bring2Front
Sub ToFront(n As Node)
    Dim joNode As JavaObject = n
    joNode.RunMethod("toFront", Null)
End Sub

or perhaps

Sub BringToFront(n As Node)
   Dim parent As Pane = n.Parent
   n.RemoveNodeFromParent
   parent.AddNode(n, n.Left, n.Top, n.PrefWidth, n.PrefHeight)
End Sub

 

[JakeBullet70]

Always good code!

 

[Mashiane]

'Define a connection to MySQL server
Sub MySQLConnectionString(serverIP As String,  serverPort As String, serverDB As String) As String
    Dim sb As StringBuilder
    sb.Initialize
    sb.Append("jdbc:mysql://").Append(serverIP).Append(":").Append(serverPort).Append("/").Append(serverDB)
    Return sb.tostring
End Sub

 

[Mashiane]

'Define a connection string to Microsoft SQL server
Sub MSSQLConnectionString(serverIP As String,  serverPort As String, serverDB As String) As String
    Dim sb As StringBuilder
    sb.Initialize
    sb.Append("jdbc:jtds:sqlserver://").Append(serverIP).Append(":").Append(serverPort).Append("/").Append(serverDB)
    Return sb.tostring
End Sub

 

[Mashiane]

On Process_Globals. Also reference jServer for connection pool

    Private pool As ConnectionPool
    Private SQLite As SQL
    Private DatabaseType As Int
    Private UsePool As Boolean

'Initialize a connection to MySQL server and returns True if successful
Sub InitializeMySQL(serverIP As String,  serverPort As String, serverDB As String, login As String, password As String, poolSize As Int) As Boolean
    Log("init mysql")
    DatabaseType = 1
    UsePool = True
    Try
        Dim jdbcUrl As String
        jdbcUrl = MySQLConnectionString(serverIP,serverPort,serverDB)
           pool.Initialize("com.mysql.jdbc.Driver", jdbcUrl, login, password)
           ' change pool size...
        Dim jo As JavaObject = pool
        jo.RunMethod("setMaxPoolSize", Array(poolSize))   
        Return True
    Catch
       Log("Last Pool Init Except: "&LastException.Message)
       Return False
    End Try
End Sub

'Initialize a connection to Microsoft SQL server
Sub InitializeMSSQL(serverIP As String,  serverPort As String, serverDB As String ,login As String, password As String, poolSize As Int) As Boolean
    DatabaseType = 2
    Try
        Dim jdbcUrl As String
        jdbcUrl = MSSQLConnectionString(serverIP,serverPort,serverDB)
        pool.Initialize("net.sourceforge.jtds.jdbc.Driver", jdbcUrl, login, password)
        ' change pool size...   
        Dim jo As JavaObject = pool
        jo.RunMethod("setMaxPoolSize", Array(poolSize))
        Return True
    Catch
        Log("Last Pool Init Except: " & LastException.Message)
        Return False
    End Try
End Sub

 

[Mashiane]

'Description: Maximize B4j form
'Tag: form, maximise

'set your screen to maximize mode
Sub MaximizeStage(frm As Form)
    Dim jmf As JavaObject = frm
      Dim stage As JavaObject = jmf.GetField("stage")
      stage.RunMethod("setMaximized", Array As Object(True))
End Sub