Android Question [SOLVED] - Android 10 - Background GPS/Ble scans stop getting data after 1 hr

SetServiceAttribute(Tracker, android:foregroundServiceType, "location")

SetServiceAttribute(svc_ble, android:foregroundServiceType, "location")
SetServiceAttribute(svc_gps, android:foregroundServiceType, "location")

*** Service (svc_ble) Create ***
01/13/2021 11:46:50.260 - Atlas SOS - svc_ble(), Service_Create
STATE_ON
** Service (svc_ble) Start **
isStatusBarNotificationAllowedAsUser: packageName = com.is.vitllinkSOS,userId = 0
getContainerInfo: value is
isStatusBarNotificationAllowedAsUser: packageName = com.is.vitllinkSOS,userId = 0
getContainerInfo: value is
isStatusBarNotificationAllowedAsUser: packageName = com.is.vitllinkSOS,userId = 0
getContainerInfo: value is
isStatusBarNotificationAllowedAsUser: packageName = com.is.vitllinkSOS,userId = 0
getContainerInfo: value is
01/13/2021 11:46:50.342 - Atlas SOS - svc_ble(), Service_Start
01/13/2021 11:46:50.362 - Atlas SOS - svc_ble(), StartScan, STATE = 12
SFWD update time=1509214775072
STATE_ON
STATE_ON
Start Scan with callback
add() - appUid: 10225, appName: com.is.vitllinkSOS
[INFO:gatt_api.cc(953)] GATT_Register 4d8e26af-d0f4-440c-b0ca-3c00aa8e958a
[INFO:gatt_api.cc(990)] allocated gatt_if=7
onScannerRegistered() - status=0 scannerId=7 mScannerId=0
STATE_ON
setExpandState() isExpand = true, mLockscreenPageState = EXPAND, notificationCount = 0, mNotificationCount = 0
01/13/2021 11:46:50.411 - Atlas SOS - svc_ble(), Manager_StateChanged, 12 POWERED ON
STATE_ON
Cannot start unfiltered scan in screen-off. This scan will be resumed later: 7
getCallState - callingPid : 17348 / processName : sts
0|com.is.vitllinkSOS|1966|null|10225: granting content://settings/system/notification_sound
onNotificationPosted : com.is.vitllinkSOS number : 1966 listener : null
shouldBeFilteredOut : com.is.vitllinkSOS missingTitleAndText : false isGroupHeader : false
onNotificationPosted : com.is.vitllinkSOS number : 1966 listener : null
shouldBeFilteredOut : com.is.vitllinkSOS missingTitleAndText : false isGroupHeader : false
Notification for foreground service is posted, 0|com.is.vitllinkSOS|1966|null|10225
setExpandState() isExpand = true, mLockscreenPageState = EXPAND, notificationCount = 0, mNotificationCount = 0
uid=1000 system_server identical 3 lines
0|com.is.vitllinkSOS|1966|null|10225: granting content://settings/system/notification_sound
!@ 179,0 r 77868 4394322 w 18333 377672 d 1565 180944 f 2743 6644 iot 50432 40355 th 51200 0 0 pt 0 inp 0 0 1509.635
getCallState - callingPid : 17348 / processName : sts
uid=10058(com.android.systemui) identical 1 line
setExpandState() isExpand = true, mLockscreenPageState = EXPAND, notificationCount = 0, mNotificationCount = 0
onSignalStrengthsChanged signalStrength=SignalStrength:{mCdma=Invalid,mGsm=Invalid,mWcdma=CellSignalStrengthWcdma: ss=-97 ber=99 rscp=-89 ecno=0 level=2,mTdscdma=Invalid,mLte=Invalid,mNr=Invalid,SignalBarInfo{ wcdmaLevel=3 },P,rat=3,primary=CellSignalStrengthWcdma} level=3
getMobileIconGroup(): 0
getCallState - callingPid : 17348 / processName : sts
!@Sync 50 [2021-01-13 11:46:54.404] FD count : 524, wdog_way : softdog
Sending ACTION_BATTERY_CHANGED. scale:100, info:{.chargerAcOnline = false, .chargerUsbOnline = true, .chargerWirelessOnline = false, .maxChargingCurrent = 0, .maxChargingVoltage = 0, .batteryStatus = CHARGING, .batteryHealth = GOOD, .batteryPresent = true, .batteryLevel = 53, .batteryVoltage = 4009, .batteryTemperature = 223, .batteryCurrent = 0, .batteryCycleCount = 0, .batteryFullCharge = 3000000, .batteryChargeCounter = 1500800, .batteryTechnology = Li-ion}
online:4, current avg:495, charge type:1, POGO powered:false, power sharing:false, high voltage charger:false, charger_type:0, capacity:280000, misc_event:0, current_event:0, current_now:506
stay LED for charging
Plugged
  mCableConnection= 1
