Android Code Snippet Grid in a CustomListView for B4A: Icon Selector with Lazy Loading

Sub CLV1_VisibleRangeChanged(FirstIndex As Int, LastIndex As Int)
    Dim loadFrom    As Int = Max(0, FirstIndex - 1)
    Dim loadTo      As Int = Min(CLV1.Size - 1, LastIndex + 1)
    Dim unloadFrom  As Int = 0
    Dim unloadTo    As Int = Max(0, FirstIndex - 3)
    Dim unloadFrom2 As Int = Min(CLV1.Size - 1, LastIndex + 3)
    Dim unloadTo2   As Int = CLV1.Size - 1

    For i = 0 To CLV1.Size - 1
        Dim pRow As B4XView = CLV1.GetPanel(i)
        Dim shouldLoad As Boolean = (i >= loadFrom And i <= loadTo)
        Dim shouldUnload As Boolean = (i <= unloadTo) Or (i >= unloadFrom2)

        For c = 0 To pRow.NumberOfViews - 1
            Dim pCell As B4XView = pRow.GetView(c)
            If Not(pCell.Tag Is Map) Then Continue

            Dim cellTag As Map = pCell.Tag
            Dim iv As ImageView = pCell.GetView(0)

            If shouldLoad And Not(cellTag.Get("loaded")) Then
                Try
                    iv.Background = AR.GetApplicationDrawable(cellTag.Get("name"))
                    cellTag.Put("loaded", True)
                Catch
                    Log("Failed to load: " & cellTag.Get("name"))
                End Try
            Else If shouldUnload And cellTag.Get("loaded") Then
                iv.Background = Null
                cellTag.Put("loaded", False)
            End If
        Next
    Next
End Sub