Android Tutorial [B4X] Smart String Literal

Erel · Feb 2, 2015

The "smart string" literal is a more powerful version of the standard string literal.
It has three advantages:

Supports multi-line strings.
No need to escape quotes.
Supports string interpolation.

The smart string literal starts with $" and ends with "$.
Examples:

B4X:

Dim s As String = $"Hello world"$
Dim query As String = $"
SELECT value_id FROM table3
WHERE rowid >= random()%(SELECT max(rowid)FROM table3)
AND second_value ISNOTNULL
LIMIT 1"$
Log($"No need to escape "quotes"! "$)

String Interpolation

Smart strings can hold zero or more placeholders with code. The placeholders can be easily formatted.
A placeholder starts with $[optional formatter]{ and ends with }:

B4X:

Log($"5 * 3 = ${5 * 3}"$) '5 * 3 = 15

You can put any code you like inside the placeholders.

B4X:

Dim x = 1, y = 2, z = 4 As Int
Log($"x = ${x}, y = ${y}, z = ${Sin(z)}"$) 'x = 1, y = 2, z = -0.7568024953079282

This is a compile time feature. You cannot load the strings from a file for example.

Number Formatter

The number formatter allows you to set the minimum number of integers and the maximum number of fractions digits. It is similar to NumberFormat keyword.

The number formatter structure: MinIntegers.MaxFractions. MaxFractions component is optional.
Examples:

B4X:

Dim h = 2, m = 15, s = 7 As Int
Log($"Remaining time $2{h}:$2{m}:$2{s}"$) 'Remaining time 02:15:07
Log($"10 / 7 = $0.3{10 / 7}"$) '10 / 7 = 1.429
Log($"$1.2{"The value is not a number!"}"$) 'NaN

Other Formatters

Note that the formatters are case insensitive.
Date - Equivalent to DateTime.Date:

B4X:

Log($"Current date is $date{DateTime.Now}"$) 'Current date is 02/02/2015

Time - Equivalent to DateTime.Time:

B4X:

Log($"Current time is $time{DateTime.Now}"$) 'Current time is 11:17:45

DateTime - Equivalent to DateTime.Date & " " & DateTime.Time:

B4X:

Log($"Current time is $DateTime{DateTime.Now}"$) 'Current time is 02/02/2015 11:18:36