set cable connected : mGripEnabled = false
ACTION_BATTERY_CHANGED - Level=53, status=2
received broadcast android.intent.action.BATTERY_CHANGED
handleBatteryUpdate
received ACTION_BATTERY_CHANGED
Intent : android.intent.action.BATTERY_CHANGED
handleMessage -> MSG_UPDATE_CHARGING_STATE: mUsbCharging=true
updateUsbNotification(false): mConnected=true mConfigured=true mCurrentFunctions=mtp,adb mHostConnected=false mSourcePower=false mSinkPower=true mUsbCharging=true mUseUsbNotification=true
Set mCurrentFunctionsForNoti=mtp
priorPlugType = 2 mPlugType = 2 priorBatteryStatus = 2 mBatteryStatus = 2
isDexModeOn() : false
isSemiDexModeOn() : false
id=27 mUsbNotificationId=27
Intent : android.intent.action.BATTERY_CHANGED
showChargingNotice oldChargingType : 1 currentChargingType : 1 oldChargingTime : -1 mChargingTime : -1
There is no change about charging status, so return!
Battery swelling mode - priorBatterySwellingMode = 0 mBatterySwellingMode = 0 mBatteryStatus = 2
getDisplayHeight portrait? true  displayHeight= 1280
01/13/2021 11:46:55.362 - Atlas SOS - svc_ble() check_timeout, Scan Time Reached
STATE_ON
Stop Scan with callback
remove() - id: 7
remove() - removed: 7
01/13/2021 11:46:55.382 - Atlas SOS - svc_ble(), process_beacons, SCAN COMPLETE, Beacons Count = 0
[GSIM LOG]: gsimLogHandler, msg: MESSAGE_SCAN_STOP, appName: com.is.vitllinkSOS, scannerId: 7, reportDelayMillis=0
01/13/2021 11:46:55.393 - Atlas SOS - svc_ble(), No Beacons found
01/13/2021 11:46:55.403 - Atlas SOS - svc_ble(), Created Beacon Packet, packet is too old
01/13/2021 11:46:55.412 - Atlas SOS - svc_ble(), Created Beacon Packet  WIBD~12021/01/13 11:46:55355523116710742NOBEACONFIX
setExpandState() isExpand = true, mLockscreenPageState = EXPAND, notificationCount = 0, mNotificationCount = 0
** Service (svc_ble) Destroy **

