Android Tutorial Introduction to the libGDX library

Informatix · Sep 12, 2013

Introduction to the libGDX library

What is libGDX ?

libGDX is a game engine. As we saw in the first tutorial, a game engine provides a framework to create games and covers all aspects (rendering, animation, input, music, networking, physics, ...) of various kinds of games.

libGDX is considered as one of the best and fastest engine for the Android world. It is free, rich-featured, reliable, and proved its efficiency in a lot of well-known games (Ingress, Zombie Smasher, Apparatus, Monsterama Park, Clash of the Olympians, Bumbledore, etc.)

It’s a layered framework: it goes from low-level classes for OpenGL experts to high-level classes, easy to use by beginners. It includes a scene graph (Scene2D classes), a physics engine (Box2D classes), a particle system, a map renderer, a sprite batcher, an extensive set of mathematics classes… more than 200 classes in total.

For technical reasons, the version for Basic4Android cannot be multi-platform, and by choice, the current release doesn't include the 3D classes (except the ones for the perspective camera and for the decals) and the Daydream class.

libGDX was created in 2010 by Mario Zechner (badlogicgames.com) and is maintained by M. Zechner, Nathan Sweet (esotericsoftware.com) and a community of developers.

Minimum requirements

OpenGL ES 2.0
Android Froyo (API 8)

Hardware acceleration

libGDX does not require that you enable hardware acceleration on your device because it is based on OpenGL, which interacts directly with the GPU.

Debugging

You cannot use the debugger of B4A with libGDX because most of the code of the library runs in a different thread. You have to use the Log() function to debug your game.

The library provides a debug renderer for Box2D (lgBox2DDebugRenderer), a debug renderer for Scene2D (lgScn2DDebugRenderer) and a profiler for OpenGL (lgGLProfiler).

A word about the classes

The main class is LibGDX. All other classes are prefixed by lg.
All Box2D classes are prefixed by lgBox2D. All Scene2D classes are prefixed by lgScn2D. All Map classes are prefixed by lgMap. All Math classes are prefixed by lgMath.

The LibGDX class gives access to five interfaces: Audio (lgAudio), Files (lgFiles), Graphics (lgGraphics), Input (lgInput), and Net (lgNet). You will use the Input interface, for example, to get the input from the accelerometer.

With some classes (e.g. the five interfaces), you cannot create a new instance with Dim. You have to use an instance returned by the library. For example, you cannot write:

B4X:

Dim Graphics As lgGraphics
Graphics = lGdx.Graphics

but you can write:

B4X:

Dim Graphics As lgGraphics = lGdx.Graphics

Some classes cannot be instantiated at all because they are generic classes (e.g. com.badlogic.gdx.scenes.scene2d.utils.Drawable or com.badlogic.gdx.maps.tiled.TiledMapTile). In this case, either you store their instance as an Object or you use a subclass, e.g.:

B4X:

Dim objTile As Object = CurrentLayer.GetCell(X, Y).Tile
Dim staticTile As lgMapStaticTiledMapTile = CurrentLayer.GetCell(X, Y).Tile

OpenGL ES

I explained what OpenGL is in the previous tutorial and I won't discuss it further here because the main advantage to use a game engine like libGDX is to benefit from the abstraction layer above OpenGL. However, if you need (or want) to call directly OpenGL, here's how to get access to the classes and functions:

B4X:

Dim lGdx_GL20 As lgGL20 = lGdx.Graphics.GL20

or better (includes also the constants):

B4X:

Dim GL As lgGL

Note: libGDX uses the 2D coordinate system and the color encoding of OpenGL ES, so the Y-axis is pointing upwards and each color value ranges from 0 to 1.

The libGDX life-cycle

An important thing to keep in mind about libGDX is that it runs in its own thread. Your Basic4Android application runs most of the time in a different thread called the UI thread, or main thread. That means you cannot access the other views of your activity and change their properties from the libGDX thread. Fortunately, there's a function in the LibGDX class that passes the runnable (the piece of code to execute) from a thread to the other: CallSubUI. So if you want to change the activity title, set a label text or show a MsgBox from the libGDX thread, don't forget to use this function to avoid a crash!

