Italian DataBase con coordinate autovelox

private Sub Get_Autovelox(CurrentLocation As Location)
    
    Dim RS As ResultSet
    Dim AutoveloxFounded As List

    GettingAutovelox = True
    
    Sleep(0)
        
    'Inizializzo la list degli id degli autovelox trovati per non reinserirli dopo il primo inserimento
    If AutoveloxFoundedId.IsInitialized = False Then
        AutoveloxFoundedId.Initialize
    End If
    
    'Cerco gli autovelox nella zona e alla distanza specificata
    Try
        
        RS = Functions.SQLConn.ExecQuery("SELECT * FROM Autovelox WHERE (Latitude > " & _
        (CurrentLocation.Latitude-(AppSettings.AutoveloxDistance/100000)) & " And Latitude < " & (CurrentLocation.Latitude+(AppSettings.AutoveloxDistance/100000)) & _
        ") And (Longitude > " & (CurrentLocation.Longitude-(AppSettings.AutoveloxDistance/100000)) & " And Longitude < " & (CurrentLocation.Longitude+(AppSettings.AutoveloxDistance/100000)) & ")")
        
        RS.Position = 0
        
        'Numero di autovelox trovati
        AutoveloxCounter = RS.RowCount

    Catch
        
        AutoveloxCounter = 0
        
    End Try
        
    'se li trovo nell'intervallo specificato li visualizzo
    If AutoveloxCounter > 0 Then
        
        'Inizializzo la list degli autovelox trovati ogni volta per aggiornare il dato della distanza
        AutoveloxFounded.Initialize
            
        RS.Position = 0

        'Per ogni autovelox del recordset che ho trovato nella distanza specificata
        For i = 0 To (RS.RowCount-1)
            
            Dim Autovelox As AutoveloxProp
                
            RS.Position = i
                        
            '***Inserisco l'autovelox se non già trovato
            If AutoveloxFoundedId.IndexOf(RS.GetInt("Id")) = -1 Then
                
                'inserisco id dell'autovelox nella list di quelli già trovati   
                AutoveloxFoundedId.Add(RS.GetInt("Id"))
                
                'Visualizzo l'autovelox sulla mappa
                GoogleMap.AddMarker3(RS.GetDouble("Latitude"),RS.GetDouble("Longitude"),"Autovelox",LoadBitmap(File.DirAssets,"Autovelox.png"))
                                
            End If
            
            'Salvo le proprietà dell'autovelox nella list di quelli trovati
            Autovelox.AutoveloxId = RS.GetInt("Id")
            Autovelox.Latitude = RS.GetDouble("Latitude")
            Autovelox.Longitude = RS.GetDouble("Longitude")
            Autovelox.Lim = RS.GetInt("Lim")
            Autovelox.Dist = Get_AutoveloxDist(CurrentLocation,Autovelox)
            AutoveloxFounded.Add(Autovelox)
            
        Next
        
        '***Ordino per distanza dalla più piccola alla più grossa per trovare l'autovelox più vicino
        AutoveloxFounded.SortType("Dist",True)
        Dim NearestAutovelox As AutoveloxProp
        NearestAutovelox = AutoveloxFounded.Get(0)
        AutoveloxDistShowed_Update(NearestAutovelox)
        
        'Se non ho ancora visualizzato l'informazione sull'autovelox la visualizzo
        If AutoveloxAlertEnabled = False Then Autovelox_Alert
    
    Else if AutoveloxCounter = 0 Then
        
        AutoveloxAlertEnabled = False
        
    End If
        
    GettingAutovelox = False

End Sub

private Sub Get_AutoveloxDist(CurrentLocation As Location,Autovelox As AutoveloxProp) As Float
  
    Dim AutoveloxLocation As Location
  
    'Calcolo la distanza di ogni autovelox trovato nella distanza specificata
    AutoveloxLocation.Initialize
    AutoveloxLocation.Latitude = Autovelox.Latitude
    AutoveloxLocation.Longitude = Autovelox.Longitude

    Return AutoveloxLocation.DistanceTo(CurrentLocation)

End Sub