Private Sub ScanWithLeScanner
    
    Dim ScanSettingsStatic As JavaObject
    ScanSettingsStatic.InitializeStatic("android.bluetooth.le.ScanSettings")
    
    ' // https://punchthrough.com/android-ble-guide/
    ' // https://developer.android.com/reference/android/bluetooth/le/ScanSettings.Builder
    ' // https://developer.android.com/reference/android/bluetooth/le/ScanSettings#SCAN_MODE_LOW_POWER
    
    Dim ScanSettingsBuilder As JavaObject
    ScanSettingsBuilder.InitializeNewInstance("android.bluetooth.le.ScanSettings.Builder", Null)
    
    ' // 2021.01.07 - 
    ScanSettingsBuilder.RunMethod("setScanMode", Array(ScanSettingsStatic.GetField("SCAN_MODE_LOW_POWER")))
    
    Dim ScanFilterStatic As JavaObject
    ScanFilterStatic.InitializeStatic("android.bluetooth.le.ScanFilter")
    
    ' // set the scan filter for iBeacons
    Dim ScanFilterBuilder1 As JavaObject
    ScanFilterBuilder1.InitializeNewInstance("android.bluetooth.le.ScanFilter.Builder", Null)
    ScanFilterBuilder1.RunMethod("setManufacturerData", Array(76,Array As Byte())) 'Apple ID
    
                                
    Dim Filters As List = Array(ScanFilterBuilder1.RunMethod("build", Null))
    If Filters.Size > 0 Then
        Dim aScanFilterJO As JavaObject = Filters.Get(0)
        mod_functions.writelog($"svc_ble::ScanWithLeScanner, Filter=${aScanFilterJO.RunMethod("toString", Null)}"$)
    End If
    Scanner.RunMethod("startScan", Array(Filters, ScanSettingsBuilder.RunMethod("build", Null), ScanCallback))
    comI.scanning = True
    
End Sub

ScanFilterBuilder1.RunMethod("setManufacturerData", Array(76,Array As Byte())) 'Apple ID

ScanFilterBuilder1.RunMethod("setManufacturerData", Array(76,Null)) 'Apple ID

Type mBeacon (uniqueid As String, name As String, uuid As String, _
                    minor As Int, major As Int, TX As Int, battery As Int, _
                    rssi As Double, distance As Double, TIME As Long, knowBeacon As Boolean)

' // IMPORTANT
' // https://stackoverflow.com/questions/50840378/how-to-scan-and-connect-to-ibeacon-using-ble-services-in-the-background/50841523#50841523
' // https://stackoverflow.com/questions/58428763/android-10-not-working-with-ble-bluetooth-scanning

' // https://developer.android.com/guide/components/foreground-services **
' // https://developer.android.com/reference/android/bluetooth/le/ScanFilter.Builder#setManufacturerData(int,%20byte[])
' // https://developer.android.com/reference/android/bluetooth/le/ScanSettings
' // https://support.kontakt.io/hc/en-gb/articles/201492492-iBeacon-advertising-packet-structure
' // https://github.com/NordicSemiconductor/Android-Scanner-Compat-Library/blob/master/scanner/src/main/java/no/nordicsemi/android/support/v18/scanner/ScanSettings.java
' // https://github.com/AltBeacon/android-beacon-library/pull/936 **

' // https://www.b4x.com/android/forum/threads/ble-android-9-scanning-stops-when-screen-turned-off.103249/#content
' // https://www.b4x.com/android/forum/threads/iot-beaconparser-discover-ibeacons-and-eddystone-beacons.61127/#content
' // https://www.b4x.com/android/forum/threads/ble-android-8-1-and-higher.113180/#post-706362
' // https://www.b4x.com/android/forum/threads/ble-scansettings.94908/#post-600231
' // https://www.b4x.com/android/forum/threads/background-task-with-blemanager2-and-beacon.117707/#content
' // https://www.b4x.com/android/forum/threads/ble-scansettings.94908/
' // https://www.b4x.com/android/forum/threads/background-location-tracking.99873/
' // https://www.b4x.com/android/forum/threads/android-10-background-gps-ble-scans-stop-getting-data-after-1-hr.126303/

Sub Process_Globals()

    'These global variables will be declared once when the application starts.
    'These variables can be accessed from all modules.
   
    Dim SCAN_FAILED_ALREADY_STARTED As Int = 1
    Dim SCAN_FAILED_APPLICATION_REGISTRATION_FAILED As Int = 2
    Dim SCAN_FAILED_FEATURE_UNSUPPORTED As Int = 4
    Dim SCAN_FAILED_INTERNAL_ERROR As Int = 3

    Dim tmrClock As Timer   
    Dim mfinished, scanComplete, restartNow As Boolean   
    Dim dieNow         As Boolean
   
    Private manager             As BleManager2
    Private Scanner             As JavaObject
    Private ScanCallback         As JavaObject
    Private ManagerJO             As JavaObject
    Private Adapter             As JavaObject
   
    Dim iBeacons As Map
   
    Private nID As Int = 1966
    Private n As Notification
   
    Private btm         As BluetoothAdmin
    Private pwAlive        As Boolean
    Private pw            As PhoneWakeState
    private scanTimeOut As long
   