Since libGDX runs in a different thread, you have to inform its library of the events of your activity : Create, Pause and Resume. First, create an instance of libGDX in Globals :

B4X:

Dim lGdx As libGDX

In Activity_Create (and nowhere else), add the Initialize function :

B4X:

lGdx.Initialize(False, "LG") 'fills the activity with the libGDX surface, uses OpenGL 1 for compatibility and prefixes the events with LG

In Activity_Resume, add the following line :

B4X:

If lGdx.IsInitialized Then lGdx.Resume

In Activity_Pause, add the following line :

B4X:

If lGdx.IsInitialized Then lGdx.Pause

You could initialize libGDX differently. For example, it could be limited to a view with InitializeView. You could also define a configuration (lgConfiguration class) and pass it to libGDX. Example:

B4X:

Dim Config As lgConfiguration

'Disables the accelerometer and the compass
Config.useAccelerometer = False
Config.useCompass = False

'Uses a WakeLock (the device will stay on)
Config.useWakelock = True

'Creates the libGDX surface
lGdx.Initialize2(Config, "LG")

Once done, your library is ready to raise the events of its life-cycle : Create, Resize, Render, Pause, Resume, Dispose. These events are the place to put all the code of your game. Don't put anything in the usual activity events. They are reserved for your other views and are raised by the UI thread.

Create :

