Android Tutorial [B4X] Smart String Literal

The "smart string" literal is a more powerful version of the standard string literal.
It has three advantages:

1. Supports multi-line strings.
2. No need to escape quotes.
3. Supports string interpolation.

The smart string literal starts with $" and ends with "$.
Examples:

Dim s As String = $"Hello world"$
Dim query As String = $"
SELECT value_id FROM table3
WHERE rowid >= random()%(SELECT max(rowid)FROM table3)
AND second_value ISNOTNULL
LIMIT 1"$
Log($"No need to escape "quotes"! "$)

String Interpolation

Smart strings can hold zero or more placeholders with code. The placeholders can be easily formatted.
A placeholder starts with $[optional formatter]{ and ends with }:

Log($"5 * 3 = ${5 * 3}"$) '5 * 3 = 15

You can put any code you like inside the placeholders.

Dim x = 1, y = 2, z = 4 As Int
Log($"x = ${x}, y = ${y}, z = ${Sin(z)}"$) 'x = 1, y = 2, z = -0.7568024953079282

This is a compile time feature. You cannot load the strings from a file for example.

Number Formatter

The number formatter allows you to set the minimum number of integers and the maximum number of fractions digits. It is similar to NumberFormat keyword.

The number formatter structure: MinIntegers.MaxFractions. MaxFractions component is optional.
Examples:

Dim h = 2, m = 15, s = 7 As Int
Log($"Remaining time $2{h}:$2{m}:$2{s}"$) 'Remaining time 02:15:07
Log($"10 / 7 = $0.3{10 / 7}"$) '10 / 7 = 1.429
Log($"$1.2{"The value is not a number!"}"$) 'NaN

Other Formatters

Note that the formatters are case insensitive.
Date - Equivalent to DateTime.Date:

Log($"Current date is $date{DateTime.Now}"$) 'Current date is 02/02/2015

Time - Equivalent to DateTime.Time:

Log($"Current time is $time{DateTime.Now}"$) 'Current time is 11:17:45

DateTime - Equivalent to DateTime.Date & " " & DateTime.Time:

Log($"Current time is $DateTime{DateTime.Now}"$) 'Current time is 02/02/2015 11:18:36

XML - Escapes the five XML entities (", ', <, >, &):

Dim UserString As String = $"will it break your parser ><'"&?"$
Log($"User input is: $xml{UserString}"$)
'User input is: will it break your parser &gt;&lt;&#39;&quot;&amp;?

This is also useful for html content.

 

[DonManfred]

As the output is HTML you just can use <br /> to create a new line

To output the date you can use dateutils methods inside the literal

Assuming you have a string datestr which you want to insert.

Use ${datestr}

 

[DonManfred]

    Dim dstart As Long = DateTime.DateTimeParse("01.5.2015","00:00")
    log(DateTime.Date(dstart))

will log the date.... To use this in the literal you can use it like this

Log($"The date is ${DateTime.Date(dstart)}"$)

this can be done in you
INITIAL_TEXT = $"html code..."$
too

 

[jmon]

Log($"The date is ${DateTime.Date(dstart)}"$)

Or

$"Today's Date : $Date{Datetime.now}."$

 

[Ed Brown]

Man! I wish I had seen this post for my last project! Smart Strings would have been a very handy feature.

Question: Are there any rules to Smart Strings in relation to obfuscation in Process_Globals? ie. Does obfuscation still work and do the same rules apply?

 

[Erel]

Nothing special. They will be obfuscated.

 

[stari]

hi
i wish to send string:
{
"$token": "36ada5b10da39a1347559321baf13063",
}
but i can't include $.
Any seuggestion ?

 

[Erel]

First option:

Dim s As String = $"
{
"${"$"}token": "36ada5b10da39a1347559321baf13063",
}
   "$

Better option:

Dim jg As JSONGenerator
jg.Initialize(CreateMap("$token": "36ada5b10da39a1347559321baf13063"))
Log(jg.ToPrettyString(4))

 

[stari]

First option:

Dim s As String = $"
{
"${"$"}token": "36ada5b10da39a1347559321baf13063",
}
   "$

Better option:

Dim jg As JSONGenerator
jg.Initialize(CreateMap("$token": "36ada5b10da39a1347559321baf13063"))
Log(jg.ToPrettyString(4))

thks

 

[stari]

And the best way for this :
{
"$token": "36ada5b10da39a1347559321baf13063",
"$distinct_id": "13793",
"$ip": "123.123.123.123",
"$set": {
"Address": "1313 Mockingbird Lane"
}
}

 

[Erel]

Dim m As Map = CreateMap("$token": ..., "$distinct_id": ..., "$set": CreateMap("Address": "1313..."))

For further discussion please start a new thread in the questions forum.

 

[johndb]

Syntax checking is not ignored within multi-line smart strings.

The following single line smart string statement works:

dim s as string = $"Sub xyz(var1, var2)"$

The following multi-line smart string statement fails as B4X thinks that it is code:

dim s as string =  _
$"
sub xyz(var1, var2)
"$

All text within the multi-line string should not be checked at all.

Is this a bug?

[SOLVED] You must start a line with the $" and text and the last line must end with "$ on the same lines:

dim s as string = _
$"Sub xyz (var1 as int, var2 as int) as int
return var1+var2
end sub"$

Thanks,

John

 

[Mahares]

It took me a while to figure out this convoluted way, although someone else may find a much simpler string literal and make a fool out of my solution.

Dim s As String = $"Sub${Chr(32 _
    )}xyz(var1, var2)
    "$
    Log(s)     'Displays: Sub xyz(var1, var2)

 

[Erel]

Is this a bug?

It is a limitation (by design) to allow the parser to build the document structure as fast as possible.

 

[avalle]

Does a Smart String help dealing with long strings which should not contain CRLF?
Currently I'm dealing with them as such:

resp.Write($"info="my long string...","$ & _
$"descr="my other long string","$ & _
$"etc etc..."$)

I would like to do it as such:

resp.Write($"info="my long string...", & _
descr="my other long string", & _
etc etc..."$)

Any chance? Thanks for your advice.

 

[Erel]

resp.Write($"sdjfklsdf
sd fjkwlefj lkwef
wef jwklefj wlkefj wlkef klwef
wefklwejfwlkefjwlkefj"$.Replace(CRLF, ""))

 

[avalle]

Makes sense thanks Erel

 

[LucaMs]

 

[Arya8867]

Can use this option in B4R IDE?

 

[Erel]

No. Only in B4A, B4i and B4J.

If you need to use a string with a quote inside then escape it with double quotes:

Dim s As String = "abd""efgh"

 

[JesseW]

If you need to use a string with a quote inside then escape it with double quotes:

in your CSVParser (which I greatly appreciate btw...) there is a line

word = word.Replace(QUOTE, $""""$)

if I'm understanding smart strings correctly, this could have also been writen as

word = word.Replace(QUOTE, """""")

is this correct?