End Sub

Sub Service_Create

    Service.AutomaticForegroundMode=Service.AUTOMATIC_FOREGROUND_NEVER
   
   
    If Not(btm.IsInitialized) Then
        btm.Initialize("")       
    End If
   
    Try
        ' // https://www.b4x.com/android/forum/threads/isinitialized-for-blemanager2.126591/#content
        If Not(manager.IsInitialized) Then
            manager.Initialize("manager")
        End If
        ' // 2021.04.18
        ManagerJO = manager
        Adapter = ManagerJO.GetField("blueAdapter")
        Scanner = Adapter.RunMethod("getBluetoothLeScanner", Null)
        ScanCallback.InitializeNewInstance(Application.PackageName & ".svc_ble$MyScanCallback", Null)
       
    Catch       
        log($"svc_ble::Service_Create, manager.IsInitialized, error - ${LastException.Message}"$ )
    End Try       
   
    mfinished = False
    scanComplete = False

    tmrClock.Initialize("tmrClock",1000)
    tmrStart.Initialize("tmrStart",1000)       
   
End Sub

Sub Service_Start (StartingIntent As Intent)

    Service.StartForeground(nID,CreateNotification("Atlas SOS","BLE Scan in progress","ic_bluetooth_searching_white_48dp",Main,False,False,n,nID))
   
    pw.KeepAlive(True)
    pwAlive = True
    ToastMessageShow("BLE Scan Started",False)
       
   
    If Not(btm.IsEnabled) Then
        btm.Enable
    End If
       
    ' // 10 seconds - YOU CAN CHANGE THIS
    scanTimeOut = DateTime.Now + (DateTime.TicksPerSecond * 10)
    iBeacons.Initialize   
    tmrClock.Enabled = True
    StartScan
       
End Sub

Sub Service_Destroy
   
    Service.stopForeground(nID)
   
    If pwAlive Then
        pw.releaseKeepAlive       
    End If
       
    mfinished = False
    scanComplete = False
    restartNow = False
   
End Sub


Sub tmrClock_tick

    check_timeout

    ' // we are done
    If scanComplete Then
        mfinished = True
    End If
   
    ' // we are done
    If mfinished Then
        tmrClock.Enabled = False
        StopService(Me)
    End If
   
End Sub

Sub check_timeout
   
    Try
        ' // we need to check a timeout here, if we timeout then restart the WIFI service
        If scanTimeOut < DateTime.Now Then           
            ' // stop the ble scan
            Scanner.RunMethod("stopScan", Array(ScanCallback))
            manager.StopScan
            manager.Disconnect
            ' // process beacond found
            process_beacons
            scanComplete = True
            mfinished = True
        End If
    Catch
        scanComplete = True
        mfinished = True
        mod_functions.writelog("svc_ble() check_timeout, error - " & LastException.Message)
    End Try
   
End Sub

Sub process_beacons()
   
    log($"svc_ble::process_beacons, SCAN COMPLETE, Beacons Count = ${iBeacons.Size}"$)
    ' // Got Beacons
    If iBeacons.Size > 0 Then           
        ' // process the beason list
        For Each k As String In iBeacons.Keys
           
            Dim bcn As mBeacon = iBeacons.Get(k)
                       
            log($"${bcn.uniqueid} ${bcn.name} ${bcn.Major} ${bcn.Minor} ${bcn.rssi} ${bcn.TX}"$)
           
           
        Next
       
    Else
        log("svc_ble::No Beacons found " )       
    End If
       
