Android Tutorial Introduction to the libGDX library

Informatix · Sep 12, 2013

Introduction to the libGDX library

What is libGDX ?

libGDX is a game engine. As we saw in the first tutorial, a game engine provides a framework to create games and covers all aspects (rendering, animation, input, music, networking, physics, ...) of various kinds of games.

libGDX is considered as one of the best and fastest engine for the Android world. It is free, rich-featured, reliable, and proved its efficiency in a lot of well-known games (Ingress, Zombie Smasher, Apparatus, Monsterama Park, Clash of the Olympians, Bumbledore, etc.)

It’s a layered framework: it goes from low-level classes for OpenGL experts to high-level classes, easy to use by beginners. It includes a scene graph (Scene2D classes), a physics engine (Box2D classes), a particle system, a map renderer, a sprite batcher, an extensive set of mathematics classes… more than 200 classes in total.

For technical reasons, the version for Basic4Android cannot be multi-platform, and by choice, the current release doesn't include the 3D classes (except the ones for the perspective camera and for the decals) and the Daydream class.

libGDX was created in 2010 by Mario Zechner (badlogicgames.com) and is maintained by M. Zechner, Nathan Sweet (esotericsoftware.com) and a community of developers.

Minimum requirements

OpenGL ES 2.0
Android Froyo (API 8)

Hardware acceleration

libGDX does not require that you enable hardware acceleration on your device because it is based on OpenGL, which interacts directly with the GPU.

Debugging

You cannot use the debugger of B4A with libGDX because most of the code of the library runs in a different thread. You have to use the Log() function to debug your game.

The library provides a debug renderer for Box2D (lgBox2DDebugRenderer), a debug renderer for Scene2D (lgScn2DDebugRenderer) and a profiler for OpenGL (lgGLProfiler).

A word about the classes

The main class is LibGDX. All other classes are prefixed by lg.
All Box2D classes are prefixed by lgBox2D. All Scene2D classes are prefixed by lgScn2D. All Map classes are prefixed by lgMap. All Math classes are prefixed by lgMath.

The LibGDX class gives access to five interfaces: Audio (lgAudio), Files (lgFiles), Graphics (lgGraphics), Input (lgInput), and Net (lgNet). You will use the Input interface, for example, to get the input from the accelerometer.

With some classes (e.g. the five interfaces), you cannot create a new instance with Dim. You have to use an instance returned by the library. For example, you cannot write:

B4X:

Dim Graphics As lgGraphics
Graphics = lGdx.Graphics

but you can write:

B4X:

Dim Graphics As lgGraphics = lGdx.Graphics

Some classes cannot be instantiated at all because they are generic classes (e.g. com.badlogic.gdx.scenes.scene2d.utils.Drawable or com.badlogic.gdx.maps.tiled.TiledMapTile). In this case, either you store their instance as an Object or you use a subclass, e.g.:

B4X:

Dim objTile As Object = CurrentLayer.GetCell(X, Y).Tile
Dim staticTile As lgMapStaticTiledMapTile = CurrentLayer.GetCell(X, Y).Tile

OpenGL ES

I explained what OpenGL is in the previous tutorial and I won't discuss it further here because the main advantage to use a game engine like libGDX is to benefit from the abstraction layer above OpenGL. However, if you need (or want) to call directly OpenGL, here's how to get access to the classes and functions:

B4X:

Dim lGdx_GL20 As lgGL20 = lGdx.Graphics.GL20

or better (includes also the constants):

B4X:

Dim GL As lgGL

Note: libGDX uses the 2D coordinate system and the color encoding of OpenGL ES, so the Y-axis is pointing upwards and each color value ranges from 0 to 1.

The libGDX life-cycle

An important thing to keep in mind about libGDX is that it runs in its own thread. Your Basic4Android application runs most of the time in a different thread called the UI thread, or main thread. That means you cannot access the other views of your activity and change their properties from the libGDX thread. Fortunately, there's a function in the LibGDX class that passes the runnable (the piece of code to execute) from a thread to the other: CallSubUI. So if you want to change the activity title, set a label text or show a MsgBox from the libGDX thread, don't forget to use this function to avoid a crash!

Since libGDX runs in a different thread, you have to inform its library of the events of your activity : Create, Pause and Resume. First, create an instance of libGDX in Globals :

B4X:

Dim lGdx As libGDX

