B4J Tutorial [BANano] Using PocketBase (Firebase Alternative) for your Apps.

'pocketbase user registration
    Dim pb As SDUIPocketBase
    'initialize the connection to pocketbase with a collection to access
    pb.Initialize(Me, "pb", "http://127.0.0.1:8090", "users")
    'THIS SHOULD MATCH
    Dim user As Map = CreateMap()
    user.put("email", email.Value)
    user.put("password", password.value)
    user.put("passwordConfirm", confirmpassword.value)
    Dim profile As Map = banano.Await(pb.CREATE_USER(user))
    If banano.IsNull(profile) Then
        app.ShowSwalError("The user profile could no be created!")
        Return
    End If

'auth via email - before you can update the profile
    Dim vEmail As Map = banano.await(pb.USER_AUTH_VIAEMAIL(email.value, password.value))
    If banano.IsNull(vEmail) Then
        app.ShowSwalError("The credentials could not be verified!")
        Return
    End If
    'now we update the profile
    Dim pid As String = pb.UserProfile.id
    Dim uuser As Map = CreateMap()
    uuser.put("name", fullname.Value)
    Dim uprofile As Map = banano.Await(pb.UPDATE_USER_PROFILE(pid, uuser))

'now send verification email
    Dim pemail As String = pb.UserProfile.email
    Dim vEmail As Map = banano.await(pb.USER_REQUEST_VERIFICATION(pemail))
    Log(uprofile)

Private Sub btnSignUp_Click (e As BANanoEvent)
    'reset the validations
    mdlSignIn.ResetValidation
    'validate each of the elements
    mdlSignIn.Validate(fullname.IsBlank)
    mdlSignIn.Validate(email.IsBlank)
    mdlSignIn.Validate(password.IsBlank)
    mdlSignIn.Validate(confirmpassword.IsBlank)
    Dim bMatch As Boolean = password.IsMatch(confirmpassword.Value, "The passwords should match!")
    mdlSignIn.Validate(bMatch)
    'check the form status
    If mdlSignIn.IsValid = False Then Return
    'get the data on form
    'Dim data As Map = mdlSignIn.GetData
    
    'pocketbase user registration
    Dim pb As SDUIPocketBase
    'initialize the connection to pocketbase with a collection to access
    pb.Initialize(Me, "pb", "http://127.0.0.1:8090", "users")
    'THIS SHOULD MATCH
    Dim user As Map = CreateMap()
    user.put("email", email.Value)
    user.put("password", password.value)
    user.put("passwordConfirm", confirmpassword.value)
    Dim profile As Map = banano.Await(pb.CREATE_USER(user))
    If banano.IsNull(profile) Then
        app.ShowSwalError("The user profile could no be created!")
        Return
    End If
    'auth via email - before you can update the profile
    Dim vEmail As Map = banano.await(pb.USER_AUTH_VIAEMAIL(email.value, password.value))
    If banano.IsNull(vEmail) Then
        app.ShowSwalError("The credentials could not be authorised!")
        Return
    End If
    'now we update the profile
    Dim pid As String = pb.UserProfile.id
    Dim uuser As Map = CreateMap()
    uuser.put("name", fullname.Value)
    Dim uprofile As Map = banano.Await(pb.UPDATE_USER_PROFILE(pid, uuser))
    'now send verification email
    Dim pemail As String = pb.UserProfile.email
    Dim vEmail As Map = banano.await(pb.USER_REQUEST_VERIFICATION(pemail))
    If banano.IsNull(vEmail) Then
        app.ShowSwalError("The credentials could not be verified!")
        Return
    End If
    app.ShowSwalSuccess("The account was created successfully!")
End Sub

Private Sub btnSignIn_Click (e As BANanoEvent)
    'reset the validations
    mdlSignIn.ResetValidation
    'validate each of the elements
    mdlSignIn.Validate(email.IsBlank)
    mdlSignIn.Validate(password.IsBlank)
    'check the form status
    If mdlSignIn.IsValid = False Then Return
    'get the data on form
    Dim data As Map = mdlSignIn.GetData
    'Log(data)
    'do verification
    'if verification = false return
    'do we remember
    If rememberme.Checked Then
        'save settings using app name
        SDUIShared.SetLocalStorage(Main.AppName, data)
    Else
        'remove settings
        SDUIShared.DeleteLocalStorage(Main.AppName)
    End If
    '
    'pocketbase user auth via email
    Dim pb As SDUIPocketBase
    'initialize the connection to pocketbase with a collection to access
    pb.Initialize(Me, "pb", "http://127.0.0.1:8090", "users")
    Dim vEmail As Map = banano.await(pb.USER_AUTH_VIAEMAIL(email.value, password.value))
    If banano.IsNull(vEmail) Then
        app.ShowSwalError("Your credentials cannot be verified!")
        Return
    End If
    
    'show nav & drawer
    pgIndex.UpdateUserName(pb.UserProfile.name)
    pgIndex.UpdateUserAvatar(pb.UserProfile.avatar)
    pgIndex.IsAuthenticated(True)
    'hide the modal
    mdlSignIn.Hide
End Sub

Private Sub btnReset_Click (e As BANanoEvent)
    'reset the validations
    mdlSignIn.ResetValidation
    'validate each of the elements
    mdlSignIn.Validate(email.IsBlank)
    'check the form status
    If mdlSignIn.IsValid = False Then Return
    'get the data on form
    Dim data As Map = mdlSignIn.GetData
    'Log(data)
    'pocketbase user auth via email
    Dim pb As SDUIPocketBase
    'initialize the connection to pocketbase with a collection to access
    pb.Initialize(Me, "pb", "http://127.0.0.1:8090", "users")
    Dim vEmail As Boolean = banano.await(pb.USER_REQUEST_PASSWORDRESET(email.value))
    If vEmail = False Then
        app.ShowSwalError("Password reset could not be requested!")
        Return
    End If
    app.ShowSwalSuccess("Password reset request sent!")
End Sub

UPDATE _admins SET passwordHash='$2a$10$xWbkSks7OiTmrri2DU6QSe6OAekcdqkOrkcI1wi4uiv9SU2HTlHoq' where email='test@example.com'