Create is the first raised event. It is raised soon after the initialization of the library and the creation of the OpenGL surface.
In this event, initialize your renderer and your input processors, load your resources (we'll see that in detail later) and initialize your game data.

Resize :

Resize is raised when the size of the libGDX surface changes. Under Android, that should only happen when you start the application and when it is restarted after a rotation or resumed.
It is raised at least once, after Create, and, when the application is resumed, just before Resume.
In this event, initialize the camera viewport. It's probably the only use you will find for it.
This event returns the new width and height in pixels.

Render :

Render is raised as soon as possible after Create and Resize.
It's where things are drawn. It's also where you have to put the logic of your game, but I would not recommend putting hundreds of lines of code here. Instead, create new subs and new modules and call them from this event.
The first lines in Render should be to clear the screen. Example:

B4X:

lGdx_GL.glClearColor(0, 0, 1, 1) 'Blue background
lGdx_GL.glClear(lGdx_GL.GL10_COLOR_BUFFER_BIT)

Pause :

Pause is raised when the activity is sent in the background, rotated or exited.
It's the right place to save your game data.
Note that the OpenGL context is destroyed when the app goes in the background, so all your unmanaged textures and pixmaps have to be reloaded or recreated in the Resume event when the app returns to the foreground.

Resume :

Contrary to the Resume event of your activity, this one is not raised after Create, only when the application returns from a pause.
As the OpenGL context is destroyed when the app goes in the background, all your unmanaged* textures and pixmaps have to be reloaded or recreated when this event is raised. More info here. *Not loaded by an asset manager.

Dispose :

Dispose is called when the activity is exited, after Pause, or when the device is rotated.
In this event, release all the used resources by calling the Dispose function of objects (if they have one).

The life-cycle :

Multiple screens

A game is made of many screens. You could create an activity for each one, but that would not be very convenient because you'd have to reinitialize the library in each activity and reload some resources. Moreover, that would not ease any graphical transition between screens. In fact, most games are made with a very small number of activities and make use of a screen manager instead. The screen manager stores the reference of the different screens and allows switching between them. Each screen has its own life-cycle.
To create a screen manager with two screens, for example, declare them in Globals:

B4X:

Dim lGdx_ScrMgr As lgScreenManager
Dim lGdx_Screen(2) As lgScreen

Then add these lines in the Create event handler:

B4X:

'Creates two screens
lGdx_ScrMgr.Initialize(lGdx)
lGdx_Screen(0) = lGdx_ScrMgr.AddScreen("LGS1")
lGdx_Screen(1) = lGdx_ScrMgr.AddScreen("LGS2")

Show the first screen:

B4X:

lGdx_ScrMgr.CurrentScreen = lGdx_Screen(0)

When you want to change the current screen, just change the value of the CurrentScreen property. That will raise the Hide event of the previous screen and the Show event of the new one.

The screens have the same life-cycle as the library, and thus the same events except that Create is named Show and Dispose is named Hide.

Input processor and gesture detector

To get the input events raised by your players, you have to declare input processors. libGDX has an input processor for keyboard and touch events (lgInputProcessor) and a specialized input processor for gestures (lgGestureDetector).
Start by declaring them in Globals:

B4X:

Dim lGdx_IP As lgInputProcessor
Dim lGdx_GD As lgGestureDetector

Initialize them in the Create event (or the Show event of a screen if you want different processors for different screens):

B4X:

lGdx_IP.Initialize("IP")
lGdx_GD.Initialize("GD")

And add the event handlers that you need:

B4X:

Sub IP_KeyDown(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyUp(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyTyped(Character As Char) As Boolean
   Return False
End Sub

Sub IP_TouchDown(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchDragged(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchUp(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_TouchDown(X As Float, Y As Float, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_Fling(VelocityX As Float, VelocityY As Float) As Boolean
   Return False
End Sub

Sub GD_LongPress(X As Float, Y As Float) As Boolean
   Return False
End Sub

Sub GD_Pan(X As Float, Y As Float, DeltaX As Float, DeltaY As Float) As Boolean
   Return False
End Sub

Sub GD_Pinch(InitialPointer1 As lgMathVector2, InitialPointer2 As lgMathVector2, Pointer1 As lgMathVector2, Pointer2 As lgMathVector2) As Boolean
   Return False
End Sub

Sub GD_Tap(X As Float, Y As Float, Count As Int) As Boolean
   Return False
End Sub

Sub GD_Zoom(InitialDistance As Float, Distance As Float) As Boolean
    Return False
End Sub

Description of events :

Fling: The user quickly dragged a finger across the screen, then lifted it. Useful to implement swipe gestures.
Pan: The user is dragging a finger across the screen. The detector reports the current touch coordinates as well as the delta between the current and previous touch positions. Useful to implement camera panning in 2D.
Pinch: Similar to zoom. The detector reports the initial and current finger positions instead of the distance. Useful to implement camera zooming and more sophisticated gestures such as rotation.
Tap: The user touched the screen and lifted the finger. The finger must not move outside a specified square area around the initial touch position for a tap to be registered. Multiple consecutive taps will be detected if the user performs taps within a specified time interval.
Zoom: The user has placed two fingers on the screen and is moving them together/apart. The detector reports both the initial and current distance between fingers in pixels. Useful to implement camera zooming.

The other events are self-explanatory.

.....

Informatix · Nov 18, 2016

wonder said:
Since I'm never going to use FlipY, I could remove it to make it lighter:

B4X:

public static byte[] GetDefaultFrameBufferPixels (int X, int Y, int Width, int Height) { Gdx.gl.glPixelStorei(GL20.GL_PACK_ALIGNMENT, 1); final ByteBuffer pixels = BufferUtils.newByteBuffer(Width * Height * 4); Gdx.gl.glReadPixels(X, Y, Width, Height, GL20.GL_RGBA, GL20.GL_UNSIGNED_BYTE, pixels); final int numBytes = Width * Height * 4; byte[] lines = new byte[numBytes]; pixels.clear(); pixels.get(lines); return lines; }

But... why return "lines" instead of "pixels"? How is "lines" affected by pixels.get(lines)?

ByteBuffer is not usable by a B4A user.

wonder · Nov 18, 2016

So that would be the fastest solution...
Using FastIO for sending GetDefaultFrameBufferPixels to the specified destination. Correct?

You mentioned zipping the data. Wouldn't this slowdown the operation a lot, since it would be called 60 times per second? If not, which lib should I go with?

Informatix · Nov 18, 2016

wonder said:
So that would be the fastest solution...
Using FastIO for sending GetDefaultFrameBufferPixels to the specified destination. Correct?

You mentioned zipping the data. Wouldn't this slowdown the operation a lot, since it would be called 60 times per second? If not, which lib should I go with?

Unless you have a communication channel beween the two devices that allows to transfer directly bytes (the file would be no longer needed).

wonder · Nov 18, 2016

Informatix said:
Unless you have a communication channel beween the two devices

Yes, that what I'm after.

UDP seems like a good candidate, it should be easy to implement a receiver/decoder.
https://www.b4x.com/android/help/network.html#udpsocket

wonder · Nov 18, 2016

Sorry to double-post, but please tell me, would this code work?

B4X:

public static byte[] GetDefaultFrameBufferPixels (int X, int Y, int Width, int Height)
{  
    final ByteBuffer pixels = BufferUtils.newByteBuffer(Width * Height * 4);
    Gdx.gl.glPixelStorei(GL20.GL_PACK_ALIGNMENT, 1);
    Gdx.gl.glReadPixels(X, Y, Width, Height, GL20.GL_RGBA, GL20.GL_UNSIGNED_BYTE, pixels);  
    pixels.clear();
    return pixels.array();
}

Informatix · Nov 18, 2016

wonder said:

Sorry to double-post, but please tell me, would this code work?

B4X:

public static byte[] GetDefaultFrameBufferPixels (int X, int Y, int Width, int Height)
{ 
    final ByteBuffer pixels = BufferUtils.newByteBuffer(Width * Height * 4);
    Gdx.gl.glPixelStorei(GL20.GL_PACK_ALIGNMENT, 1);
    Gdx.gl.glReadPixels(X, Y, Width, Height, GL20.GL_RGBA, GL20.GL_UNSIGNED_BYTE, pixels); 
    pixels.clear();
    return pixels.array();
}

Why don't you try it? It's the best way to know.

wonder · Nov 18, 2016

I don't have the LibGDX source... right?

Informatix · Nov 18, 2016

wonder said:
I don't have the LibGDX source... right?

So what do you want to do with this code?

wonder · Nov 19, 2016

I thought you could want to give it a try (could be implemented as GetDefaultFrameBufferPixels2).
Not that is better than yours, but as it has less lines of code it could perform a tiny bit faster...

I know that LibGDX (B4A) is not open-source but I just wanted to contribute.

Informatix · Nov 21, 2016

wonder said:
I thought you could want to give it a try (could be implemented as GetDefaultFrameBufferPixels2).
Not that is better than yours, but as it has less lines of code it could perform a tiny bit faster...

I know that LibGDX (B4A) is not open-source but I just wanted to contribute.

No, I won't add it because it's too specific and I'm not convinced that you will get a significant boost to performance.

wonder · Nov 21, 2016

It's okay, I was able to implement it with a little bit of Java here and there.

ilan · Nov 29, 2016

hi @Informatix (i am pointing this question to you because you wrapped the wonderful libgdx lib and only u can answer this questions)

question1:

i see a lot of tutorials in the net where you can do something like this:

vec2A = vec2B - vec2C

get a vector from calculating 2 other vectors but in b4a libgdx it is not working i am getting an "type does not match" error.
is this a limitation?

question2:

i have in my latest box2d game 2 dynamic bodies that both are connected with a distanceJoint to a separate static body

and i let them swing. (something like this)

now the problem is when they collide on a specific force one of the dynamic body loose the joint and start flying very fast all over the screen.
is this a bug? or am i doing something wrong?

if you need a sample project that demonstrate this behavior let me know.

thanks in advance, ilan

ilan · Dec 2, 2016

regarding to my last question post #252. question 2 in not relevant, sorry it was my mistake joint works as expected.

Informatix · Dec 2, 2016

ilan said:
hi @Informatix
i see a lot of tutorials in the net where you can do something like this:

vec2A = vec2B - vec2C

This is not possible in the original library, and not possible in the wrapper too.
You have to use the sub function of lgMathVector2.

wonder · Dec 2, 2016

Not sure if it helps but...

Generally speaking, you can sum/subtract vectors like this:

B4X:

'Pseudocode:

'Deconstruct Vector A into XY components
- VecA_x = cos(VecA_angle) * VecA_magnitude
- VecA_y = sin(VecA_angle) * VecA_magnitude

'Deconstruct Vector B into XY components
- VecB_x = cos(VecB_angle) * VecB_magnitude
- VecB_y = sin(VecB_angle) * VecB_magnitude

'Sum/Subtract XY components
- VecC_x = VecA_x + VecB_x
- VecC_y = VecA_y + VecB_y

'Construct vector C
- VecC_angle     = atan2(vecC_y, vecC_x)
- VecC_magnitude = sqrt(vecC_x^2 + vecC_y^2)

I think there are more ways to do it, by the way...

ilan · Dec 3, 2016

Informatix said:
You have to use the sub function of lgMathVector2.

ohh, i have not noticed those function.

B4X:

    Dim vec2,vec3 As lgMathVector2
    vec2.Set(-3,4)
    vec3.Set(2,4)
    vec2.add(vec3)
    Log(vec2)
    vec3.sub(vec2)
    Log(vec3)

[-1.0:8.0]
[3.0:-4.0]

thanks a lot @Informatix

wimpie3 · Mar 14, 2017

I've noticed that when I use lgmusic.play, the first 100ms are sometimes dropped (not always, about 80% of the time). Anything I can do about this? Can this be a hardware problem?

Informatix · Mar 14, 2017

wimpie3 said:
I've noticed that when I use lgmusic.play, the first 100ms are sometimes dropped (not always, about 80% of the time). Anything I can do about this? Can this be a hardware problem?

No idea.

rkwan · Mar 22, 2018

New
Hello, I am a newbie trying to use this good example to plot 3D scatter points.
However, I find that I cannot use the ShRdr.Point() to display anthing after drawing the axis lines
while using Shrdr.Circle2() can draw the circle.

B4X:

ShRdr.Begin(ShRdr.SHAPETYPE_Line)
   
        'Draws the 3 axis
        ShRdr.Color = Color1.WHITE
        ShRdr.Line2(0, 0, 0, 1, 0, 0)
        ShRdr.Line2(0, 0, 0, 0, 1, 0)
        ShRdr.Line2(0, 0, 0, 0, 0, 1)
    ShRdr.End
    'ShRdr.Begin(ShRdr.SHAPETYPE_Filled)
    ShRdr.Begin(ShRdr.SHAPETYPE_Point)
    ShRdr.Color = Color1.RED
    'ShRdr.Circle2(0,0,0.2,16)
    ShRdr.Point(0.5, 0.5, 0.5)
    ShRdr.End

Is it because I miss some other step/s before I can call the ShRdr.Point() please?!

Thanks & Best Regards,
Robert

Informatix · Mar 22, 2018

rkwan said:
New
Hello, I am a newbie trying to use this good example to plot 3D scatter points.
However, I find that I cannot use the ShRdr.Point() to display anthing after drawing the axis lines
while using Shrdr.Circle2() can draw the circle.

B4X:

ShRdr.Begin(ShRdr.SHAPETYPE_Line) 'Draws the 3 axis ShRdr.Color = Color1.WHITE ShRdr.Line2(0, 0, 0, 1, 0, 0) ShRdr.Line2(0, 0, 0, 0, 1, 0) ShRdr.Line2(0, 0, 0, 0, 0, 1) ShRdr.End 'ShRdr.Begin(ShRdr.SHAPETYPE_Filled) ShRdr.Begin(ShRdr.SHAPETYPE_Point) ShRdr.Color = Color1.RED 'ShRdr.Circle2(0,0,0.2,16) ShRdr.Point(0.5, 0.5, 0.5) ShRdr.End

Is it because I miss some other step/s before I can call the ShRdr.Point() please?!

Thanks & Best Regards,
Robert

I just tried your code and I saw nothing wrong with the Point function. There's a red point displayed at the right place. Note that a point is very small so it may be hard to notice on your device. Change the color to white or yellow to make it more obvious.

Android Tutorial Introduction to the libGDX library

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Well-Known Member

Expert

Member

Expert

Similar Threads

Privacy & Transparency

Privacy & Transparency