End Sub


Sub StartScan
   
    scanComplete = False
    ' // start ble backgrouns scanning   
    ScanWithLeScanner
   
End Sub

Sub Manager_StateChanged (State As Int)
   
    Dim currentStateText As String
   
    Select State
        Case manager.STATE_POWERED_OFF
            currentStateText = "POWERED OFF"
        Case manager.STATE_POWERED_ON
            currentStateText = "POWERED ON"
        Case manager.STATE_UNSUPPORTED
            currentStateText = "UNSUPPORTED"
    End Select
   
    Log($"svc_ble::Manager_StateChanged, ${State} ${currentStateText} "$)
   
   
End Sub

Private Sub ScanWithLeScanner
  
   
    Try
        Dim ScanSettingsStatic As JavaObject
        ScanSettingsStatic.InitializeStatic("android.bluetooth.le.ScanSettings")
       
        ' // https://punchthrough.com/android-ble-guide/
        ' // https://developer.android.com/reference/android/bluetooth/le/ScanSettings.Builder
        ' // https://developer.android.com/reference/android/bluetooth/le/ScanSettings#SCAN_MODE_LOW_POWER
       
        Dim ScanSettingsBuilder As JavaObject
        ScanSettingsBuilder.InitializeNewInstance("android.bluetooth.le.ScanSettings.Builder", Null)
       
        ' // 2021.01.07 -
        ScanSettingsBuilder.RunMethod("setScanMode", Array(ScanSettingsStatic.GetField("SCAN_MODE_LOW_POWER")))
       
        Dim ScanFilterStatic As JavaObject
        ScanFilterStatic.InitializeStatic("android.bluetooth.le.ScanFilter")
       
        ' // set the scan filter for iBeacons
        Dim ScanFilterBuilder1 As JavaObject
        ScanFilterBuilder1.InitializeNewInstance("android.bluetooth.le.ScanFilter.Builder", Null)
        ScanFilterBuilder1.RunMethod("setManufacturerData", Array(76,Array As Byte())) 'Apple ID
                                           
        Dim Filters As List = Array(ScanFilterBuilder1.RunMethod("build", Null))
        If Filters.Size > 0 Then
            Dim aScanFilterJO As JavaObject = Filters.Get(0)
            log($"svc_ble::ScanWithLeScanner, Filter=${aScanFilterJO.RunMethod("toString", Null)}"$)
        End If
        Scanner.RunMethod("startScan", Array(Filters, ScanSettingsBuilder.RunMethod("build", Null), ScanCallback))       
    Catch
        log($"svc_ble::ScanWithLeScanner, error=${LastException.Message}"$)       
        scanComplete = True
    End Try
       
End Sub


Private Sub Scan_Failed (Result As Int)
   
    Dim res As String
   
    Select Case Result
       
        Case 1
            res = "SCAN_FAILED_ALREADY_STARTED"
        Case 2
            res = "SCAN_FAILED_APPLICATION_REGISTRATION_FAILED"
        Case 3
            res = "SCAN_FAILED_INTERNAL_ERROR"
        Case 4
            res = "SCAN_FAILED_FEATURE_UNSUPPORTED"
    End Select
   
    mod_functions.writeLog($"svc_ble::Scan_Failed, ${Result} ${res} "$)
   
    Dim btm As BluetoothAdmin
    btm.Initialize("")
    btm.Disable
    scanComplete = True
   
   
End Sub

