Android Question (SOLVED) B4XEncryption difference between B4J and B4A? (or is it me? probably me...)

[walt61]

When I do the following:
- encrypt file X with B4J to new file Y, and
- decrypt file Y with B4A to new file Z, then
- new file Z is not identical to original file X

All other combinations (B4J -> B4J, B4A -> B4A, B4A -> B4J) appear to work correctly.

Environment:
- OS: Win 10 or Linux Mint with Wine (tried both)
- JDK: OpenJDK 19.0.2
- B4A: 13.40; relevant libs: B4XEncryption 1.00, RandomAccessFile 2.33
- B4J: 10.30; relevant libs: jB4XEncryption 1.00, jRandomAccessFile 2.35

Demo project attached and the relevant encryption/decryption methods added below. Any insight would be greatly appreciated!

Private Sub EncryptFile(inPath As String, outPath As String, encKey As String) As Boolean

    Dim enc As B4XCipher
    Dim result As Boolean
    Dim rafInput, rafOutput As RandomAccessFile

    TextArea1.Text = TextArea1.Text & CRLF & "Input file to encrypt: " & inPath & CRLF & "Encrypted output file: " & outPath

    If File.Exists(outPath, "") Then File.Delete(outPath, "")

    rafInput.Initialize(inPath, "", True)
    rafOutput.Initialize(outPath, "", False)

    Try
        Dim size As Long = File.Size(inPath, "")
        Dim b(size) As Byte
        rafInput.ReadBytes(b, 0, size, 0)
        Dim bb() As Byte = enc.Encrypt(b, encKey)
        rafOutput.WriteBytes(bb, 0, bb.Length, rafOutput.CurrentPosition)
        result = True
    Catch
        TextArea1.Text = TextArea1.Text & CRLF & LastException
        result = False
    End Try

    rafInput.Close
    rafOutput.Close
    Return result

End Sub

Private Sub DecryptFile(inPath As String, outPath As String, encKey As String) As Boolean

    Dim enc As B4XCipher
    Dim result As Boolean
    Dim rafInput, rafOutput As RandomAccessFile

    TextArea1.Text = TextArea1.Text & CRLF & "Input file to decrypt: " & inPath & CRLF & "Decrypted output file: " & outPath

    If File.Exists(outPath, "") Then File.Delete(outPath, "")

    rafInput.Initialize(inPath, "", True)
    rafOutput.Initialize(outPath, "", False)

    Try
        Dim size As Long = File.Size(inPath, "")
        Dim b(size) As Byte
        rafInput.ReadBytes(b, 0, size, 0)
        Dim bb() As Byte = enc.Decrypt(b, encKey)
        rafOutput.WriteBytes(bb, 0, bb.Length, 0)
        result = True
    Catch
        TextArea1.Text = TextArea1.Text & CRLF & LastException
        result = False
    End Try

    rafInput.Close
    rafOutput.Close

    Return result

End Sub

 

[teddybear]

Try testing using the B4XEncryption in B4J to see if there are any differences

 

[walt61]

I should have added this to the first post (did that now): all other combinations (B4J -> B4J, B4A -> B4A, B4A -> B4J) appear to work correctly.

 

[Erel]

Why aren't you using File.WriteBytes / ReadBytes?

 

[walt61]

Because I isolated the problem here with minimal code. The actual code I use comes from this post: https://www.b4x.com/android/forum/t...encryption-and-decryption.114141/#post-713166 as the files can be large ones.

What I'm doing in my project is: zip a file, encrypt it, then send it over to another device (it's a file sync/file manager project).

 

[Erel]

I'm implemented this task with simpler code:

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Root.LoadLayout("MainPage")
    Dim password As String = "123456"
    Dim c As B4XCipher
    Dim original() As Byte = File.ReadBytes(File.DirAssets, "original.dat")
    Log("Original length: " & original.Length)
    #if B4J
    Dim encrypted() As Byte = c.Encrypt(original, password)
    File.WriteBytes(File.DirApp, "encrypted.dat", encrypted) 'copy back to Files folder of B4J and B4A
    #end if
    Dim decrypted() As Byte = c.Decrypt(File.ReadBytes(File.DirAssets, "encrypted.dat"), password)
    Log("Decrypted length: " & decrypted.Length)
    Log("Compare: " & CompareArrays(original, decrypted))
End Sub

Private Sub CompareArrays(b1() As Byte, b2() As Byte) As Boolean
    If b1.Length <> b2.Length Then Return False
    Dim bb1 As B4XBytesBuilder
    bb1.Initialize
    bb1.Append(b1)
    Return bb1.IndexOf(b2) = 0
End Sub

Output in B4A:

Original length: 12438
Decrypted length: 12438
Compare: true

 

[walt61]

Thanks Erel, but as I'm implementing a sync process, I need it to work in both directions. With large files, File.ReadBytes into a byte array would surely lead to out of memory errors? Any kind of file can be selected by the user, they could be multiple Gb.

 

[DonManfred]

With large files, File.ReadBytes into a byte array would surely lead to out of memory errors?

your code

Dim size As Long = File.Size(inPath, "") Dim b(size) As Byte rafInput.ReadBytes(b, 0, size, 0) Dim bb() As Byte = enc.Decrypt(b, encKey)

also load the complete file into memory!?

 

[walt61]

With the above example code, that's correct, Don. However, what I'm actually using is Erel's code from the link in post 5, which encrypts/decrypts files in chunks. I've reduced it as much as possible to pinpoint the issue.

To elaborate a bit about the project:
- server is a Raspberry Pi with an external USB disc, placed 'offsite' (at a friend's or family member or wherever) and a B4J server program
- clients are B4J or B4A
- all traffic is encrypted
- files (and some metadata like the original file path) are encrypted/decrypted client-side; the server only knows 'there is a file', it doesn't know its real name or what it contains

The intention is to have an offsite backup/sync that would be completely useless for anyone who would steal it/break into it. Safe personal cloud storage, you might say.

 

[walt61]

Found it ! I was using #AdditionalJar: bcprov-jdk18on-177 and that appears to have been the culprit. Just in case someone else runs into this issue:

These ones work fine:
bcprov-jdk15on-154
bcprov-jdk15on-165
bcprov-jdk18on-1.81 (must have had brain fog, this one does not work)

These don't:
bcprov-jdk15to18-177
bcprov-jdk18on-171
bcprov-jdk18on-177
bcprov-jdk18on-1.81