Android Tutorial Introduction to the libGDX library

Introduction to the libGDX library​

What is libGDX ?

libGDX is a game engine. As we saw in the first tutorial, a game engine provides a framework to create games and covers all aspects (rendering, animation, input, music, networking, physics, ...) of various kinds of games.

libGDX is considered as one of the best and fastest engine for the Android world. It is free, rich-featured, reliable, and proved its efficiency in a lot of well-known games (Ingress, Zombie Smasher, Apparatus, Monsterama Park, Clash of the Olympians, Bumbledore, etc.)

It’s a layered framework: it goes from low-level classes for OpenGL experts to high-level classes, easy to use by beginners. It includes a scene graph (Scene2D classes), a physics engine (Box2D classes), a particle system, a map renderer, a sprite batcher, an extensive set of mathematics classes… more than 200 classes in total.

For technical reasons, the version for Basic4Android cannot be multi-platform, and by choice, the current release doesn't include the 3D classes (except the ones for the perspective camera and for the decals) and the Daydream class.

libGDX was created in 2010 by Mario Zechner (badlogicgames.com) and is maintained by M. Zechner, Nathan Sweet (esotericsoftware.com) and a community of developers.

Minimum requirements

OpenGL ES 2.0
Android Froyo (API 8)

Hardware acceleration

libGDX does not require that you enable hardware acceleration on your device because it is based on OpenGL, which interacts directly with the GPU.

Debugging

You cannot use the debugger of B4A with libGDX because most of the code of the library runs in a different thread. You have to use the Log() function to debug your game.

The library provides a debug renderer for Box2D (lgBox2DDebugRenderer), a debug renderer for Scene2D (lgScn2DDebugRenderer) and a profiler for OpenGL (lgGLProfiler).

A word about the classes

The main class is LibGDX. All other classes are prefixed by lg.
All Box2D classes are prefixed by lgBox2D. All Scene2D classes are prefixed by lgScn2D. All Map classes are prefixed by lgMap. All Math classes are prefixed by lgMath.

The LibGDX class gives access to five interfaces: Audio (lgAudio), Files (lgFiles), Graphics (lgGraphics), Input (lgInput), and Net (lgNet). You will use the Input interface, for example, to get the input from the accelerometer.

With some classes (e.g. the five interfaces), you cannot create a new instance with Dim. You have to use an instance returned by the library. For example, you cannot write:

Dim Graphics As lgGraphics
Graphics = lGdx.Graphics

but you can write:

Dim Graphics As lgGraphics = lGdx.Graphics

Some classes cannot be instantiated at all because they are generic classes (e.g. com.badlogic.gdx.scenes.scene2d.utils.Drawable or com.badlogic.gdx.maps.tiled.TiledMapTile). In this case, either you store their instance as an Object or you use a subclass, e.g.:

Dim objTile As Object = CurrentLayer.GetCell(X, Y).Tile
Dim staticTile As lgMapStaticTiledMapTile = CurrentLayer.GetCell(X, Y).Tile

OpenGL ES

I explained what OpenGL is in the previous tutorial and I won't discuss it further here because the main advantage to use a game engine like libGDX is to benefit from the abstraction layer above OpenGL. However, if you need (or want) to call directly OpenGL, here's how to get access to the classes and functions:

Dim lGdx_GL20 As lgGL20 = lGdx.Graphics.GL20

or better (includes also the constants):

Dim GL As lgGL

Note: libGDX uses the 2D coordinate system and the color encoding of OpenGL ES, so the Y-axis is pointing upwards and each color value ranges from 0 to 1.

The libGDX life-cycle

An important thing to keep in mind about libGDX is that it runs in its own thread. Your Basic4Android application runs most of the time in a different thread called the UI thread, or main thread. That means you cannot access the other views of your activity and change their properties from the libGDX thread. Fortunately, there's a function in the LibGDX class that passes the runnable (the piece of code to execute) from a thread to the other: CallSubUI. So if you want to change the activity title, set a label text or show a MsgBox from the libGDX thread, don't forget to use this function to avoid a crash!