XML - Escapes the five XML entities (", ', <, >, &):

B4X:

Dim UserString As String = $"will it break your parser ><'"&?"$
Log($"User input is: $xml{UserString}"$)
'User input is: will it break your parser &gt;&lt;&#39;&quot;&amp;?

This is also useful for html content.

DonManfred · Sep 1, 2015

As the output is HTML you just can use <br /> to create a new line

To output the date you can use dateutils methods inside the literal

Assuming you have a string datestr which you want to insert.

Use ${datestr}

DonManfred · Sep 1, 2015

B4X:

    Dim dstart As Long = DateTime.DateTimeParse("01.5.2015","00:00")
    log(DateTime.Date(dstart))

will log the date.... To use this in the literal you can use it like this

B4X:

Log($"The date is ${DateTime.Date(dstart)}"$)

this can be done in you
INITIAL_TEXT = $"html code..."$
too

jmon · Sep 1, 2015

DonManfred said:
Log($"The date is ${DateTime.Date(dstart)}"$)

Or

B4X:

$"Today's Date : $Date{Datetime.now}."$

Ed Brown · Dec 10, 2015

Man! I wish I had seen this post for my last project! Smart Strings would have been a very handy feature.

Question: Are there any rules to Smart Strings in relation to obfuscation in Process_Globals? ie. Does obfuscation still work and do the same rules apply?

Erel · Dec 10, 2015

Nothing special. They will be obfuscated.

stari · Nov 7, 2016

hi
i wish to send string:
{
"$token": "36ada5b10da39a1347559321baf13063",
}
but i can't include $.
Any seuggestion ?

Erel · Nov 7, 2016

First option:

B4X:

Dim s As String = $"
{
"${"$"}token": "36ada5b10da39a1347559321baf13063",
}
   "$

Better option:

B4X:

Dim jg As JSONGenerator
jg.Initialize(CreateMap("$token": "36ada5b10da39a1347559321baf13063"))
Log(jg.ToPrettyString(4))

stari · Nov 7, 2016

Erel said:

First option:

B4X:

Dim s As String = $"
{
"${"$"}token": "36ada5b10da39a1347559321baf13063",
}
   "$

Better option:

B4X:

Dim jg As JSONGenerator
jg.Initialize(CreateMap("$token": "36ada5b10da39a1347559321baf13063"))
Log(jg.ToPrettyString(4))

thks

stari · Nov 7, 2016

And the best way for this :
{
"$token": "36ada5b10da39a1347559321baf13063",
"$distinct_id": "13793",
"$ip": "123.123.123.123",
"$set": {
"Address": "1313 Mockingbird Lane"
}
}

Erel · Nov 7, 2016

B4X:

Dim m As Map = CreateMap("$token": ..., "$distinct_id": ..., "$set": CreateMap("Address": "1313..."))

For further discussion please start a new thread in the questions forum.

johndb · Dec 29, 2016

Syntax checking is not ignored within multi-line smart strings.

The following single line smart string statement works:

B4X:

dim s as string = $"Sub xyz(var1, var2)"$

The following multi-line smart string statement fails as B4X thinks that it is code:

B4X:

dim s as string =  _
$"
sub xyz(var1, var2)
"$

All text within the multi-line string should not be checked at all.

Is this a bug?

[SOLVED] You must start a line with the $" and text and the last line must end with "$ on the same lines:

B4X:

dim s as string = _
$"Sub xyz (var1 as int, var2 as int) as int
return var1+var2
end sub"$

Thanks,

John

Mahares · Dec 30, 2016

It took me a while to figure out this convoluted way, although someone else may find a much simpler string literal and make a fool out of my solution.

B4X:

Dim s As String = $"Sub${Chr(32 _
    )}xyz(var1, var2)
    "$
    Log(s)     'Displays: Sub xyz(var1, var2)

Erel · Dec 30, 2016

johndb said:
Is this a bug?

It is a limitation (by design) to allow the parser to build the document structure as fast as possible.

avalle · Jan 3, 2018

Does a Smart String help dealing with long strings which should not contain CRLF?
Currently I'm dealing with them as such:

B4X:

resp.Write($"info="my long string...","$ & _
$"descr="my other long string","$ & _
$"etc etc..."$)

I would like to do it as such:

B4X:

resp.Write($"info="my long string...", & _
descr="my other long string", & _
etc etc..."$)

Any chance? Thanks for your advice.

Erel · Jan 3, 2018

B4X:

resp.Write($"sdjfklsdf
sd fjkwlefj lkwef
wef jwklefj wlkefj wlkef klwef
wefklwejfwlkefjwlkefj"$.Replace(CRLF, ""))

avalle · Jan 3, 2018

Makes sense thanks Erel

LucaMs · Oct 22, 2019

Arya8867 · Oct 22, 2019

Can use this option in B4R IDE?

Erel · Oct 23, 2019

No. Only in B4A, B4i and B4J.

If you need to use a string with a quote inside then escape it with double quotes:

B4X:

Dim s As String = "abd""efgh"

JesseW · Oct 3, 2021

Erel said:
If you need to use a string with a quote inside then escape it with double quotes:

in your CSVParser (which I greatly appreciate btw...) there is a line

B4X:

word = word.Replace(QUOTE, $""""$)

if I'm understanding smart strings correctly, this could have also been writen as

B4X:

word = word.Replace(QUOTE, """""")

is this correct?

Android Tutorial [B4X] Smart String Literal

Expert

Expert

Well-Known Member

Active Member

B4X founder

Active Member

B4X founder

Active Member

Active Member

B4X founder

Active Member

Expert

B4X founder

Active Member

B4X founder

Active Member

Expert

Member

B4X founder

Active Member

Privacy & Transparency

Privacy & Transparency