Android Question share url files as Picture

[ibra939]

I have url files as picture when i need to share it to whatapp as file provider not share i don't knows why

I check this link Files provider

Sub DownloadFitimage(url As String, TargetImage As ImageView)

    Dim job As HttpJob

    job.Initialize("", Me)

    job.Download(url)

    Wait For (job) JobDone(job As HttpJob)

    If job.Success Then

        Dim bmp As Bitmap = job.GetBitmap

        Dim scaledBmp As Bitmap = bmp.Resize(TargetImage.Width, TargetImage.Height, True)

        TargetImage.Bitmap = scaledBmp

        TargetImage.Gravity = Gravity.FILL

    Else

        Log("Error downloading image: " & job.ErrorMessage)

    End If

    job.Release

End Sub


Sub img_Click

    Dim now As Long = DateTime.Now

    If now - lastClickTime < doubleClickDelay Then

        Dim img As ImageView = Sender

        Dim imageUrl As String = img.Tag


        Dim j As HttpJob

        j.Initialize("downloadimage", Me)

        j.Download(imageUrl)

        Wait For (j) JobDone(j As HttpJob)

        If j.Success Then

            Dim filename As String = "temp.jpg"

            Dim out As OutputStream = File.OpenOutput(File.DirInternalCache, filename, False)

            File.Copy2(j.GetInputStream, out)

            out.Close

            j.Release

            ShareImageWhatsApp(File.DirInternalCache, filename)

        Else

            Log("Download failed: " & j.ErrorMessage)

            j.Release

        End If

    Else

        lastClickTime = now

    End If

End Sub


Sub SaveImageToTempFile(bmp As Bitmap, TempFileName As String) As String

    Dim out As OutputStream = File.OpenOutput(File.DirInternal, TempFileName, False)

    bmp.WriteToStream(out, 100, "JPEG")

    out.Close

    Return TempFileName

End Sub


Sub ShareImageWhatsApp(Dir As String, FileName As String)

    Dim uri As Object = Provider.GetFileUri(Dir, FileName)


    Dim i As Intent

    i.Initialize(i.ACTION_SEND, "")

    i.SetType("image/*")

    i.PutExtra("android.intent.extra.STREAM", uri)

    i.Flags = Bit.Or(i.Flags, 1) ' FLAG_GRANT_READ_URI_PERMISSION


    StartActivity(i)

End Sub

 

[DonManfred]

USE codetags when posting code

Better create a small project which show the issue and upload the project

 

[ibra939]

USE codetags when posting code

Better create a small project which show the issue and upload the project

thanks i forget to use

 

[ibra939]

using

Sub ShareExistingImageToWhatsApp(FileName As String)
    Dim realDir As String = File.Combine(File.DirRootExternal, "Pictures/MyApp")

    If File.Exists(realDir, FileName) = False Then
        ToastMessageShow("Photo not found", True)
        Return
    End If

    Dim in As Intent
    in.Initialize(in.ACTION_VIEW, "")
    Provider.SetFileUriAsIntentData(in, FileName)
    'Type must be set after calling SetFileUriAsIntentData
    in.SetType("image/*")
    'i.PutExtra("android.intent.extra.STREAM", uri)
    'i.Flags = Bit.Or(i.Flags, 1)
    in.SetComponent("com.whatsapp/.ContactPicker")

    StartActivity(in)
End Sub

 

[Erel]

1. Code with File.DirRootExternal = broken code.

2. FileProvider example: https://www.b4x.com/android/forum/threads/class-fileprovider-share-files.97865/#content

3. What happens when you run this code?

 

[aeric]

This is part of my code in https://www.b4x.com/android/forum/threads/webviewsharepdf.165584/

Public Sub SharePDF
    File.Copy(File.DirInternal, "example.pdf", provider.SharedFolder, "example.pdf")
    'Dim filesize As Long = File.Size(provider.SharedFolder, "example.pdf")
    'Log(NumberFormat2(filesize/1024, 1, 2, 0, False) & "KB")
    Dim in As Intent
    in.Initialize(in.ACTION_SEND, "")
    in.SetPackage("com.whatsapp")
    in.PutExtra("android.intent.extra.STREAM", provider.GetFileUri("example.pdf"))
    in.SetType("application/pdf")
    StartActivity(in)
End Sub

Change PDF mime and filename to image file.

 

[ibra939]

This is part of my code in https://www.b4x.com/android/forum/threads/webviewsharepdf.165584/

Public Sub SharePDF
    File.Copy(File.DirInternal, "example.pdf", provider.SharedFolder, "example.pdf")
    'Dim filesize As Long = File.Size(provider.SharedFolder, "example.pdf")
    'Log(NumberFormat2(filesize/1024, 1, 2, 0, False) & "KB")
    Dim in As Intent
    in.Initialize(in.ACTION_SEND, "")
    in.SetPackage("com.whatsapp")
    in.PutExtra("android.intent.extra.STREAM", provider.GetFileUri("example.pdf"))
    in.SetType("application/pdf")
    StartActivity(in)
End Sub

Change PDF mime and filename to image file.

i make test and modfiy some of the code is working perfectly Aeric .
Thanks for Sharing .

Private Sub Sharetowhatsapp_Click
    Dim galleryDir As String = File.Combine(File.Combine(File.DirRootExternal, "Pictures"), "MyApp")
    If LastSavedFileName = "" Or File.Exists(galleryDir, LastSavedFileName) = False Then
        ToastMessageShow("Not found the picture", True)
        Return
    End If

    File.Copy(galleryDir, LastSavedFileName, Provider.SharedFolder, LastSavedFileName)

    Dim in As Intent
    in.Initialize(in.ACTION_SEND, "")
    in.SetPackage("com.whatsapp")
    in.PutExtra("android.intent.extra.STREAM", Provider.GetFileUri(LastSavedFileName))
    in.SetType("image/jpeg")
    StartActivity(in)
End Sub

 

[Isaacc]

i make test and modfiy some of the code is working perfectly Aeric .
Thanks for Sharing .

Private Sub Sharetowhatsapp_Click
    Dim galleryDir As String = File.Combine(File.Combine(File.DirRootExternal, "Pictures"), "MyApp")
    If LastSavedFileName = "" Or File.Exists(galleryDir, LastSavedFileName) = False Then
        ToastMessageShow("Not found the picture", True)
        Return
    End If

    File.Copy(galleryDir, LastSavedFileName, Provider.SharedFolder, LastSavedFileName)

    Dim in As Intent
    in.Initialize(in.ACTION_SEND, "")
    in.SetPackage("com.whatsapp")
    in.PutExtra("android.intent.extra.STREAM", Provider.GetFileUri(LastSavedFileName))
    in.SetType("image/jpeg")
    StartActivity(in)
End Sub

did it stop working or still working for you?

 

[ibra939]

Working fine