Since libGDX runs in a different thread, you have to inform its library of the events of your activity : Create, Pause and Resume. First, create an instance of libGDX in Globals :

Dim lGdx As libGDX

In Activity_Create (and nowhere else), add the Initialize function :

lGdx.Initialize(False, "LG") 'fills the activity with the libGDX surface, uses OpenGL 1 for compatibility and prefixes the events with LG

In Activity_Resume, add the following line :

If lGdx.IsInitialized Then lGdx.Resume

In Activity_Pause, add the following line :

If lGdx.IsInitialized Then lGdx.Pause

You could initialize libGDX differently. For example, it could be limited to a view with InitializeView. You could also define a configuration (lgConfiguration class) and pass it to libGDX. Example:

Dim Config As lgConfiguration

'Disables the accelerometer and the compass
Config.useAccelerometer = False
Config.useCompass = False

'Uses a WakeLock (the device will stay on)
Config.useWakelock = True

'Creates the libGDX surface
lGdx.Initialize2(Config, "LG")

Once done, your library is ready to raise the events of its life-cycle : Create, Resize, Render, Pause, Resume, Dispose. These events are the place to put all the code of your game. Don't put anything in the usual activity events. They are reserved for your other views and are raised by the UI thread.

Create :

Create is the first raised event. It is raised soon after the initialization of the library and the creation of the OpenGL surface.
In this event, initialize your renderer and your input processors, load your resources (we'll see that in detail later) and initialize your game data.

Resize :

Resize is raised when the size of the libGDX surface changes. Under Android, that should only happen when you start the application and when it is restarted after a rotation or resumed.
It is raised at least once, after Create, and, when the application is resumed, just before Resume.
In this event, initialize the camera viewport. It's probably the only use you will find for it.
This event returns the new width and height in pixels.

Render :

Render is raised as soon as possible after Create and Resize.
It's where things are drawn. It's also where you have to put the logic of your game, but I would not recommend putting hundreds of lines of code here. Instead, create new subs and new modules and call them from this event.
The first lines in Render should be to clear the screen. Example:

lGdx_GL.glClearColor(0, 0, 1, 1) 'Blue background
lGdx_GL.glClear(lGdx_GL.GL10_COLOR_BUFFER_BIT)

Pause :

Pause is raised when the activity is sent in the background, rotated or exited.
It's the right place to save your game data.
Note that the OpenGL context is destroyed when the app goes in the background, so all your unmanaged textures and pixmaps have to be reloaded or recreated in the Resume event when the app returns to the foreground.

Resume :

Contrary to the Resume event of your activity, this one is not raised after Create, only when the application returns from a pause.
As the OpenGL context is destroyed when the app goes in the background, all your unmanaged* textures and pixmaps have to be reloaded or recreated when this event is raised. More info here. *Not loaded by an asset manager.

Dispose :

Dispose is called when the activity is exited, after Pause, or when the device is rotated.
In this event, release all the used resources by calling the Dispose function of objects (if they have one).

The life-cycle :

Multiple screens

A game is made of many screens. You could create an activity for each one, but that would not be very convenient because you'd have to reinitialize the library in each activity and reload some resources. Moreover, that would not ease any graphical transition between screens. In fact, most games are made with a very small number of activities and make use of a screen manager instead. The screen manager stores the reference of the different screens and allows switching between them. Each screen has its own life-cycle.
To create a screen manager with two screens, for example, declare them in Globals:

Dim lGdx_ScrMgr As lgScreenManager
Dim lGdx_Screen(2) As lgScreen

Then add these lines in the Create event handler:

'Creates two screens
lGdx_ScrMgr.Initialize(lGdx)
lGdx_Screen(0) = lGdx_ScrMgr.AddScreen("LGS1")
lGdx_Screen(1) = lGdx_ScrMgr.AddScreen("LGS2")

Show the first screen:

lGdx_ScrMgr.CurrentScreen = lGdx_Screen(0)

When you want to change the current screen, just change the value of the CurrentScreen property. That will raise the Hide event of the previous screen and the Show event of the new one.

The screens have the same life-cycle as the library, and thus the same events except that Create is named Show and Dispose is named Hide.

Input processor and gesture detector

To get the input events raised by your players, you have to declare input processors. libGDX has an input processor for keyboard and touch events (lgInputProcessor) and a specialized input processor for gestures (lgGestureDetector).
Start by declaring them in Globals:

Dim lGdx_IP As lgInputProcessor
Dim lGdx_GD As lgGestureDetector

Initialize them in the Create event (or the Show event of a screen if you want different processors for different screens):

lGdx_IP.Initialize("IP")
lGdx_GD.Initialize("GD")

And add the event handlers that you need:

Sub IP_KeyDown(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyUp(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyTyped(Character As Char) As Boolean
   Return False
End Sub

Sub IP_TouchDown(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchDragged(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchUp(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_TouchDown(X As Float, Y As Float, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_Fling(VelocityX As Float, VelocityY As Float) As Boolean
   Return False
End Sub

Sub GD_LongPress(X As Float, Y As Float) As Boolean
   Return False
End Sub

Sub GD_Pan(X As Float, Y As Float, DeltaX As Float, DeltaY As Float) As Boolean
   Return False
End Sub

Sub GD_Pinch(InitialPointer1 As lgMathVector2, InitialPointer2 As lgMathVector2, Pointer1 As lgMathVector2, Pointer2 As lgMathVector2) As Boolean
   Return False
End Sub

Sub GD_Tap(X As Float, Y As Float, Count As Int) As Boolean
   Return False
End Sub

Sub GD_Zoom(InitialDistance As Float, Distance As Float) As Boolean
    Return False
End Sub

Description of events :

Fling: The user quickly dragged a finger across the screen, then lifted it. Useful to implement swipe gestures.
Pan: The user is dragging a finger across the screen. The detector reports the current touch coordinates as well as the delta between the current and previous touch positions. Useful to implement camera panning in 2D.
Pinch: Similar to zoom. The detector reports the initial and current finger positions instead of the distance. Useful to implement camera zooming and more sophisticated gestures such as rotation.
Tap: The user touched the screen and lifted the finger. The finger must not move outside a specified square area around the initial touch position for a tap to be registered. Multiple consecutive taps will be detected if the user performs taps within a specified time interval.
Zoom: The user has placed two fingers on the screen and is moving them together/apart. The detector reports both the initial and current distance between fingers in pixels. Useful to implement camera zooming.

The other events are self-explanatory.

.....

 

[wonder]

@ilan, even if you don't succeed, you'll end up with a PhD in physics!
Carry on, don't be discouraged!

 

[ilan]

you'll end up with a PhD in physics!

sorry, but what means PhD??

Carry on, don't be discouraged!

you know me i am a fighter

 

[ilan]

is there any event for lgInputProcessor or lgGestureDetector that recognize if my finger is touching a specific area.
i dont mean thouchdown, because only when i touch it, it will be fired i mean when i still hold my finger on the same point

i tried to set a boolean to true when touchdown and then to false when touchup but the problem is, i have 4 buttons and i touch 2 at the same time
and on touch up all booleans goes to false and this is not what i want.

and if i would check the touchup (if it was on a specific area) this will also not be a good choice because i have in my game a gas pedal and a break pedal (+2 other buttons) if the user touch the break and then slide his finger out of the button area and then touch up the gas boolean will still be true and that is wrong
so i need to set all booleans to false on touchup but then if i cannot press 2 buttons simultaneously

what should i do? use the regular activity touch event?

 

[Informatix]

You should manage the touch events at the actor level, not at the screen level. Each Scene2D actor has its own event, so no confusion, no pointer handling, nothing special to do...

NEVER USE the activity events in a game made with libGDX, especially Keypress. It's a good way to get mysterious crashes.

 

[ilan]

i dont know if i understood you correctly
but what you mean is i need to create for each button a different Scene2d (lgScn2DActor) and handle the touch on it?

 

[Informatix]

i dont know if i understood you correctly
but what you mean is i need to create for each button a different Scene2d (lgScn2DActor) and handle the touch on it?

A lgScn2DButton is more appropriate for a button, but yes, that's the idea.
The HUD and all interactions with the player should be handled with Scene2D. Personally, I use Scn2D for almost everything. It makes things so simple. I just avoid it for parts that really needs performance.

 

[ilan]

thank you very much @Informatix, i did not knew libgdx got his own controls like button.
can you tell me please how the event of the lgbutton look like?

or is it just Sub Lgbtn_CLick ?

EDIT: or does your libgdx example got a button in it? if yes could you point me to that example? thank you

 

[Informatix]

thank you very much @Informatix, i did not knew lg got his own controls like button.
can you tell me please how the event of the lgbutton look like?

or is it just Sub Lgbtn_CLick ?

Try the various demos.

 

[ilan]

Try the various demos.

ok, i looked on some projects and i could found how to add a button and handle the event i also looked at the touchpad example and window example.
i could not figure out if the button has a touchdown/up event and how that event look like

so what i did i add a lgScn2DInputListener and handle the touchdown/up from there but is this the right way?
or does the button has his own touchdown/up events?

is there anywhere a documentation about all events for all libgdx controls?

thank you,

 

[Informatix]

ok, i looked on some projects and i could found how to add a button and handle the event i also looked at the touchpad example and window example.
i could not figure out if the button has a touchdown/up event and how that event look like

so what i did i add a lgScn2DInputListener and handle the touchdown/up from there but is this the right way?
or does the button has his own touchdown/up events?

is there anywhere a documentation about all events for all libgdx controls?

thank you,

This is covered in details in this thread. Just read post #3.

 

[Informatix]

is there anywhere a documentation about all events for all libgdx controls?

Do as usual: sub + space + tab + view selection

 

[melonZgz]

I'm not sure I understand the dispose event.
In the dispose event I dispose everything I can. I suppose it's correct (spritebatch, box2D world... everything witch has a dispose method)
But, when is it called? Because sometimes it's called after the pause event. Not usually, but sometimes it does. And it's a problem for me, because if it's called, in the resume event I have to create everything again. If I'm in a menu it doesn't care much, but if I am ingame (accidental home button, income call, or even when showing an ad), in some of those cases, after pause, if dispose is called, my Box2d world is disposed, and I have to create everything again? or restart the level?
Is it a problem if I don't dispose my box2d world?

 

[ilan]

income call, or even when showing an ad)

if Not(UserClosed) then ...
you can check if the user closed that activity and not an incoming call or an ad...

you can also catch the Back key (sub Activity_KeyPress) and ask if user want to exit the game set a boolean to true and if the user exits in a different way like home key that boolean will be false and u continue from the same point you left (don't dispose in that case).

 

[Informatix]

I'm not sure I understand the dispose event.
In the dispose event I dispose everything I can. I suppose it's correct (spritebatch, box2D world... everything witch has a dispose method)
But, when is it called? Because sometimes it's called after the pause event. Not usually, but sometimes it does. And it's a problem for me, because if it's called, in the resume event I have to create everything again. If I'm in a menu it doesn't care much, but if I am ingame (accidental home button, income call, or even when showing an ad), in some of those cases, after pause, if dispose is called, my Box2d world is disposed, and I have to create everything again? or restart the level?
Is it a problem if I don't dispose my box2d world?

It's clearly explained in the guide:

Dispose :

Dispose is called when the activity is exited, after Pause, or when the device is rotated.
In this event, release all the used resources by calling the Dispose function of objects (if they have one).

"Dispose" is required to deallocate the memory because libGDX calls internally a lot of C code and this C code does not benefit from a garbage collector. This offers a great advantage (fast code, all memory available) but has this minor drawback (memory has to be released explicitely when no longer used).

As suggested by Ilan, you can avoid calling the dispose routines by checking UserClosed.

 

[Informatix]

you can also catch the Back key (sub Activity_KeyPress) and ask if user want to exit the game set a boolean to true and if the user exits in a different way like home key that boolean will be false and u continue from the same point you left (don't dispose in that case).

It is dangerous to handle the Back Key with the Activity_KeyPress event in a libGdx game because all events are supposed to be seen and processed by the libGDX engine. You can have unexplained crashes when leaving a screen or an app by doing that as libGDX was not able to perform some internal operations.
The safe way is to handle this key in the Render event with lGdx.Input.IsKeyJustPressed(KeyCodes.KEYCODE_BACK). You have to set lGdx.Input.CatchBackKey to True before. You can also handle this key with the KeyPressed event of lgInputProcessor.

 

[ilan]

It is dangerous to handle the Back Key with the Activity_KeyPress event in a libGdx game because all events are supposed to be seen and processed by the libGDX engine. You can have unexplained crashes when leaving a screen or an app by doing that as libGDX was not able to perform some internal operations.
The safe way is to handle this key in the Render event with lGdx.Input.IsKeyJustPressed(KeyCodes.KEYCODE_BACK). You have to set lGdx.Input.CatchBackKey to True before. You can also handle this key with the KeyPressed event of lgInputProcessor.

thanx @Informatix, until today i used the backkey to exit my libgx game activity and i had never a crash report but i will definitely use your suggestion for my next libgdx box2d game

 

[melonZgz]

About rendering tiled maps:

It is also possible to create a texture atlas from an existing map with the TiledMapPacker tool. I recommend using it when you have visual issues while zooming or rescaling the map as it duplicates the edges of your tiles.

Only wanted to say that I've been facing this problem (visual issues, you can see the edges of some tiles) and the problem isn't there if you use power of 2 textures. I don't know if it's been said before, but It was driving me nuts until I saw the solution.

 

[wonder]

About rendering tiled maps:


Only wanted to say that I've been facing this problem (visual issues, you can see the edges of some tiles) and the problem isn't there if you use power of 2 textures. I don't know if it's been said before, but It was driving me nuts until I saw the solution.

I had the same problem, keyword: had.

a) What kind of value goes into your DrawRegion() or DrawTex() commands?
Is it a (result of) Int, Float or Double (calculations)?

b) Are you expriencing this problem with or without the Linear filter?

c) Are your texutures padded at least 2px away from the edges and each-other?

 

[Informatix]

c) Are your texutures padded at least 2px away from the edges and each-other?

This is almost mandatory when you deal with tiles. Without this padding, you're pretty sure to have visual issues on some devices.

 

[wonder]

This is almost mandatory when you deal with tiles. Without this padding, you're pretty sure to have visual issues on some devices.

Yep this and also making sure that, if you're using floats or doubles for your tile placement, the drawing "step" must be constant.

In my case:
BAD (before):
- Calculate tile placement (x, y) As Double
- Draw at (x, y)

GOOD (after):
- Calculate the placement of the first tile (x, y)
- Draw all the remainng tiles at (double) FirstTile_Offset(x, y) + (int) TileIterator(x, y) * (int) TileSize(x, y)

Example:

FirstTileX = 23.56
FirstTileY = 87.489

Dim w, h as Int
Dim x, y as Double
For ix = 0 To (maxHorizontalTilesOnScreen - 1)
    For iy = 0 To (maxVerticalTilesOnScreen - 1)
        w = TileWidth
        h = TileHeight
        x = FirstTileX + (ix * w)
        y = FirstTileY + (iy * h)
        Batch.DrawRegion2(tile, x, y, w, h)
    Next
Next