iOS Question [Solved] CSBuilder - MaterialIcon - doesn'twork on b4xview button/Label

[AymanA]

Hi All,

I am sorry if this is basic question as I am trying to grasp the transition from B4A to B4I, I am trying to assign MaterialIcon or fontawesome + text using CSBuilder.

Based on this link it should work with AttributedString, but can not find this when I am using b4xview (by button/label is b4xview as I am trying cross platform), so how can I achieve the below:

cs.Font(Font.CreateMaterialIcons(20)).Color(0xFF777777).Append(Chr(0xE7FD)).Append("test").PopAll
    Main_Button1.Text =  cs

Thanks in advance for the assistance

 

[Star-Dust]

MainButton1.AttributedText=Cs

see also

[B4X] Set CSBuilder or Text to a Label

Edit: This sub is included in XUI Views library: XUIViewsUtils.SetTextOrCSBuilderToLabel This sub accepts a string or CSBuilder and sets it as the Label's text. It is useful for cross platform solutions. Note that the Text parameter type is Object. Public Sub SetTextOrCSBuilderToLabel(xlbl As...

www.b4x.com

 

[AymanA]

MainButton1.AttributedText=Cs

Thank you for your reply, I am using b4xview so seems this attribute doesn't exist for b4xview:

But following the link works perfectly fine for the b4xview when checking if it is a label - still same problem if I am checking if it is a button - so seems the attributedtext only works with labels!

Thank you so much for for your help and all your contributions on this forum, I am a follower to your awesome work

 

[Star-Dust]

Yes, you are right, it only works with a Label.

Dim cs As CSBuilder
ButtonSetAttributedText(Button1, _
   cs.Initialize.Color(Colors.Red).Append("Click ").Font(Font.CreateNewBold(30)).Append("Me!!!").PopAll, _
   cs.Initialize.Color(Colors.Gray).Append("Click ").Font(Font.CreateNewBold(30)).Append("Me!!!").PopAll, _
   cs.Initialize.Append("disabled"))

Sub ButtonSetAttributedText(btn As Button, NormalText As AttributedString, HighlightedText As AttributedString, _
     DisabledText As AttributedString)
   Dim no As NativeObject = btn
   no.RunMethod("setAttributedTitle:forState:", Array(NormalText, 0))
   no.RunMethod("setAttributedTitle:forState:", Array(HighlightedText, 1))
   no.RunMethod("setAttributedTitle:forState:", Array(DisabledText, 2))
End Sub

see:

CSBuilder - AttributedStrings builder

AttributedStrings are strings with additional styling information. CSBuilder is a new type added in B4i v4.00 which helps with creating such strings. It is an alternative to iRichString class: https://www.b4x.com/android/forum/threads/48573/#content Note that unlike in B4A, where CharSequence...

www.b4x.com

 

[Star-Dust]

I would add this.

Public Sub SetTextOrCSBuilderToLabelOrButton(Label_or_Button As B4XView, Text As Object)
   #if B4A or B4J
   Label_or_Button.Text = Text
   #else if B4i
    If Text Is CSBuilder Then
        If Label_or_Button Is Label Then
            Dim lbl As Label = Label_or_Button
            lbl.AttributedText = Text
        else if Label_or_Button Is Button Then
            Dim no As NativeObject = Label_or_Button
            Dim AText As AttributedString = Text
            'normal text
            no.RunMethod("setAttributedTitle:forState:", Array(AText, 0))
            'Highlighted Text
            no.RunMethod("setAttributedTitle:forState:", Array(AText, 1))
            ' disabled text
            no.RunMethod("setAttributedTitle:forState:", Array(AText, 2))
        End If
    Else
        If GetType(Text) = "__NSCFNumber" Then Text = "" & Chr(Text)
        Label_or_Button.Text = Text
    End If
   #end if
End Sub

 

[AymanA]

I would add this.

Yaay! That Worked perfectly for both label and button! thank you so much for spending that time to help, I really appreciate it!