In Activity_Create (and nowhere else), add the Initialize function :

B4X:

lGdx.Initialize(False, "LG") 'fills the activity with the libGDX surface, uses OpenGL 1 for compatibility and prefixes the events with LG

In Activity_Resume, add the following line :

B4X:

If lGdx.IsInitialized Then lGdx.Resume

In Activity_Pause, add the following line :

B4X:

If lGdx.IsInitialized Then lGdx.Pause

You could initialize libGDX differently. For example, it could be limited to a view with InitializeView. You could also define a configuration (lgConfiguration class) and pass it to libGDX. Example:

B4X:

Dim Config As lgConfiguration

'Disables the accelerometer and the compass
Config.useAccelerometer = False
Config.useCompass = False

'Uses a WakeLock (the device will stay on)
Config.useWakelock = True

'Creates the libGDX surface
lGdx.Initialize2(Config, "LG")

Once done, your library is ready to raise the events of its life-cycle : Create, Resize, Render, Pause, Resume, Dispose. These events are the place to put all the code of your game. Don't put anything in the usual activity events. They are reserved for your other views and are raised by the UI thread.

Create :

Create is the first raised event. It is raised soon after the initialization of the library and the creation of the OpenGL surface.
In this event, initialize your renderer and your input processors, load your resources (we'll see that in detail later) and initialize your game data.

Resize :

Resize is raised when the size of the libGDX surface changes. Under Android, that should only happen when you start the application and when it is restarted after a rotation or resumed.
It is raised at least once, after Create, and, when the application is resumed, just before Resume.
In this event, initialize the camera viewport. It's probably the only use you will find for it.
This event returns the new width and height in pixels.

Render :

Render is raised as soon as possible after Create and Resize.
It's where things are drawn. It's also where you have to put the logic of your game, but I would not recommend putting hundreds of lines of code here. Instead, create new subs and new modules and call them from this event.
The first lines in Render should be to clear the screen. Example:

B4X:

lGdx_GL.glClearColor(0, 0, 1, 1) 'Blue background
lGdx_GL.glClear(lGdx_GL.GL10_COLOR_BUFFER_BIT)

Pause :

Pause is raised when the activity is sent in the background, rotated or exited.
It's the right place to save your game data.
Note that the OpenGL context is destroyed when the app goes in the background, so all your unmanaged textures and pixmaps have to be reloaded or recreated in the Resume event when the app returns to the foreground.

Resume :

Contrary to the Resume event of your activity, this one is not raised after Create, only when the application returns from a pause.
As the OpenGL context is destroyed when the app goes in the background, all your unmanaged* textures and pixmaps have to be reloaded or recreated when this event is raised. More info here. *Not loaded by an asset manager.

Dispose :

Dispose is called when the activity is exited, after Pause, or when the device is rotated.
In this event, release all the used resources by calling the Dispose function of objects (if they have one).

The life-cycle :

Multiple screens

A game is made of many screens. You could create an activity for each one, but that would not be very convenient because you'd have to reinitialize the library in each activity and reload some resources. Moreover, that would not ease any graphical transition between screens. In fact, most games are made with a very small number of activities and make use of a screen manager instead. The screen manager stores the reference of the different screens and allows switching between them. Each screen has its own life-cycle.
To create a screen manager with two screens, for example, declare them in Globals:

B4X:

Dim lGdx_ScrMgr As lgScreenManager
Dim lGdx_Screen(2) As lgScreen

Then add these lines in the Create event handler:

B4X:

'Creates two screens
lGdx_ScrMgr.Initialize(lGdx)
lGdx_Screen(0) = lGdx_ScrMgr.AddScreen("LGS1")
lGdx_Screen(1) = lGdx_ScrMgr.AddScreen("LGS2")

Show the first screen:

B4X:

lGdx_ScrMgr.CurrentScreen = lGdx_Screen(0)

When you want to change the current screen, just change the value of the CurrentScreen property. That will raise the Hide event of the previous screen and the Show event of the new one.

The screens have the same life-cycle as the library, and thus the same events except that Create is named Show and Dispose is named Hide.

Input processor and gesture detector

To get the input events raised by your players, you have to declare input processors. libGDX has an input processor for keyboard and touch events (lgInputProcessor) and a specialized input processor for gestures (lgGestureDetector).
Start by declaring them in Globals:

B4X:

Dim lGdx_IP As lgInputProcessor
Dim lGdx_GD As lgGestureDetector

Initialize them in the Create event (or the Show event of a screen if you want different processors for different screens):

B4X:

lGdx_IP.Initialize("IP")
lGdx_GD.Initialize("GD")

And add the event handlers that you need:

B4X:

Sub IP_KeyDown(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyUp(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyTyped(Character As Char) As Boolean
   Return False
End Sub

Sub IP_TouchDown(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchDragged(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchUp(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_TouchDown(X As Float, Y As Float, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_Fling(VelocityX As Float, VelocityY As Float) As Boolean
   Return False
End Sub

Sub GD_LongPress(X As Float, Y As Float) As Boolean
   Return False
End Sub

Sub GD_Pan(X As Float, Y As Float, DeltaX As Float, DeltaY As Float) As Boolean
   Return False
End Sub

Sub GD_Pinch(InitialPointer1 As lgMathVector2, InitialPointer2 As lgMathVector2, Pointer1 As lgMathVector2, Pointer2 As lgMathVector2) As Boolean
   Return False
End Sub

Sub GD_Tap(X As Float, Y As Float, Count As Int) As Boolean
   Return False
End Sub

Sub GD_Zoom(InitialDistance As Float, Distance As Float) As Boolean
    Return False
End Sub

Description of events :

Fling: The user quickly dragged a finger across the screen, then lifted it. Useful to implement swipe gestures.
Pan: The user is dragging a finger across the screen. The detector reports the current touch coordinates as well as the delta between the current and previous touch positions. Useful to implement camera panning in 2D.
Pinch: Similar to zoom. The detector reports the initial and current finger positions instead of the distance. Useful to implement camera zooming and more sophisticated gestures such as rotation.
Tap: The user touched the screen and lifted the finger. The finger must not move outside a specified square area around the initial touch position for a tap to be registered. Multiple consecutive taps will be detected if the user performs taps within a specified time interval.
Zoom: The user has placed two fingers on the screen and is moving them together/apart. The detector reports both the initial and current distance between fingers in pixels. Useful to implement camera zooming.

The other events are self-explanatory.

.....

andymc · Jun 2, 2014

You can use the log() command to send information to the log in B4A to see more information from your game.

persianpowerman1 · Jun 2, 2014

andymc said:
You can use the log() command to send information to the log in B4A to see more information from your game.

yes.. i got that...
but is it possible... to go step by step... like how we generally debug... so unless i press F8 the program doesnt go to the next step.. got it?
i want to do this so i can see exactly how the collision is being detected etc.. etc... step by step..
any way possible?

Informatix · Jun 3, 2014

persianpowerman1 said:
how may i debug...?

The answer is in the text that you quoted: with the Log function. I'm so used to debug this way that I never use the debugger (and I'm not sure that anyone with a debugger will find more quickly where a problem is).

Informatix · Jun 3, 2014

persianpowerman1 said:
yes.. i got that...
but is it possible... to go step by step... like how we generally debug... so unless i press F8 the program doesnt go to the next step.. got it?
i want to do this so i can see exactly how the collision is being detected etc.. etc... step by step..
any way possible?

Rather than running code step by step (which can be long and boring when there are many loops in the middle), my own method is to place a few Log() at strategic places. The goal is to know whether I pass through a particular branch or not, and what's the value at this point. And if I need to detect when my variable reaches a particular value, I add a condition where the value is changed.

persianpowerman1 · Jun 3, 2014

hmmm... i get it...
ok... cool... am going to try it..
... Just that a few codes in the examples got a little heavy to understand...
but fine... will give it a go ... as you said... i'll add a few conditions here and there!

thanx buddy

ilan · Jun 20, 2014

hi, is it possible to change the speed of the playback?

via lbmusic ...

Informatix · Jun 20, 2014

ilan12041981 said:
hi, is it possible to change the speed of the playback?

via lbmusic ...

It's possible with lgSound (change the pitch value) but not with lgMusic.

ilan · Jun 20, 2014

thanx informatix, the problem with lgsound is that i dont know how to make an endless loop
with lgmusic its easy only looping = true
lgsound you put the times how much it should loop but i cannot find an endless looping option

will it effect in any way my game if i use lgsound instead of lgmusic with larger files??

ilan · Jun 20, 2014

i have one more question i have developed my first libgdx game and i have now uploaded it to my google play account but i see that the game required only open gl 1.0 and i saw you wrote it need at least open gl 2.0 so do i need to write something in the manifest editor?

i set the minsdk to 8 is this correct?

Informatix · Jun 20, 2014

ilan12041981 said:
thanx informatix, the problem with lgsound is that i dont know how to make an endless loop

The Loop function does not work?

ilan12041981 said:
will it effect in any way my game if i use lgsound instead of lgmusic with larger files??

You will use more memory as the sounds are entirely loaded before being played contrary to the music which is streamed from the media. And large files take some time to be loaded.

ilan12041981 said:
i set the minsdk to 8 is this correct?

It works with 8, but a recent discussion led to the conclusion that 9 is better (so only devices with Gingerbread are allowed for Android versions < 3).

ilan · Jun 20, 2014

thank you i will set the min sdk to 8, what about the opengl ? do i need to set anything more in the menifest editor?

Informatix · Jun 20, 2014

ilan12041981 said:
thank you i will set the min sdk to 8, what about the opengl ? do i need to set anything more in the menifest editor?

no.

wahyuway · Jun 22, 2014

is there any chance in future to release lib with 3d classes? i need to load my 3d object

ilan · Jun 22, 2014

i'm trying to call a sub from the render but its not working what am i doing wrong

B4X:

lGdx.CallSubUI("submsg",Null)

Sub submsg
If fireb.Visible = True Then fireb.Visible = False
End Sub

Informatix · Jun 23, 2014

wahyuway said:
is there any chance in future to release lib with 3d classes? i need to load my 3d object

It is not planned in the near future.
The current owner of the wrapped library is Anywhere Software (Erel) so I won't take big decisions about it and, personally, I don't have neither the time nor the desire to work on these classes.
Please note that it already exists a library for 3D objects: jPCT-AE.

Informatix · Jun 23, 2014

ilan12041981 said:
i'm trying to call a sub from the render but its not working what am i doing wrong

B4X:

lGdx.CallSubUI("submsg",Null) Sub submsg If fireb.Visible = True Then fireb.Visible = False End Sub

Like for any event handler, the parameter is mandatory for your sub even if you do not use it:
Sub submsg(NotUsed As Object)

ilan · Jun 23, 2014

thanx informatix i will test it when i get home...
do i need to pause the lGdx? and then do what i would like to do?

Informatix · Jun 23, 2014

ilan12041981 said:
thanx informatix i will test it when i get home...
do i need to pause the lGdx? and then do what i would like to do?

If you have no reason to stop the rendering, then there's no reason to pause lGDX.

wahyuway · Jun 23, 2014

in live wallpaper example, i combine with gifdecoder lib,to decode gif

i made a sub event and call it with CallSubUI("loadLWP,"")

B4X:

Sub loadLWP(Param As Object)

    Dim gif As GifDecoder
   
    gif.DisposeFrames
    gif.load(File.DirAssets, "winter.gif")
   
    ToastMessageShow(gif.FrameCount & " frames", True)
   
    MyDirectory = File.DirRootExternal & "/LWP" 
    If File.Exists(MyDirectory, "") = False Then 
        File.MakeDir(File.DirRootExternal, "LWP") 
    End If
   
    For Frame = 0 To (gif.FrameCount-1)
        gif.SaveFrame(Frame, MyDirectory, "frame"&Frame&".jpg", "J", 90)
       
    Next
End Sub

But it seems not working. I called it inside LG_Create

1. How to handle files and directory inside libgdx?
2. Is there any tick event to animate background?

Thanks

Informatix · Jun 23, 2014

wahyuway said:
But it seems not working. I called it inside LG_Create

What does not work? The call to your sub or the sub itself?
In your case, I see no reason to call this sub from libGDX. What it does is not supposed to be done during the game, but before, and does not involve libGDX, so call that before initializing libGDX and that will be fine.

wahyuway said:
1. How to handle files and directory inside libgdx?
2. Is there any tick event to animate background?

You should read the following chapters in the first posts of this thread: "The libGDX life-cycle", "Rendering" and "File handling".

Android Tutorial Introduction to the libGDX library

Well-Known Member

Active Member

Expert

Expert

Active Member

Expert

Expert

Expert

Expert

Expert

Expert

Expert

Member

Expert

Expert

Expert

Expert

Expert

Member

Expert

Similar Threads

Privacy & Transparency

Privacy & Transparency