Private Sub Scan_Result (Result As Object)
   
    Dim ScanResult As JavaObject = Result
    Dim device As JavaObject = ScanResult.RunMethod("getDevice", Null)
    Dim address As String = device.RunMethod("getAddress", Null)
    ManagerJO.GetFieldJO("devices").RunMethod("put", Array(address, device))
   
    Dim ScanRecord As JavaObject = ScanResult.RunMethod("getScanRecord", Null)   
    Dim data() As Byte = ScanRecord.RunMethod("getManufacturerSpecificData", Array(76)) '76 = apple id
       
    If data <> Null Then
       
        Try
            Private bc As ByteConverter
            Dim raf As RandomAccessFile
            Dim ib As mBeacon
            raf.Initialize3(data, False)
            ' // load beacons props
            ib.Initialize
            ib.name = ScanRecord.RunMethod("getDeviceName",Null)
            ib.uniqueid = address
            ib.major =  Bit.And(0xFFFF,raf.ReadShort(18))
            ib.minor =  Bit.And(0xFFFF,raf.ReadShort(20))
            ib.rssi = ScanResult.RunMethod("getRssi", Null)
            ib.tx = ScanRecord.RunMethod("getTxPowerLevel",Null)
                       
            ' // https://www.b4x.com/android/forum/threads/iot-beaconparser-discover-ibeacons-and-eddystone-beacons.61127/post-450458
            ib.distance = CalculateDistance(ib.tx, ib.rssi)
            ib.time = DateTime.Now
            iBeacons.Put(ib.uniqueid, ib)
            Log($"${DateTime.Time(ib.time)} - ${ib.name} ${ib.uniqueid} ${ib.tx} ${ib.rssi} ${ib.distance} "$)
        Catch
            log($"Scan_Result, Error ${LastException.Message}"$)
            log(ScanRecord.RunMethod("toString", Null))
        End Try       
               
    End If
   
End Sub

Sub CalculateDistance(txPower As Int, rssi As Double) As Double
 
    Dim ratio As Double, tx As Int
       
    If txPower = -12 Then
        tx = -77
    Else
        tx = txPower
    End If

    If (rssi = 0) Then
        Return -1.0
    End If

    ratio = rssi*1.0/tx

    If (ratio < 1.0) Then
        Return Round2(Power(ratio,10),2)
    Else
        Return Round2((0.89976) * Power(ratio,7.7095) + 0.111,2)
    End If
   
   
End Sub

Private Sub CreateNotification(Title As String, Content As String, Icon As String, TargetActivity As Object, _
                                    Sound As Boolean, Vibrate As Boolean, pN As Notification,pNID As Int) As Notification
   
   
    Dim p As Phone
   
   
    If p.SdkVersion >= 21 Then
        Dim nb As NotificationBuilder
        Dim Channel As NotificationChannelBuilder
        Dim ChannelID As String = "ies_atlas_sos_ble_scan"
        Dim ChannelName As String = "Atlas SOS Ble Scan"
       
        ' // Build a Channel
   
        If Channel.ChannelsSupported Then
            Channel.Initialize(ChannelID, ChannelName, Channel.IMPORTANCE_LOW)
            Channel.Build
        End If
       
        nb.Initialize(ChannelID)
        nb.AutoCancel = False
        nb.OnGoingEvent = True
        nb.DefaultSound = Sound
        nb.DefaultVibrate = Vibrate
        nb.DefaultLight = False
        nb.ContentTitle = Title
        nb.ContentText = Content
        nb.setActivity(TargetActivity)
        nb.SmallIcon = Icon
        nb.Number = pNID
        ' //set the return object for the notification object (n1) in this service
        pN = nb.GetNotification
    Else
        pN.Initialize
        pN.Number = pNID
        pN.Light = False
        pN.Vibrate = Vibrate
        pN.Sound = Sound
        pN.OnGoingEvent = True
        pN.Icon = Icon
        pN.SetInfo(Title, Content, TargetActivity)
    End If
    pN.Notify(pNID)
    Return pN
   
End Sub
#if Java
import android.bluetooth.le.*;
public static class MyScanCallback extends ScanCallback {
public void onScanResult(int callbackType, ScanResult result) {
         processBA.raiseEvent(this, "scan_result", result);
    }

  

    /**
     * Callback when scan could not be started.
     *
     * @param errorCode Error code (one of SCAN_FAILED_*) for scan failure.
     */
    public void onScanFailed(int errorCode) {      
       processBA.raiseEvent(this, "scan_failed", errorCode);
    }
}
#End If